Question

我必须编写代码以获取所有可访问的进程，但我需要删除此数组上的重复项，并且每个进程只显示一次。

如何做到这一点的最佳方法，因为我认为进程数组不像普通数组。

我的代码：

For Each p As Process In Process.GetProcesses
    Try
        'MsgBox(p.ProcessName + " " + p.StartTime.ToString)
    Catch ex As Exception
        'Do nothing
    End Try
Next

提前致谢

Answer 1

Process.GetProcesses()方法返回一个数组。您可以使用Distinct方法，为其提供IEqualityComparer。

一个例子是比较者：

Public Class ProcessComparer
    Implements IEqualityComparer(Of Process)

    Public Function Equals1(p1 As Process, p2 As Process) As Boolean Implements IEqualityComparer(Of Process).Equals
        ' Check whether the compared objects reference the same data. 
        If p1 Is p2 Then Return True
        'Check whether any of the compared objects is null. 
        If p1 Is Nothing OrElse p2 Is Nothing Then Return False
        ' Check whether the Process' names are equal. 
        Return (p1.ProcessName = p2.ProcessName)
    End Function

    Public Function GetHashCode1(process As Process) As Integer Implements IEqualityComparer(Of Process).GetHashCode
        ' Check whether the object is null. 
        If process Is Nothing Then Return 0
        ' Get hash code for the Name field if it is not null. 
        Return process.ProcessName.GetHashCode()
    End Function
End Class

你可以像这样使用它：

Sub Main()
    Dim processes As Process() = Process.GetProcesses()
    Console.WriteLine(String.Format("Count before Distinct = {0}", processes.Length))

    ' Should contain less items
    Dim disProcesses As Process() = processes.Distinct(New ProcessComparer()).ToArray()
    Console.WriteLine(String.Format("Count after Distinct = {0}", disProcesses.Length))

    Console.ReadLine()
End Sub

您可能需要根据您的规格以及您将要使用的情况优化Comparer。

使用VB .net从进程数组中删除重复项

1 个答案: