Question

我正在尝试保护包含敏感信息的本地数据库（类似于this question，仅限 for delphi 2010 ）

我正在使用DISQLite component，它支持AES加密，但我仍然需要保护我用来解密的密码。阅读数据库。

我最初的想法是生成一个随机密码，使用DPAPI（Crypt32.dll中找到的CryptProtectData和CryptUnprotectData函数）存储它，但我找不到任何关于它的示例Delphi的

我的问题是：如何安全地存储随机生成的密码？或者，假设DPAPI之路是安全的，我如何在Delphi中实现这个DPAPI？

Answer 1

最好使用Windows“DPAPI。它比使用其他方法更安全：

CryptProtectData / CryptProtectMemory
CryptUnprotectData / CryptUnprotectMemory

CryptProtectMemory / CryptUnprotectMemory提供了更大的灵活性：

CRYPTPROTECTMEMORY_SAME_PROCESS：只有您的流程可以解密您的数据
CRYPTPROTECTMEMORY_CROSS_PROCESS：任何进程都可以解析您的数据
CRYPTPROTECTMEMORY_SAME_LOGON：只有使用同一用户并且在同一会话中运行的进程才能解密数据

优点：

无需钥匙 - Windows do it for you
粒度控制：每个进程/每个会话/每个登录/每台机器
CryptProtectData存在于Windows 2000及更新版本
DPAPI Windows比使用你写的“安全”相关代码更安全，我和相信Random（）的人绝对随机返回数字:)事实上，微软在安全领域拥有数十年的经验，受到的攻击最多操作系统：o）

缺点：

在CRYPTPROTECTMEMORY_SAME_PROCESS的情况下，一个*可以在您的流程中注入一个新线程，该线程可以解密您的数据
如果有人重置用户密码（不更改），您将无法解密数据
在CRYPTPROTECTMEMORY_SAME_LOGON的情况下：如果用户*运行被黑客攻击的进程，它可以解密您的数据
如果您使用CRYPTPROTECT_LOCAL_MACHINE - 该计算机上的每个用户*都可以解密数据。 This is why it's not recommended to save passwords in .RDP files
Known issues

注意：“每个用户”都是拥有使用DPAPI的工具或技能的用户

无论如何 - 你可以选择。

请注意@ David-Heffernan是对的 - 计算机上存储的任何内容都可以解密 - 从内存中读取，在进程中注入线程等。

另一方面......为什么我们不让饼干的生活变得更难？：）

经验法则：使用后清除包含敏感数据的所有缓冲区。这不会使事情变得非常安全，但会降低内存中包含敏感数据的可能性。当然，这并没有解决其他主要问题：其他Delphi组件如何处理传递给它们的敏感数据：）

Security Library by JEDI具有面向对象的DPAPI方法。此外，JEDI项目包含DPAPI（JWA IIRC）的已翻译窗口标题

更新：以下是使用DPAPI的示例代码（使用JEDI API）：

Uses SysUtils, jwaWinCrypt, jwaWinBase, jwaWinType;

function dpApiProtectData(var fpDataIn: tBytes): tBytes;
var
  dataIn,               // Input buffer (clear-text/data)
  dataOut: DATA_BLOB;   // Output buffer (encrypted)
begin
  // Initializing variables
  dataOut.cbData := 0;
  dataOut.pbData := nil;

  dataIn.cbData := length(fpDataIn); // How much data (in bytes) we want to encrypt
  dataIn.pbData := @fpDataIn[0];     // Pointer to the data itself - the address of the first element of the input byte array

  if not CryptProtectData(@dataIn, nil, nil, nil, nil, 0, @dataOut) then
    RaiseLastOSError; // Bad things happen sometimes

  // Copy the encrypted bytes to RESULT variable
  setLength(result, dataOut.cbData);
  move(dataOut.pbData^, result[0], dataOut.cbData);
  LocalFree(HLOCAL(dataOut.pbData));                  // http://msdn.microsoft.com/en-us/library/windows/desktop/aa380261(v=vs.85).aspx
//  fillChar(fpDataIn[0], length(fpDataIn), #0);  // Eventually erase input buffer i.e. not to leave sensitive data in memory
end;

function dpApiUnprotectData(fpDataIn: tBytes): tBytes;
var
  dataIn,               // Input buffer (clear-text/data)
  dataOut: DATA_BLOB;   // Output buffer (encrypted)
begin
  dataOut.cbData := 0;
  dataOut.pbData := nil;

  dataIn.cbData := length(fpDataIn);
  dataIn.pbData := @fpDataIn[0];

  if not CryptUnprotectData(
    @dataIn,  
    nil, 
    nil, 
    nil, 
    nil, 
    0,         // Possible flags: http://msdn.microsoft.com/en-us/library/windows/desktop/aa380261%28v=vs.85%29.aspx 
               // 0 (zero) means only the user that encrypted the data will be able to decrypt it
    @dataOut
  ) then
    RaiseLastOSError;

  setLength(result, dataOut.cbData);                  // Copy decrypted bytes in the RESULT variable
  move(dataOut.pbData^, result[0], dataOut.cbData);   
  LocalFree(HLOCAL(dataOut.pbData));                  // http://msdn.microsoft.com/en-us/library/windows/desktop/aa380882%28v=vs.85%29.aspx
end;

procedure testDpApi;
var
  bytesClearTextIn,       // Holds input bytes
  bytesClearTextOut,      // Holds output bytes
  bytesEncrypted: tBytes; // Holds the resulting encrypted bytes
  strIn, strOut: string;  // Input / Output strings
begin

  // *** ENCRYPT STRING TO BYTE ARRAY
  strIn := 'Some Secret Data Here';

  // Copy string contents to bytesClearTextIn
  // NB: this works for STRING type only!!! (AnsiString / UnicodeString)
  setLength(bytesClearTextIn, length(strIn) * sizeOf(char));
  move(strIn[1], bytesClearTextIn[0], length(strIn) * sizeOf(char));

  bytesEncrypted := dpApiProtectData(bytesClearTextIn);     // Encrypt data

  // *** DECRYPT BYTE ARRAY TO STRING
  bytesClearTextOut := dpApiUnprotectData(bytesEncrypted);  // Decrypt data

  // Copy decrypted bytes (bytesClearTextOut) to the output string variable
  // NB: this works for STRING type only!!! (AnsiString / UnicodeString)    
  setLength(strOut, length(bytesClearTextOut) div sizeOf(char));
  move(bytesClearTextOut[0], strOut[1], length(bytesClearTextOut));

  assert(strOut = strIn, 'Boom!');  // Boom should never booom :)

end;

注意：

该示例是使用CryptProtectData / CryptUnprotectData;
加密是面向字节的，因此更容易使用tBytes（tBytes = byte of array）;
如果输入和输出字符串是UTF8String，则删除“* sizeOf（char）”，因为UTF8String的char只有1个字节
使用CryptProtectMemory / CryptUnProtectMemory类似

Answer 2

如果您的问题只是让用户不必每次都输入密码，那么您应该知道Windows已经有密码存储系统。

如果您转到控制面板 - ＆gt; 凭据管理器。从那里你正在寻找 Windows凭证 - ＆gt; 通用凭据。

从那里你可以看到存储远程桌面密码之类的地方是同一个地方：

公开此功能的API是CredRead，CredWrite和CredDelete。

我把它们包含在三个功能中：

function CredReadGenericCredentials(const Target: UnicodeString; var Username, Password: UnicodeString): Boolean;
function CredWriteGenericCredentials(const Target, Username, Password: UnicodeString): Boolean;
function CredDeleteGenericCredentials(const Target: UnicodeString): Boolean;

目标是识别凭证的东西。我通常使用应用程序名称。

String target = ExtractFilename(ParamStr(0)); //e.g. 'Contoso.exe'

那么它只是：

CredWriteGenericCredentials(ExtractFilename(ParamStr(0)), username, password);

然后，您可以在凭据管理器中看到它们：

当你想要阅读它们时：

CredReadGenericCredentials(ExtractFilename(ParamStr(0)), {var}username, {var}password);

您需要执行额外的UI工作：

检测到没有存储的凭据，并提示用户提供凭据
检测到保存的用户名/密码无效并提示输入新的/正确的凭据，尝试连接并保存新的正确凭据

阅读存储的凭据：

function CredReadGenericCredentials(const Target: UnicodeString; var Username, Password: UnicodeString): Boolean;
var
    credential: PCREDENTIALW;
    le: DWORD;
    s: string;
begin
    Result := False;

    credential := nil;
    if not CredReadW(Target, CRED_TYPE_GENERIC, 0, {var}credential) then
    begin
        le := GetLastError;
        s := 'Could not get "'+Target+'" generic credentials: '+SysErrorMessage(le)+' '+IntToStr(le);
        OutputDebugString(PChar(s));
        Exit;
    end;

    try
        username := Credential.UserName;
        password := WideCharToWideString(PWideChar(Credential.CredentialBlob), Credential.CredentialBlobSize div 2); //By convention blobs that contain strings do not have a trailing NULL.
    finally
        CredFree(Credential);
    end;

    Result := True;
end;

编写存储的凭证：

function CredWriteGenericCredentials(const Target, Username, Password: UnicodeString): Boolean;
var
    persistType: DWORD;
    Credentials: CREDENTIALW;
    le: DWORD;
    s: string;
begin
    ZeroMemory(@Credentials, SizeOf(Credentials));
    Credentials.TargetName := PWideChar(Target); //cannot be longer than CRED_MAX_GENERIC_TARGET_NAME_LENGTH (32767) characters. Recommended format "Company_Target"
    Credentials.Type_ := CRED_TYPE_GENERIC;
    Credentials.UserName := PWideChar(Username);
    Credentials.Persist := CRED_PERSIST_LOCAL_MACHINE;
    Credentials.CredentialBlob := PByte(Password);
    Credentials.CredentialBlobSize := 2*(Length(Password)); //By convention no trailing null. Cannot be longer than CRED_MAX_CREDENTIAL_BLOB_SIZE (512) bytes
    Credentials.UserName := PWideChar(Username);
    Result := CredWriteW(Credentials, 0);
    end;
end;

然后删除：

function CredDeleteGenericCredentials(const Target: UnicodeString): Boolean;
begin
    Result := CredDelete(Target, CRED_TYPE_GENERIC);
end;

CredRead是CryptProtectData

的包装器

应该注意CredWrite / CredRead内部使用CryptProtectData。

它还选择在适合的地方存储凭据
它还为用户提供了一个用户界面，可以查看，管理甚至手动输入和更改已保存的凭据

自己使用CryptProtectData的不同之处在于，您只获得了一个blob。由您决定将其存储在某个地方，并在以后检索它。

存储密码时，CryptProtectData和CryptUnprotectData周围的包装很好：

function EncryptString(const Plaintext: UnicodeString; const AdditionalEntropy: UnicodeString): TBytes;
function DecryptString(const Blob: TBytes; const AdditionalEntropy: UnicodeString): UnicodeString;

这很容易使用：

procedure TForm1.TestStringEncryption;
var
    encryptedBlob: TBytes;
    plainText: UnicodeString;
const
    Salt = 'Salt doesn''t have to be secret; just different from the next application';
begin
    encryptedBlob := EncryptString('correct battery horse staple', Salt);

    plainText := DecryptString(encryptedBlob, salt);

    if plainText <> 'correct battery horse staple' then
        raise Exception.Create('String encryption self-test failed');
end;

实际的胆量是：

type
    DATA_BLOB = record
            cbData: DWORD;
            pbData: PByte;
    end;
    PDATA_BLOB = ^DATA_BLOB;

const
    CRYPTPROTECT_UI_FORBIDDEN = $1;

function CryptProtectData(const DataIn: DATA_BLOB; szDataDescr: PWideChar; OptionalEntropy: PDATA_BLOB; Reserved: Pointer; PromptStruct: Pointer{PCRYPTPROTECT_PROMPTSTRUCT}; dwFlags: DWORD; var DataOut: DATA_BLOB): BOOL; stdcall; external 'Crypt32.dll' name 'CryptProtectData';
function CryptUnprotectData(const DataIn: DATA_BLOB; szDataDescr: PPWideChar; OptionalEntropy: PDATA_BLOB; Reserved: Pointer; PromptStruct: Pointer{PCRYPTPROTECT_PROMPTSTRUCT}; dwFlags: DWORD; var DataOut: DATA_BLOB): Bool; stdcall; external 'Crypt32.dll' name 'CryptUnprotectData';

function EncryptString(const Plaintext: UnicodeString; const AdditionalEntropy: UnicodeString): TBytes;
var
    blobIn: DATA_BLOB;
    blobOut: DATA_BLOB;
    entropyBlob: DATA_BLOB;
    pEntropy: Pointer;
    bRes: Boolean;
begin
    blobIn.pbData := Pointer(PlainText);
    blobIn.cbData := Length(PlainText)*SizeOf(WideChar);

    if AdditionalEntropy <> '' then
    begin
        entropyBlob.pbData := Pointer(AdditionalEntropy);
        entropyBlob.cbData := Length(AdditionalEntropy)*SizeOf(WideChar);
        pEntropy := @entropyBlob;
    end
    else
        pEntropy := nil;

    bRes := CryptProtectData(
            blobIn,
            nil, //data description (PWideChar)
            pentropy, //optional entropy (PDATA_BLOB)
            nil, //reserved
            nil, //prompt struct
            CRYPTPROTECT_UI_FORBIDDEN, //flags
            {var}blobOut);
    if not bRes then
        RaiseLastOSError;

    //Move output blob into resulting TBytes
    SetLength(Result, blobOut.cbData);
    Move(blobOut.pbData^, Result[0], blobOut.cbData);

    // When you have finished using the DATA_BLOB structure, free its pbData member by calling the LocalFree function
    LocalFree(HLOCAL(blobOut.pbData));
end;

并解密：

function DecryptString(const blob: TBytes; const AdditionalEntropy: UnicodeString): UnicodeString;
var
    dataIn: DATA_BLOB;
    entropyBlob: DATA_BLOB;
    pentropy: PDATA_BLOB;
    dataOut: DATA_BLOB;
    bRes: BOOL;
begin
    dataIn.pbData := Pointer(blob);
    dataIn.cbData := Length(blob);

    if AdditionalEntropy <> '' then
    begin
        entropyBlob.pbData := Pointer(AdditionalEntropy);
        entropyBlob.cbData := Length(AdditionalEntropy)*SizeOf(WideChar);
        pentropy := @entropyBlob;
    end
    else
        pentropy := nil;

    bRes := CryptUnprotectData(
            DataIn,
            nil, //data description (PWideChar)
            pentropy, //optional entropy (PDATA_BLOB)
            nil, //reserved
            nil, //prompt struct
            CRYPTPROTECT_UI_FORBIDDEN,
            {var}dataOut);
    if not bRes then
        RaiseLastOSError;

    SetLength(Result, dataOut.cbData div 2);
    Move(dataOut.pbData^, Result[1], dataOut.cbData);
    LocalFree(HLOCAL(DataOut.pbData));
end;

Answer 3

好的，这是使用TurboPower Lockbox的示例（版本2 ）

  uses LbCipher, LbString;

  TaAES = class
  private
    Key: TKey256;
    FPassword: string;
  public
    constructor Create;

    function Code(AString: String): String;
    function Decode(AString: String): String;

    property Password: string read FPassword write FPassword;
  end;

function TaAES.Code(AString: String): String;
begin
  try
    RESULT := RDLEncryptStringCBCEx(AString, Key, SizeOf(Key), False);
  except
    RESULT := '';
  end;
end;

constructor TaAES.Create;
begin
  GenerateLMDKey(Key, SizeOf(Key), Password);
end;

function TaAES.Decode(AString: String): String;
begin
  RESULT := RDLEncryptStringCBCEx(AString, Key, SizeOf(Key), True);
end;

您可以将密码保存为应用程序中的变量。没有保存到文件示例，但您可以使用TFileStream保存加密的（code）密码，然后使用decode来读取它： - ）

在Windows中存储密码的安全方式

3 个答案:

CredRead是CryptProtectData