ColdFusion“是”eq“True”; “没有”eq“错误

时间：2013-03-19 08:10:25

标签： coldfusion

为什么？

<cfif "yes" eq "true">

Yes equals true.

<cfelse>

Yes does not equal true.

</cfif>

页面输出。 “是的，这是真的。”

6 个答案:

答案 0 :(得分：13)

Chris'和Keshav的答案是正确的，ColdFusion会转换价值观。以下是有关ColdFusion数据转换的官方文档。

Conversion between types 

Value     As Boolean     As number     As date-time     As string

"Yes"     True           1             Error            "Yes"

"No"      False          0             Error            "No"

True      True           1             Error            "Yes"

False     False          0             Error            "No"

答案 1 :(得分：10)

ColdFusion具有动态变量类型，并且在运行时进行一些奇怪的转换，字符串可以用作布尔值，日期和数字而不用它们进行转换，这既有优点也有缺点。

如果您需要进行简单的字符串比较，可以使用内置的compare（）函数。

Ben Nadel在此提供了一个很好的字符串比较选项摘要 - http://www.bennadel.com/blog/236-ColdFusion-String-Comparison-Compare-vs-Equals-vs-CompareTo-.htm

答案 2 :(得分：3)

你必须非常小心真/假的比较。它们应该很简单，但有时候，根据您编写代码的方式，TRUE / FALSE的评估可能会有所不同。通过几乎每个定义，FALSE将始终为按位0（和CF中的否）。 TRUE将按位1，但也是和任何非0数字。所以42仍然是真的。并且-1仍为TRUE（特别感谢MS Access是/否数据类型:-p）。

由于FALSE始终为0（或NO或FALSE），检查NOT FALSE或NEQ 0通常比检查TRUE更好。然而，即便如此，你仍然要小心。确定您要考虑的内容为真，并对此进行全面评估。 ColdFusion有时会以不同方式转换TRUE和FALSE变量。查看以下代码的结果：

（感谢Bert Dawson和Jamie Jackson提供的querySim脚本。）

<!--- set up the fake query: --->
<cfscript>
/**
 * Accepts a specifically formatted chunk of text, and returns it as a query object.
 * v2 rewrite by Jamie Jackson
 * 
 * @param queryData      Specifically format chunk of text to convert to a query. (Required)
 * @return Returns a query object. 
 * @author Bert Dawson (bert@redbanner.com) 
 * @version 2, December 18, 2007 
 */
function querySim(queryData) {
    var fieldsDelimiter="|";
    var colnamesDelimiter=",";
    var listOfColumns="";
    var tmpQuery="";
    var numLines="";
    var cellValue="";
    var cellValues="";
    var colName="";
    var lineDelimiter=chr(10) & chr(13);
    var lineNum=0;
    var colPosition=0;

    // the first line is the column list, eg "column1,column2,column3"
    listOfColumns = Trim(ListGetAt(queryData, 1, lineDelimiter));

    // create a temporary Query
    tmpQuery = QueryNew(listOfColumns);

    // the number of lines in the queryData
    numLines = ListLen(queryData, lineDelimiter);

    // loop though the queryData starting at the second line
    for(lineNum=2;  lineNum LTE numLines;  lineNum = lineNum + 1) {
        cellValues = ListGetAt(queryData, lineNum, lineDelimiter);

        if (ListLen(cellValues, fieldsDelimiter) IS ListLen(listOfColumns,",")) {
            QueryAddRow(tmpQuery);
            for (colPosition=1; colPosition LTE ListLen(listOfColumns); colPosition = colPosition + 1){
                cellValue = Trim(ListGetAt(cellValues, colPosition, fieldsDelimiter));
                colName   = Trim(ListGetAt(listOfColumns,colPosition));
                QuerySetCell(tmpQuery, colName, cellValue);
            }
        } 
    }
    return( tmpQuery );
}
</cfscript>

<!--- populate the fake query --->    
<cfscript>
fakeQuery = querySim('
testID , isThisTruthy
1 | TRUE
2 | FALSE
3 | YES
4 | NO
5 | 1
6 | 0
7 | -1
8 | 42
');
</cfscript>
<!--- End of the fake query setup --->

<!--- Dump the fakeQuery so we can see what we've got. --->
<cfdump var="#fakeQuery#" label="fakeQueryInfo" />

<!--- 
    Not really necessary since the query is created above. Just included for 
    clarity, as everything above this line can really be ignored if connecting 
    to a real query. 
--->
<cfquery name="truthyCheck" dbtype="query">
    SELECT testID, isThisTruthy
    FROM fakeQuery
</cfquery>

<!--- Begin the truthy statements. --->
<br/><br/>
<strong>cfif isThisTruthy >></strong> 
<!--- 
    This one has an implicit evaluation of TRUE or FALSE that seems to be based on a
    broader (and more accurate) definition of what should be TRUE or FALSE. However,
    it's much less clear in what you're trying to do. 
--->
<br/>
<cfoutput query="truthyCheck">
    #testID#: #isThisTruthy# | <cfif isThisTruthy>True<cfelseif NOT isThisTruthy>False<cfelse>NULL</cfif> <br/>
</cfoutput>
<br/><br/>

<!--- 
    The rest of these appear to actually evaluate down to a bit (using the standard
    1,0,YES,NO,TRUE,FALSE definitions) and then they do an integer comparison. This 
    may not be completely what you're looking for.
--->
<strong>cfif isThisTruthy IS TRUE >></strong>
<br/>
<cfoutput query="truthyCheck">
    #testID#: #isThisTruthy# | <cfif isThisTruthy IS TRUE>True<cfelseif isThisTruthy IS NOT TRUE>False<cfelse>NULL</cfif> 
    <!--- 1 IS 1 IS TRUE, but -1 IS 1 IS FALSE. --->
    <br/>
</cfoutput>
<br/><br/>
<strong>cfif isThisTruthy EQ 1 >></strong>
<br/>
<cfoutput query="truthyCheck">
    #testID#: #isThisTruthy# | <cfif isThisTruthy EQ 1>True<cfelseif isThisTruthy NEQ 1>False<cfelse>NULL</cfif> 
    <!--- 1 EQ 1 IS TRUE, but -1 EQ 1 IS FALSE. --->
    <br/>
</cfoutput>
<br/><br/>
<strong>cfif isThisTruthy NEQ 0 >></strong>
<br/>
<cfoutput query="truthyCheck">
    #testID#: #isThisTruthy# | <cfif isThisTruthy NEQ 0>True<cfelseif isThisTruthy EQ 0>False<cfelse>NULL</cfif> 
    <!--- 1 NEQ 0 and -1 NEQ 0 both evaluate to the same. --->
    <br/>
</cfoutput>
<br/><br/>
<strong>cfif isThisTruthy NEQ FALSE >></strong>
<br/>
<cfoutput query="truthyCheck">
    #testID#: #isThisTruthy# | <cfif isThisTruthy NEQ FALSE>True<cfelseif isThisTruthy EQ FALSE>False<cfelse>NULL</cfif> 
    <!--- 1 NEQ 0 and -1 NEQ 0 both evaluate to the same. --->
    <br/>
</cfoutput>

你会得到：

cfif isThisTruthy＆gt;＆gt;
1：TRUE |真的 2：FALSE |假的 3：是|真的 4：没有|假的 5：1 |真的 6：0 |假的 7：-1 | True ＆lt; ---技术上正确
8:42 | True ＆lt; ---技术上正确

cfif isThisTruthy IS TRUE＆gt;＆gt;
1：TRUE |真的 2：FALSE |假的 3：是|真的 4：没有|假的 5：1 |真的 6：0 |假的 7：-1 |错误＆lt; ---技术上不正确
8:42 |错误＆lt; ---技术上不正确

cfif isThisTruthy EQ 1＆gt;＆gt;
1：TRUE |真的 2：FALSE |假的 3：是|真的 4：没有|假的 5：1 |真的 6：0 |假的 7：-1 |错误＆lt; ---技术上不正确
8:42 |错误＆lt; ---技术上不正确

cfif isThisTruthy NEQ 0＆gt;＆gt;
1：TRUE |真的 2：FALSE |假的 3：是|真的 4：没有|假的 5：1 |真的 6：0 |假的 7：-1 | True ＆lt; ---技术上正确
8:42 | True ＆lt; ---技术上正确

cfif isThisTruthy NEQ FALSE＆gt;＆gt;
1：TRUE |真的 2：FALSE |假的 3：是|真的 4：没有|假的 5：1 |真的 6：0 |假的 7：-1 | True ＆lt; ---技术上正确
8:42 | True ＆lt; ---技术上正确

答案 3 :(得分：2)

在ColdFusion中，“yes”和“true”在用作表达式时都会转换为数值1

答案 4 :(得分：1)

是的，1和true在coldFusion中是相同的。如此链接中所示：

http://help.adobe.com/en_US/ColdFusion/9.0/Developing/WSc3ff6d0ea77859461172e0811cbec09af4-7fd0.html

答案 5 :(得分：0)

在coldfusion中，“yes”和“true”被解释为bit（1）同样“no”和“false”被解释为bit（0），因此“yes”和“true”相等。以同样的方式

<cfif 1 eq "true">

Yes equals true.

</cfif>
相关问题
最新问题