Question

Vim很棒，但是和很多人一样，当我想要复制，删除，然后粘贴时，我会非常恼火 - 删除操作会覆盖yank缓冲区。

现在我知道有101种解决方法和映射，其中一些在这样的帖子中列举：Any way to delete in vim without overwriting your last yank?

但所有这些解决方案都有缺点 - 即使我是一个缓冲大师（我不是）。例如，多余的击键 - 而我通常xxxx快速删除4个字符（只有一个按键因为我按住它并等待自动重复），现在切换到x，x，x，x或无论映射我必须使用不同的缓冲区。

真正理想的只是一个模式切换，你可以打开和关闭D，d，X和x键的副作用行为，这样他们可以交替地做或不写他们的文字到一个缓冲区。这样我就可以简单地进入“无副作用”模式并删除内容，然后在我准备好时粘贴。如果需要，可以重新启用副作用。

有没有人知道这样做的方法？

[更新：解决方案]好吧我明白了：我写了一个能够切换“无副作用”模式的功能......完美运行！请参阅下面我接受的正确答案

[更新＃2]我的解决方案仍然很有效，我在使用大量删除和粘贴时一直使用它。但同时我还发现了一种更简单的方法来满足复制，粘贴，删除的特定用例 - 对于要删除的文本是连续的简单情况。

正常浏览文本后，我会使用v命令直观地突出显示要删除的文本，然后使用p命令将其粘贴到其上。在没有任何特殊映射的情况下实现了期望的效果。

这个工作流程的唯一问题是，如果我想再次粘贴，粘贴突出显示文本的行为会覆盖原始粘贴缓冲区，但是使用.vimrc中的以下映射可以轻松更改此行为：

vnoremap p "_dp
vnoremap P "_dP

Answer 1

好的，我明白了 - .vimrc中的这个脚本让我有效切换“无缓冲副作用”模式，当“无缓冲区副作用”模式被激活时，d和x键不再覆盖缓冲区。

在.vimrc

中添加

function! ToggleSideEffects()
    if mapcheck("dd", "n") == ""
        noremap dd "_dd
        noremap D "_D
        noremap d "_d
        noremap X "_X
        noremap x "_x
        echo 'side effects off'
    else
        unmap dd
        unmap D
        unmap d
        unmap X
        unmap x
        echo 'side effects on'
    endif
endfunction
nnoremap ,, :call ToggleSideEffects()<CR>

然后切换进入和退出此模式使用组合键，（两个逗号）

Answer 2

我认为尝试“关闭”每个删除/更改命令的副作用将是非常困难，如果不是不可能的话。处理这种情况的基本方法是：

在删除或更改命令中使用黑洞（"_）注册。例如"_dd
使用包含最新手势的"0注册表和粘贴命令。例如"0p
将文本感染到指定的寄存器。例如"ayy然后执行"ap

我个人倾向于"0p方法，因为这符合我的思维方式。

现在看到你要求没有这样的解决方法我提供了一些功能来改变粘贴命令，以便在我所谓的paste_copy和nopaste_copy模式之间切换。 nopaste_copy是Vim的默认行为。将以下内容放入~/.vimrc：

function! PasteCopy(cmd, mode)
  let reg = ""
  if exists('g:paste_copy') && g:paste_copy == 1 && v:register == '"'
    let reg = '"0'
  elseif v:register != '"'
    let reg = '"' . v:register
  endif
  let mode = ''
  if a:mode == 'v'
    let mode = 'gv'
  endif
  exe "norm! " . mode . reg . a:cmd
endfunction

command! -bar -nargs=0 TogglePasteCopy let g:paste_copy = exists('g:paste_copy') && g:paste_copy == 1 ? 0 : 1<bar>echo g:paste_copy ? '  paste_copy' : 'nopaste_copy'

nnoremap <silent> p :call PasteCopy('p', 'n')<cr>
nnoremap <silent> P :call PasteCopy('P', 'n')<cr>
nnoremap <silent> ]p :call PasteCopy(']p', 'n')<cr>
nnoremap <silent> [p :call PasteCopy('[p', 'n')<cr>
nnoremap <silent> ]P :call PasteCopy(']P', 'n')<cr>
nnoremap <silent> [P :call PasteCopy('[P', 'n')<cr>
vnoremap <silent> p :<c-u>call PasteCopy('p', 'v')<cr>
vnoremap <silent> P :<c-u>call PasteCopy('P', 'v')<cr>

您可以通过:TogglePasteCopy切换paste_copy模式。您可能更喜欢这样的映射

nnoremap <leader>tp :TogglePasteCopy<cr>

作为最后的建议，我强烈建议使用"0p或使用命名寄存器来处理这种方法，因为它们是vim原生的，而且还有一种“模式”需要担心。

删除时vim切换缓冲区覆盖行为

2 个答案: