Question

您好我正在尝试在Ubuntu上安装nVidia OptiX SDK 3.0.0版本的linux64。

我已下载.run文件。当执行完成后，我得到一个名为〜/ NVIDIA-OptiX-SDK-3.0.0-linux64 /

的文件夹

它在我的主文件夹中。

预编译的示例工作正常，但是当我尝试编译自己的代码时，编译器似乎将.cu文件作为CUDA文件处理并尝试将它们编译为.cu.o。我程序错误的一个输出是：

Building NVCC (Device) object CMakeFiles/RayTracerExec.dir/src/Tracy/ObjectLoader/optixcu/./RayTracerExec_generated_triangle_mesh_target.cu.o

通常文件应该编译成某种ptx文件吗？

以下错误是：

ptxas /tmp/tmpxft_00000eef_00000000-5_triangle_mesh_target.ptx, line 94; error   : Label expected for argument 0 of instruction 'call'
ptxas /tmp/tmpxft_00000eef_00000000-5_triangle_mesh_target.ptx, line 94; error   : Call target not recognized
ptxas /tmp/tmpxft_00000eef_00000000-5_triangle_mesh_target.ptx, line 94; error   : Function '_rt_buffer_get_64' not declared in this scope

找不到函数_rt_buffer_get_64会让我觉得某些东西安装不正确。

在文件夹中是名为的子文件夹 doc包括lib64 SDK SDK-precompiled-samples 我所做的是将include的内容复制到/ usr / local / include中和lib64的内容到/ usr / local / lib

任何想法？此致

Answer 1

看起来您正在使用CMake根据输出中的文本来构建样本。看起来构建系统认为您要编译目标文件而不是PTX文件。您看到的错误消息也表明了这种症状。

有几种从CMake中编译CUDA代码的方法。

如果您使用的是CUDA运行时，则通常会执行以下操作：

cuda_add_executable(myprogram main.cpp mycuda.cu myheader.h)

这会创建一个名为myprogram的可执行文件，它由两个目标文件组成：main.cpp.o和mycuda.cu.o。 CUDA运行时期望cuda文件中的代码符合CUDA运行时API。

除了cuda_add_executable之外，还有cuda_add_library编译库而不是可执行文件。这两个宏都使用另一个名为cuda_wrap_srcs的宏来完成大部分繁重工作，只要生成构建命令来编译CUDA代码即可。除此之外，这个宏还有一个参数，用于指定是否要使用CUDA运行时或仅定位PTX（参数为OBJ或PTX）。

要使OptiX着色器编译，您必须以PTX为目标。在我们发布的SDK中，这是通过名为OPTIX_add_sample_executable的CMake函数处理的，可以在<install>/SDK/CMakeLists.txt中找到。这个函数的主要功能是使用指定的PTX选项调用cuda_wrap_srcs。我在这里也包含了这个功能以供参考。

#########################################################
# OPTIX_add_sample_executable
#
# Convenience function for adding samples to the code.  You can copy the contents of this
# function into your individual project if you wish to customize the behavior.  Note that
# in CMake, functions have their own scope, whereas macros use the scope of the caller.
function(OPTIX_add_sample_executable target_name)

  # These calls will group PTX and CUDA files into their own directories in the Visual
  # Studio projects.
  source_group("PTX Files"  REGULAR_EXPRESSION ".+\\.ptx$")
  source_group("CUDA Files" REGULAR_EXPRESSION ".+\\.cu$")

  # Separate the sources from the CMake and CUDA options fed to the macro.  This code
  # comes from the CUDA_COMPILE_PTX macro found in FindCUDA.cmake.  We are copying the
  # code here, so that we can use our own name for the target.  target_name is used in the
  # creation of the output file names, and we want this to be unique for each target in
  # the SDK.
  CUDA_GET_SOURCES_AND_OPTIONS(source_files cmake_options options ${ARGN})

  # Create the rules to build the PTX from the CUDA files.
  CUDA_WRAP_SRCS( ${target_name} PTX generated_files ${source_files} ${cmake_options}
    OPTIONS ${options} )

  # Here is where we create the rule to make the executable.  We define a target name and
  # list all the source files used to create the target.  In addition we also pass along
  # the cmake_options parsed out of the arguments.
  add_executable(${target_name}
    ${source_files}
    ${generated_files}
    ${cmake_options}
    )

  # Most of the samples link against the sutil library and the optix library.  Here is the
  # rule that specifies this linkage.
  target_link_libraries( ${target_name}
    sutil
    optix
    ${optix_rpath}
    )
endfunction()

安装Nvidia Optix SDK 3.0.0 Ubuntu 12.04

1 个答案: