Question

我被我认为相对简单的创建功能的任务所阻碍，以允许用户将图片上传到服务器目录并寻求帮助。

我有一个简单的表单，有一个简单的接口，传递一个名为'imagedata'的变量，它是从文件输入传递的数据，一个名为'name'的变量，它是一个指定的图像名称，以及一个名为'imagetype'的变量它传递文件扩展名。

我在函数（处理程序）中用来保存此文件的代码如下：

<cfset form.imageName = form.name & "." & form.imagetype />
...
<cffile action="write" file="#sitepath#storage/bannerImages/#form.imagename#" output="#form.imageData#" />

这显然不起作用;它将使用正确的名称保存文件，但不能正确保存文件，也不会呈现为图像。我认为这是相对简单的事情，我认为我忽略了一些东西，因为我在谷歌上找不到任何东西，这很奇怪。欢迎帮助解决这个问题。

Answer 1

请勿使用action="write"，请使用action="upload"。

示例：

<cffile
    action       = "upload"
    fileField    = "ImageData"
    destination  = "/tmp/uploads"
    accept       = "image/jpg"
    nameConflict = "MakeUnique"
/>

这会将文件放在/tmp/uploads中（例如在Windows上使用d:/tmp/uploads） - 这是无法在线访问的目录。

此时，您必须验证该文件是否为其声称的文件 - 具有适当尺寸和文件大小的图像文件，而不是蒙版的EXE或embedded ZIP。

如果您对文件在服务器上托管是安全的，那么您可以将其移动到相应的目录并将名称设置为所选内容。

像...一样的东西。

<cfif cffile.FileWasSaved>

    <cfset UploadedFileName = cffile.ServerDirectory & '/' & cffile.ServerFile />

    <cfif NOT IsImageFile( UploadedFileName )>
        <cfthrow message="Uploaded file not an image." />
    </cfif>

    <!--- INFO: Checks if zip embedded in image. --->
    <cftry>
        <cfzip action="list" file="#UploadedFileName#" name="tmp"/>
        <cfthrow message="Embedded zip files not allowed."/>
        <!--- TODO: Verify correct exception type for CF: --->
        <cfcatch type="java.util.zip.zipexception"></cfcatch>
    </cftry>

    <!---
        TODO: Validate any necessary business rules
        (e.g. image not too large, etc)
    --->        

<cfelse>
    <cfthrow message="File Upload Error"/>
</cfif>


<cfif refind('\W',Form.Name)>
    <cfthrow message="Invalid Name specified. Only alphanumerics allowed."/>
</cfif>
<cfif NOT ListFindNoCase('PNG,JPG,GIF',Form.ImageType)>
    <cfthrow message="Invalid FileType specified. Must be PNG/JPG/GIF"/></cfif>
</cfif>

<cffile
    action      = "rename"
    source      = "#UploadedFileName#"
    destination = "#sitepath#storage/bannerImages/#Form.Name#.#Form.ImageType#"
/>

该代码未经测试，并且 - 与您在服务器上运行的所有内容一样，但特别是涉及客户端上传的代码 - 请确保在使用之前了解它的作用。
Adobe LiveDocs和various CF blogs上有大量有价值的信息，值得花一些时间消化。

使用ColdFusion将上载的图像保存到服务器

1 个答案: