如何将ActiveX命令按钮复制到另一个工作表并保留按钮的名称

Question

我已尝试使用以下代码从一张工作表中复制一个ActiveX命令按钮并将其粘贴到另一张工作表中：

Sheets("SRC").HasACustomName.Copy
Sheets("TRGT").Range("O1").PasteSpecial

我也试过了：

Sheets("SRC").Shapes("hasACustomName").Copy 
Sheets("TRGT").Range("O1").Select 
Sheets("TRGT").Paste

但我遇到的问题是它们将命令按钮从hasACustomName重命名为CommandButtonX。

你能想出一种方法，将命令按钮从一个工作表粘贴到另一个工作表，让我保留命令按钮的原始名称吗？

Answer 1

的ActiveX

您可以使用以下代码将ActiveX控件从一个工作表复制到另一个工作表。

注意：在一个电子表格中不能有两个同名的对象。

Sub CopyActiveX()
    Application.ScreenUpdating = False
    Dim x As OLEObject, y As OLEObject
    Set x = Sheets("SRC").OLEObjects("HasCustomName")
    Set y = x.Duplicate
    Dim xName As String
    xName = x.Name
    y.Cut
    With Sheets("TRGT")
        .Paste
        .OLEObjects(.OLEObjects.Count).Name = xName
        .Activate
    End With
    Application.ScreenUpdating = True
End Sub

<小时/>

表单控件

要将一个按钮从一个工作表复制到另一个工作表，以防止自动更改名称，请使用以下代码。默认情况下，Excel为复制的按钮（甚至在不同的工作表上）提供新名称，因此您必须重命名它以匹配您复制的按钮的名称。

使用CopyButton() sub来实现它。有4个必需参数

• from - 要从
复制按钮的工作表名称
• btnName - 您要复制的控件的名称
• toWorksheet - 目标工作表
• rng - 与按钮相关联的目标范围

---

Sub CopyPasteButton()
    CopyButton "SRC", "Button 1", "TRGT", "B10"
End Sub

Private Sub CopyButton(from As String, btnName As String, toWorksheet As String, rng As String)
    Application.ScreenUpdating = False
    Sheets(from).Shapes(btnName).Copy
    Sheets(toWorksheet).Activate
    Sheets(toWorksheet).range(rng).Select
    Sheets(toWorksheet).Paste
    Selection.ShapeRange.Name = btnName
    Application.ScreenUpdating = True
End Sub