Question

我最近接手了一个包装Shipping Web服务的Perl客户端的维护。处于初始状态的项目使用直接映射到Web服务对象的Moo对象，例如，有Parcel，Address和Label类。

在API的v2中，您必须将表示其中一个对象的所有数据POST到Web服务，然后返回该Object的唯一ID，该ID必须用于所有后续事务。

例如，如果我发布：

{ name   => 'Hunter',
  street => '121 Baker St',
  city   => 'New York',
  state  => 'NY',
}

我会收回相同的数据，但包含ID：

{ id     => 'adr_xq1411',
  name   => 'Hunter',
  street => '121 Baker St',
  city   => 'New York',
  state  => 'NY',
}

我无法决定如何创建这些对象。目前，我有这个构造函数执行实际的POST来获取ID然后修改当前对象：

sub BUILD {
    my $self = shift;

    my $requestor = Net::Easypost::Request->new;
    my $resp = $requestor->post( 
        '/addresses', 
        $self->serialize( [qw(street1 street2 city state zip)] ) 
    );

    # save the id for this Address from Easypost   
    $self->id( $resp->{id} );

    return $self;
}

在Perl中包装Web服务时，这是一种常见的方法吗？似乎理想的方法是POST到Web服务并同时创建Address对象的所有属性，但是在Moo（se）中，一旦进入BUILD方法，该对象就已经创建了。

我对包装Web服务的惯用语并不熟悉，有没有比这更简单的方法？

任何建议/意见/建议将不胜感激。

Answer 1

这当然是一种方法。将BUILD方法分解为角色可能是个好主意。类似的东西：

package MyApp::PostOnBuild;

use Moo::Role;

has id          => (is => 'rwp');
has endpoint    => (is => 'ro', default => sub { '/addresses' });
has requestor   => (is => 'ro', default => sub { Net::Easypost::Request->new });
has field_names => (is => 'ro', builder => 1);

requires '_build_field_names';
requires 'serialize';  # or maybe just implement serialize within this role!

sub BUILD { }
after BUILD => sub {
    my $self = shift;
    my $resp = $self->requestor->post($self->endpoint, $self->serialize($self->field_names));
    $self->_set_id( $resp->{id} );
};

现在，您的类不需要定义自己的BUILD方法。他们所需要做的就是：

package MyApp::Address;

use Moo;
with 'MyApp::PostOnBuild';

my @fields = qw/ street1 street2 city state zip /;

has $_ => (is => 'ro') for @fields;

sub _build_field_names { \@fields }

sub serialize { ... }  # would this method be better defined in MyApp::PostOnBuild??

请注意，requestor现在是一个属性，因此当您测试该类时，您可以执行以下操作：

my $adr = MyApp::Address->new(
    street1   => '123 Example Lane',
    city      => 'Sydney',
    state     => 'NSW',
    zip       => '2035',
    requestor => Test::Requestor->new,
);

使用Moo包装Web服务

1 个答案: