Question

根据此microsoft knowledge base question中的信息，我正在尝试从TWebBrowser打印时实现自定义页眉和页脚。知识库文章非常有用，甚至包含一个冗长的代码示例，但是，代码示例是在C ++而不是Delphi中，所以我不得不尝试将必要的数据结构转换为Delphi代码。我并不十分自信我已正确转换了我需要的代码部分。

这可能是该文章中最重要的部分，它在下面的代码中解释了我的参数vaIn应该包含的内容：

使用OLECMDID_PRINT元素的OLECMDID枚举时与ExecWB方法一起，您可以指定扩展打印通过VARIANT传入SAFEARRAY结构的信息论证pvaIn。此SAFEARRAY数据类型最多需要五个项目：
1) A string (BSTR) that contains a custom header.
2) A string (BSTR) that contains a custom footer.
3) ...

当我运行我编写的代码时，它成功删除了原始的页眉和页脚，但是没有用我的新页眉和页脚字符串替换它，所以我想知道我的代码是否在某种程度上是不正确的（或者几种方式），或者如果我不想指望它工作，因为我使用的是IE 9而不是4-6范围内的版本，这是当时知识库文章编写的。

var
  vaIn, vaOut: OleVariant;
begin
    vaIn := VarArrayCreate([0,1], varOleStr); 
    vaIn[0] := VarAsType('new header', VarOleStr); //header
    vaIn[1] := VarAsType('new footer', VarOleStr); //footer

    // Show print-preview dialog 
    WebBrowser1.ControlInterface.ExecWB(OLECMDID_PRINTPREVIEW,
      OLECMDEXECOPT_DONTPROMPTUSER, vaIn, vaOut);
end;

Answer 1

这会打印自定义页眉/页脚。自定义标头不适用于 OLECMDID_PRINTPREVIEW，但它们适用于 OLECMDID_PRINT。关键是使用 VT_ARRAY or VT_BYREF，因为 TVariantArg 必须通过引用传递。

代码来源：TEmbeddedWB https://github.com/7even11/Delphi-EmbeddedWB

procedure PrintWithHeaderFooter(ControlInterface: IWebBrowser2; Header, Footer: PWideChar; Options: OLECMDEXECOPT);
var
  saBound: TSafeArrayBound;
  psaHeadFoot: PSafeArray;
  vaIn, vaOut: TVariantArg;
  vHeadStr, vFootStr: TVariantArg;
  rgIndex: LongInt;
begin
  try
    saBound.lLbound := 0;
    saBound.cElements := 2;
    psaHeadFoot := SafeArrayCreate(VT_VARIANT, 1, saBound);
    vHeadStr.vt := VT_BSTR;
    vHeadStr.bstrVal := SysAllocString(Header);
    vFootStr.vt := VT_BSTR;
    vFootStr.bstrVal := SysAllocString(Footer);
    rgIndex := 0;
    OleCheck(SafeArrayPutElement(psaHeadFoot, rgIndex, vHeadStr));
    rgIndex := 1;
    OleCheck(SafeArrayPutElement(psaHeadFoot, rgIndex, vFootStr));
    vaIn.vt := VT_ARRAY or VT_BYREF;
    vaIn.parray := psaHeadFoot;
    ControlInterFace.ExecWB(OLECMDID_PRINT, Options,
      OleVariant(vaIn), OleVariant(vaOut));
    if vHeadStr.bstrVal <> nil then
      SysFreeString(vHeadStr.bstrVal);
    if vFootStr.bstrVal <> nil then
      SysFreeString(vFootStr.bstrVal);
  except
  end;
end;

procedure Print(ControlInterface: IWebBrowser2; bHideSetup: Boolean = False; bCustomHeaderFooter: Boolean = False; Header: string = ''; Footer: string = '');
var
  vaIn, vaOut: OleVariant;
begin
  if DocumentLoaded(ControlInterface.Document) then
  begin
    if bCustomHeaderFooter then
    begin
      if bHideSetup then
        PrintWithHeaderFooter(ControlInterface, TaskAllocWideString(Header), TaskAllocWideString(Footer), OLECMDEXECOPT_DONTPROMPTUSER)
      else
        PrintWithHeaderFooter(ControlInterface, TaskAllocWideString(Header), TaskAllocWideString(Footer), OLECMDEXECOPT_PROMPTUSER);
    end
    else
      if bHideSetup then
        ControlInterface.ExecWB(OLECMDID_PRINT, OLECMDEXECOPT_DONTPROMPTUSER, vaIn, vaOut)
      else
        ControlInterface.ExecWB(OLECMDID_PRINT, OLECMDEXECOPT_PROMPTUSER, vaIn, vaOut)
  end;
end;

如何将OleVariant参数用于TWebBrowser打印对话框？

1 个答案: