Question

这与这个问题有关：

how-to-have-emacs-helm-list-offer-files-in-current-directory-as-options

但是我希望能够拥有一个固定的目录列表，而不是从当前目录中添加文件，而helm-mini总是会提供这些目录。理想情况下，我希望能够只使用具有特定扩展名的文件，并且我希望这是递归完成的（事实上只有一层深度）。

Answer 1

以下是组织扩展的预过滤器略有不同。

(require 'helm-cmd-t)

(defvar my-org-folders (list  "~/org")
  "my permanent folders for helm-mini")

(defun helm-my-org (&optional arg)
  "Use C-u arg to work with repos."
  (interactive "P")
  (if (consp arg)
      (call-interactively 'helm-cmd-t-repos)
    (let ((helm-ff-transformer-show-only-basename nil))
      (helm :sources (mapcar (lambda (dir)
                               (helm-cmd-t-get-create-source-dir dir))
                             my-org-folders)
            :candidate-number-limit 20
            :buffer "*helm-my-org:*"
            :input "org$ "))))

Answer 2

您可以通过利用helm-cmd-t库来更好地解决问题。它打包递归目录作为可用作源的存储库。

它了解如何快速阅读大量DVCS回购。

默认功能与您在此之后不完全相同，但您可以轻松利用机器来满足您的所有要求。

例如，在这里我定义了一个命令，它将两个repos添加到默认值掌舵迷你消息来源。

(require 'helm-cmd-t)

(defvar my-mini-folders (list  "~/src/ember/data" "~/src/ember/ember.js")
  "my permanent folders for helm-mini")

(defun helm-my-mini (&optional arg)
  "my helm-mini.  Use C-u arg to work with repos."
  (interactive "P")
  (if (consp arg)
      (call-interactively 'helm-cmd-t-repos)
    (let ((helm-ff-transformer-show-only-basename nil))
      (helm :sources (nconc (list
                             helm-c-source-buffers-list
                             helm-c-source-recentf
                             helm-c-source-buffer-not-found)
                            (mapcar (lambda (dir)
                                      (helm-cmd-t-get-create-source-dir dir))
                                    my-mini-folders))
            :candidate-number-limit 20
            :buffer "*helm-my-mini:*"))))

Answer 3

你走了。我使用此代码列出特定目录中的所有组织文件。如果要列出所有文件，只需删除源中的候选变换器行，然后删除emagician / helm-ct-is-org文件。

您可能也想重命名源/变量/函数。 ;）

编辑：已修复，感谢窥探helm-cmd-t

注意：这是我制作掌舵源时的第一次真正的破解，这种实施可能很糟糕。它还专门解决了我的问题（仅在一个中直接查找所有org文件）而不是更普遍的问题（根据特定目录中的文件构建helm源）。

(defvar emagician/helm-c-source-files
  `((name  . "Find Emagician Files")
    (header-name . (lambda (_)))
    (candidates . ,(lambda () 
                    (when (file-accessible-directory-p emagician-dir)
                      (directory-files emagician-dir t))))
    (match helm-c-match-on-file-name helm-c-match-on-directory-name)
    (keymap . ,helm-generic-files-map)
    (candidate-transformer . emagician/helm-ct-is-org-file)
    (help-message . helm-generic-file-help-message)
    (mode-line . ,helm-generic-file-mode-line-string)
    (type . file)))

(defun emagician/helm-ct-is-org-file (candidates)
  (remove-if-not (lambda (c)
                   (and (string= (substring c -4) ".org")
                        (not (string= (substring (file-name-nondirectory c) 0 2) ".#"))))
                 candidates))


(defun emagician/helm-emagician-dir () 
  "List all the org files in the Emagician dir"
  (interactive)
  (helm :sources emagician/helm-c-source-files
        :candidate-number-limit 40
        :buffer "*emagician-|-+-|-files*"))

(global-set-key (kbd "S-<f3>") 'emagician/helm-emagician-dir)

如何让emacs-helm list提供固定目录中的文件作为选项？

3 个答案: