Question

我有一个字符数组，我想要获取任何字符，并且能够循环遍历该数组并找到最接近的3个（使用Point.distance）邻居。谁能让我知道如何做到这一点？

Answer 1

这是我昨晚发布的代码的新版本和改进版。它由两个类组成，PointTester和TestCase。这次我能够测试它！

我们从TestCase.as开始

package  {

    import flash.geom.Point;
    import flash.display.Sprite;

    public class TestCase extends Sprite {

        public function TestCase() {
            // some data to test with
            var pointList:Array = new Array();
            pointList.push(new Point(0, 0));
            pointList.push(new Point(0, 0));
            pointList.push(new Point(0, 0));
            pointList.push(new Point(1, 2));
            pointList.push(new Point(9, 9));

            // the point we want to test against
            var referencePoint:Point = new Point(10, 10);

            var resultPoints:Array = PointTester.findClosest(referencePoint, pointList, 3);

            trace("referencePoint is at", referencePoint.x, referencePoint.y);
            for each(var result:Object in resultPoints) {
                trace("Point is at:", result.point.x, ", ", result.point.y, " that's ", result.distance, " units away");
            }
        }

    }

}

这将是PointTester.as

package  {

    import flash.geom.Point;

    public class PointTester {

        public static function findClosest(referencePoint:Point, pointList:Array, maxCount:uint = 3):Array{

            // this array will hold the results
            var resultList:Array = new Array();

            // loop over each point in the test data
            for each (var testPoint:Point in pointList) {

                // we store the distance between the two in a temporary variable
                var tempDistance:Number = getDistance(testPoint, referencePoint);

                // if the list is shorter than the maximum length we don't need to do any distance checking
                // if it's longer we compare the distance to the last point in the list, if it's closer we add it
                if (resultList.length <= maxCount || tempDistance < resultList[resultList.length - 1].distance) {

                    // we store the testing point and it's distance to the reference point in an object
                    var tmpObject:Object = { distance : tempDistance, point : testPoint };
                    // and push that onto the array
                    resultList.push(tmpObject);

                    // then we sort the array, this way we don't need to compare the distance to any other point than
                    // the last one in the list
                    resultList.sortOn("distance", Array.NUMERIC );

                    // and we make sure the list is kept at at the proper number of entries
                    while (resultList.length > maxCount) resultList.pop();
                }
            }

            return resultList;
        }

        public static function getDistance(point1:Point, point2:Point):Number {
            var x:Number = point1.x - point2.x;
            var y:Number = point1.y - point2.y;
            return Math.sqrt(x * x + y * y);
        }
    }
}

Answer 2

值得一提的是，如果点的数量足够大以使性能变得重要，那么通过保留两个点列表可以更快地实现目标，一个点由X排序，另一个点由Y排序。然后可以通过遍历每个点在O（logn）时间而不是O（n）时间找到最接近的3个点。

Answer 3

如果您使用grapefrukt的解决方案，您可以将getDistance方法更改为return x*x + y*y;而不是return Math.sqrt( x * x + y * y );

在Actionscript 3中找到前3个最接近的目标

3 个答案: