Question

我正在使用 VB6 ，我想创建一个在局域网上运行的聊天应用程序。我使用了 WinSock 控件，但是当我运行Listen()函数时，我的套接字只是侦听127.0.0.1而不是我的计算机在局域网上的IP。

为什么呢？有没有办法在局域网上监听我的IP？

Answer 1

通常，您可以调用Bind方法来设置本地端口，并可选择指定要使用的适配器的本地IP地址。它应默认为系统的主适配器。然后你在没有参数的情况下调用Listen。

您可以跳过Bind，然后设置LocalPort然后设置Listen，但除了简单的单连接服务器方案外，这是不可取的。

这些都没有解释为什么默认选择你的环回地址。听起来像盒子上的某种网络配置问题。

Answer 2

我相信你可以在监听时设置控件上的RemoteHost属性，以确定服务器将侦听哪个网络地址。要收听所有网络接口，您可以使用：

WinSock1.RemoteHost = "0.0.0.0"
WinSock1.Lsten()

Answer 3

您需要设置localport属性（并且客户端需要连接到该端口）

'1 form with :
'  1 textbox : name=Text1
'  1 winsock control : name=Winsock1

Option Explicit

Private Sub Form_Load()
  Text1.Move 0, 0, ScaleWidth, ScaleHeight 'position the textbox
  With Winsock1
    .LocalPort = 5001                      'set the port to listen on
    .Listen                                'start listening
  End With 'Winsock1
End Sub

Private Sub Winsock1_ConnectionRequest(ByVal requestID As Long)
  With Winsock1
    If .State <> sckClosed Then .Close     'close the port when not closed (you could also use another winsock control to accept the connection)
    .Accept requestID                      'accept the connection request
  End With 'Winsock1
End Sub

Private Sub Winsock1_DataArrival(ByVal bytesTotal As Long)
  Dim strData As String
  Winsock1.GetData strData                 'get the data
  ProcessData strData                      'process the data
End Sub

Private Sub Winsock1_Error(ByVal Number As Integer, Description As String, ByVal Scode As Long, ByVal Source As String, ByVal HelpFile As String, ByVal HelpContext As Long, CancelDisplay As Boolean)
  MsgBox Description, vbCritical, "Error " & CStr(Number)
End Sub

Private Sub ProcessData(strData As String)
  Text1.SelText = strData                  'show the data
End Sub

Winsock的Listen（）函数

3 个答案: