Question

我为2或3或4或'n'个用户名传递一个密码值。

如何动态地将user_id传递给更新查询？

update user_table
set column_password = 'password value'
where user_id in ( )

Answer 1

首先使用以下代码创建函数：

SET ANSI_NULLS ON
GO

SET QUOTED_IDENTIFIER ON
GO

CREATE FUNCTION [dbo].[SplitIDs]
(
    @List varchar(5000)
)
RETURNS 
@ParsedList table
(
    ID int
)
AS
BEGIN
    DECLARE @ID varchar(10), @Pos int

    SET @List = LTRIM(RTRIM(@List))+ ','
    SET @Pos = CHARINDEX(',', @List, 1)

    IF REPLACE(@List, ',', '') <> ''
    BEGIN
        WHILE @Pos > 0
        BEGIN
            SET @ID = LTRIM(RTRIM(LEFT(@List, @Pos - 1)))
            IF @ID <> ''
            BEGIN
                INSERT INTO @ParsedList (ID) 
                VALUES (CAST(@ID AS int)) --Use Appropriate conversion
            END
            SET @List = RIGHT(@List, LEN(@List) - @Pos)
            SET @Pos = CHARINDEX(',', @List, 1)

        END
    END 
    RETURN
END

GO

然后在存储过程中declate @UserIDs varchar(max)。您将逗号分隔的ID列表传递给此参数。

然后在您的存储过程中，您可以：

update U
set U.column_password = 'password value'
FROM dbo.SplitIDs(@UserIDs) I
INNER JOIN user_table U ON I.ID=U.user_id

Answer 2

创建功能

CREATE FUNCTION [dbo].[FnSplit]
(
@List nvarchar(2000),
@SplitOn nvarchar(5)
)
RETURNS @RtnValue table (Id int identity(1,1), Value nvarchar(100))
AS
BEGIN

While(Charindex(@SplitOn,@List)>0)

  Begin


        Insert Into @RtnValue (value)

        Select Value = ltrim(rtrim(Substring(@List,1,Charindex(@SplitOn,@List)-1)))

        Set @List = Substring(@List,Charindex(@SplitOn,@List)+len(@SplitOn),len(@List))

  End


Insert Into @RtnValue (Value)

Select Value = ltrim(rtrim(@List))

Return

END

存储过程

CREATE Procedure usp_Multipleparameter (@Users VARCHAR(1000)= NULL)
AS
BEGIN

        update user_table
        set column_password = 'password value'
        where user_id collate database_default IN (SELECT Value FROM dbo.FnSplit(@Users,','))

END
GO

调用商店程序

EXEC usp_Multipleparameter 'User1,User2'

Answer 3

只是一个想法。如果这已存在于存储过程中，则可能已经通过select语句向您提供了user_id。我会做这样的事情。

update user_table
set column_password = 'password value'
where user_id in ( select user_id from table
where criteria = '' )

动态更新SQL中的列值

3 个答案: