Question

我有一个INI文件，用于存储设置的一些整数。部分名称存储如下：

[ColorScheme_2]
name=Dark Purple Gradient
BackgroundColor=224
BackgroundBottom=2
BackgroundTop=25
...

[ColorScheme_3]
name=Retro
BackgroundColor=5
BackgroundBottom=21
BackgroundTop=8
...

我需要想办法创建新的部分，从最高的部分编号增加颜色方案编号+1。我有一个comboBox列出了当前的colorscheme名称，所以当用户保存到INI文件时，现有的方案就会被覆盖。如何检查ComboBox文本以查看它是否是现有部分，如果不是，请创建一个具有递增名称的新文本？（即，从上面的示例代码中，ColorScheme_2和ColorScheme_3已经存在，因此要创建的下一部分将是ColorScheme_4）。

Answer 1

您可以使用ReadSections方法阅读所有部分，然后迭代返回的字符串列表并解析其中的每个项目以存储找到的最高索引值：

uses
  IniFiles;

function GetMaxSectionIndex(const AFileName: string): Integer;
var
  S: string;
  I: Integer;
  Index: Integer;
  IniFile: TIniFile;
  Sections: TStringList;
const
  ColorScheme = 'ColorScheme_';
begin
  Result := 0;
  IniFile := TIniFile.Create(AFileName);
  try
    Sections := TStringList.Create;
    try
      IniFile.ReadSections(Sections);
      for I := 0 to Sections.Count - 1 do
      begin
        S := Sections[I];
        if Pos(ColorScheme, S) = 1 then
        begin
          Delete(S, 1, Length(ColorScheme));
          if TryStrToInt(S, Index) then
            if Index > Result then
              Result := Index;
        end;
      end;
    finally
      Sections.Free;
    end;
  finally
    IniFile.Free;
  end;
end;

用法：

procedure TForm1.Button1Click(Sender: TObject);
begin
  ShowMessage(IntToStr(GetMaxSectionIndex('d:\Config.ini')));
end;

Answer 2

如何查看ComboBox文本以查看它是否为现有部分，如果没有，请创建一个名称递增的新文本？

像这样：

const
  cPrefix = 'ColorScheme_';
var
  Ini: TIniFile;
  Sections: TStringList;
  SectionName: String;
  I, Number, MaxNumber: Integer;
begin
  Ini := TIniFile.Create('myfile.ini')
  try
    SectionName := ComboBox1.Text;
    Sections := TStringList.Create;
    try
      Ini.ReadSections(Sections);
      Sections.CaseSensitive := False;
      if Sections.IndexOf(SectionName) = -1 then
      begin
        MaxNumber := 0;
        for I := 0 to Sections.Count-1 do
        begin
          if StartsText(cPrefix, Sections[I]) then
          begin
            if TryStrToInt(Copy(Sections[I], Length(cPrefix)+1, MaxInt), Number) then
            begin
              if Number > MaxNumber then
                MaxNumber := Number;
            end;
          end;
        end;
        SectionName := Format('%s%d', [cPrefix, MaxNumber+1]);
      end;
    finally
      Sections.Free;
    end;
    // use SectionName as needed...
  finally
    Ini.Free;
  end;
end;

增加INI文件节号

2 个答案: