Question

我正在学习使用Alex和Happy编写一个小编译器。我想维护AST节点的行和列信息，以便我可以向用户提供有意义的错误消息。为了说明我打算如何做，我写了一个小例子（见下面的代码），我想知道我是否接近问题的方式（将AlexPosn附加到标记，将多态属性字段附加到AST节点，使用tkPos和astAttr）是好的风格，或者是否有更好的方法来处理位置信息。

Lexer.x：

{
module Lexer where
}

%wrapper "posn"

$white = [\ \t\n]

tokens :-

$white+ ;
[xX] { \pos s -> MkToken pos X }
"+"  { \pos s -> MkToken pos Plus }
"*"  { \pos s -> MkToken pos Times }
"("  { \pos s -> MkToken pos LParen }
")"  { \pos s -> MkToken pos RParen }

{
data Token = MkToken AlexPosn TokenClass
           deriving (Show, Eq)

data TokenClass = X
                | Plus
                | Times
                | LParen
                | RParen
                  deriving (Show, Eq)

tkPos :: Token -> (Int, Int)
tkPos (MkToken (AlexPn _ line col) _) = (line, col)
}

Parser.y：

{
module Parser where

import Lexer
}

%name simple
%tokentype { Token }
%token
    '(' { MkToken _ LParen }
    ')' { MkToken _ RParen }
    '+' { MkToken _ Plus }
    '*' { MkToken _ Times }
    x   { MkToken _ X }

%%

Expr : Term '+' Expr     { NAdd $1 $3 (astAttr $1) }
     | Term              { $1 }

Term : Factor '*' Term   { NMul $1 $3 (astAttr $1) }
     | Factor            { $1 }

Factor : x               { NX (tkPos $1) }
       | '(' Expr ')'    { $2 }


{
data AST a = NX a
           | NMul (AST a) (AST a) a
           | NAdd (AST a) (AST a) a
             deriving (Show, Eq)

astAttr :: AST a -> a
astAttr (NX a)       = a
astAttr (NMul _ _ a) = a
astAttr (NAdd _ _ a) = a

happyError :: [Token] -> a
happyError _ = error "parse error"
}

Main.hs：

module Main where

import Lexer
import Parser

main :: IO ()
main = do
  s <- getContents
  let toks = alexScanTokens s
  print $ simple toks

Answer 1

我个人对你所描述的风格非常满意。但是，它非常手动，我希望至少提供一种可能更容易管理的替代方案。

如果你向documentation for alex wrappers稍微向下看，你会注意到monad和monadstate包装都包含位置信息。缺点是你现在把整个东西包裹在一个monad中，它使解析器稍微复杂化。但是，通过将其包装在monad中，解析的结果为Alex a，这意味着您在创建ast节点时可以完全访问行和列信息。现在，这只是从词法分析器中删除了一些锅炉板，并没有做更多的事情。

通过执行此操作，您还可以使用令牌携带AlexState，但这可能是不必要的。

如果你需要帮助实际修复解析器以处理monad / monadstate包装器，我写了一个关于我如何设法让它在这里工作的响应：How to use an Alex monadic lexer with Happy?

与Alex和Happy一起管理职位信息

1 个答案: