Question

我确定我是昏暗的并且错过了显而易见的但是有一种简单的方法可以使用当前类别作为配置文件中的文件名而无需借助子程序调用吗？

因此，在下面的内容中可以使用${category}.log而不是在文件名行中重复bin.nh.tpp

log4perl.logger.**bin.nh.tpp**=INFO, BIN_NH_TPP_LOGFILE

log4perl.appender.BIN_NH_TPP_LOGFILE=Log::Log4perl::Appender::File
log4perl.appender.BIN_NH_TPP_LOGFILE.filename=${LOGS}/nh/**bin.nh.tpp**.log
log4perl.appender.BIN_NH_TPP_LOGFILE.mode=append
log4perl.appender.BIN_NH_TPP_LOGFILE.layout=PatternLayout
log4perl.appender.BIN_NH_TPP_LOGFILE.layout.ConversionPattern=[%d] %F{1} %L %c - %m%n

Answer 1

我担心它比一个子程序更复杂。 l4p conf文件中的子程序允许包括在conf文件解析时已知的变量，例如，时间/日期或用户ID。您无法以这种方式修改日志时间行为。

我现在想到的最简单的方法就是实现你想要的东西，比如

package FileByCategoryAppender;

use warnings;
use strict;
use base qw( Log::Log4perl::Appender::File );

sub new {
    my( $class, %options ) = @_;

    $options{filename } = "no-category.log";
    my $self = $class->SUPER::new( %options );
    bless $self, $class;
}

sub log {
    my( $self, %params ) = @_;

    my $category = $params{ log4p_category };
    $self->SUPER::file_switch( $category . ".log" );
    $self->SUPER::log( %params );
}

1;

然后在您的脚本中使用它，如

use strict;
use warnings;

use Log::Log4perl qw( get_logger );

my $conf = q(
log4perl.category         = WARN, Logfile
log4perl.appender.Logfile = FileByCategoryAppender
log4perl.appender.Logfile.create_at_logtime = 1
log4perl.appender.Logfile.layout = \
  Log::Log4perl::Layout::PatternLayout
log4perl.appender.Logfile.layout.ConversionPattern = %d %F{1} %L> %m %n
);

Log::Log4perl::init(\$conf);

my $logger = get_logger("Bar::Twix");
$logger->error("twix error");

$logger = get_logger("Bar::Mars");
$logger->error("mars error");

将导致在日志时创建两个日志文件：

# Bar.Mars.log
2012/11/18 11:12:12 t 21> mars error

和

# Bar.Twix.log
2012/11/18 11:12:12 t 21> twix error

Log4perl类别作为日志文件名

1 个答案: