Question

如何扫描包含由新行字符分隔的电子邮件地址的文件，并删除属于某个域的电子邮件地址，例如hacker@bad.com。我想删除所有@bad.com

的电子邮件地址

Answer 1

使用grep代替Perl

grep -v '@bad\.com' inputfile > outputfile

在Windows上

findstr /v "@bad\.com" inputfile > outputfile

Answer 2

Email::Address是处理电子邮件地址的一个很好的模块。

这是一个可以让你胃口大开的例子：

use Email::Address;

my $data = 'this person email is hacker@bad.com
blah blah hacker@good.com blah blah
another@bad.com
';

my @emails      = Email::Address->parse( $data );
my @good_emails = grep { $_->host ne 'bad.com' } @emails;

say "@emails";       # => hacker@bad.com hacker@good.com another@bad.com
say "@good_emails";  # => hacker@good.com

Answer 3

这应该做：

$badDomain = "bad.com";
while(<>)
{
        s{\s+$}{};
        print "$_\n" if(!/\@$badDomain$/);
}

Answer 4

以下将允许您拥有一个可以及时增强的脚本...而不是简单地过滤掉@ bad.com（您可以使用简单的grep），您可以编写脚本以便轻松很复杂哪些域名是不受欢迎的。

my $bad_addresses = {'bad.com'=>1};

while (my $s = <>) {
    print $s unless (is_bad_address($s));
}

sub is_bad_address {
    my ($addr) = @_;
    if ($addr=~/^([^@]+)\@([^@\n\r]+)$/o) {
        my $domain = lc($2);
        return 0 unless (defined $bad_addresses->{$domain});
        return $bad_addresses->{$domain};
    }
    return 1;
}

Answer 5

与其他人所做的完全不同。

use strict;
use warnings;

my @re = map { qr/@(.*\.)*\Q$_\E$/ } qw(bad.com mean.com);

while (my $line = <DATA>) {
    chomp $line;
    if (grep { $line =~ /$_/ } @re) {
        print "Rejected: $line\n";
    } else {
        print "Allowed: $line\n";
    }
}

__DATA__
good@good.com
bad@bad.com
notbad@bad.comm.com
alsobad@bad.com
othergood@good.com
not@mean.com
good@reallymean.com
bad@really.mean.com

Answer 6

Perl

perl -ne 'print if !/@bad\.com/' file

AWK

awk '!/@bad\.com/' file

Answer 7

此代码应过滤输入文件中的所有@ bad.com地址。

 my @array = <>;

 foreach(@array) {
   if(!/\@bad.com$/) {
     print $_;
   }
 }

如何使用Perl过滤属于特定域的电子邮件地址？

7 个答案: