Question

我的用户对我们拥有的大型Lotus Notes应用程序（不是Web）的糟糕性能感到非常沮丧。它目前是10Gb，有大约500.000个文档，它包含读者字段。

我想要做的是创建应用程序应用程序的迷你版本，因为大多数用户只对最近几年的文档感兴趣。

此时无法归档或移动大型应用程序，因此我正在考虑提供新的迷你副本并进行选择性复制，仅包含今年的文档。

我遇到的问题是应用程序的完整版本需要在所有服务器上，这意味着我将在具有相同副本ID的同一服务器上获得完整版和迷你版，这看起来有点可怕。 / p>

有更好的方法吗？

Answer 1

我已经看到很多不同的方法解决这个问题，从简单到过度设计。可悲的是，我认为我一直是过度设计方法的设计者。幸运的是，我已经吸取了一些教训。以下是我认为最低技术方法：

您首先要做的是制作数据库的仅设计副本。我将其称为productiondocs.ntf。我将原来称为alldocs.nsf。

将两个代理添加到productiondocs.ntf，并确保它们受到设计刷新/替换的保护。调用第一个代理“synch”，并将其设置为在新的或修改的文档上运行，并编写代码以简单地将新的/修改过的文档复制到alldocs.nsf中。确保检查isValid以防止在此代理的主循环中处理已删除的文档。调用第二个代理“清除”。编写代码以检查日期（文档中的已创建，mod或数据字段，具体取决于您要强制执行的规则），并删除超过一年的文档。

现在，您可以使用选择性复制 - 但只需一次。制作一个alldocs.nsf的选择性复制品，只包含一年的文档，并称之为yeardocs.nsf。然后制作yeardocs.nsf的非副本副本并将其命名为production.nsf。最后，使用production.ntf替换production.nsf的设计。仔细检查代理是否在那里以及它们是否受到保护以防止设计刷新/替换操作。（某些版本的设计师搞砸了！）安排同步以根据需要运行，并安排清除每天或每周运行。将production.nsf复制到所有服务器，并将用户移至production.nsf。

（注意：您可以反过来，在清除后将用户保留在现有数据库中;但老实说，我认为通过从一个干净的新NSF开始，您将获得额外的性能提升，这就是我编写它的原因我的方式。）

Answer 2

我真的很喜欢理查德的解决方案，但我最近实现了迄今为止我喜欢的推导。基本上，将每个文档中的任何元数据放入作为“索引”的单独数据库中，当它们打开索引文档时，它会在alldocs.nsf中打开文档（并关闭索引文档）。

为此，请在alldocs.nsf中编写代理，以便在修改或保存文档时创建索引文档。它应该只复制您要用于索引的字段（元数据）。从我的复制事件到主代理执行此操作的示例代码（没有它调用的子例程或函数）：

Sub Initialize
Dim session As New NotesSession
Dim maindb As NotesDatabase ' Main SIR
Dim mainincidents As NotesView ' view in Main SIR
Dim maindoc As NotesDocument ' document in Main SIR
Dim projectdoc, nextprojectdoc As NotesDocument ' document in this database
Dim ndc As NotesDocumentCollection ' unprocessed documents in this database
Dim fieldItem As NotesItem
Dim reportnumber, value, formtype As Variant
Dim fieldsToCopy (10) As String 
Dim reason As String

On Error GoTo errorhandler 

Call StartAgentLogging ( session )

Set thisdb = session.Currentdatabase

' find all unstamped documents
Set ndc = thisdb.Unprocesseddocuments

If ndc.Count = 0 Then
    Call agentLog.LogAction ( "No incidents to process" )
    Exit Sub
End If

maindbfilepath = DetermineKeyword("MAINSIR")
Set maindb = session.Getdatabase("","")
Call maindb.Open("", maindbfilepath)

If Not maindb.Isopen Then
    reason = "Main Security database could not be found at " & maindbfilepath
    Call agentLog.LogAction ( reason )
    MessageBox reason, 16, "Error"
    Exit Sub
End If

Set mainincidents = maindb.Getview("(Incidents for Upload)")
Set projectdoc = ndc.Getfirstdocument()
fieldsToCopy (0) = "ReportType"
fieldsToCopy (1) = "ReportNumber"
fieldsToCopy (2) = "ReportDate"
fieldsToCopy (3) = "IncidentDate"
fieldsToCopy (4) = "ProjectName"
fieldsToCopy (5) = "ProjectCountry"
fieldsToCopy (6) = "ProjectLocation"
fieldsToCopy (7) = "ReporterName"
fieldsToCopy (8) = "ReporterPhone"
fieldsToCopy (9) = "ReporterEmail"
fieldsToCopy (10) = "Appointment"

While Not projectdoc Is Nothing
    formtype = projectdoc.GetItemValue ("Form")
    If formtype(0) = "Incident" Then
        ' check to see if that exists in the main SIR
        reportnumber = projectdoc.GetItemValue("ReportNumber")
        Call agentLog.LogAction ( "Checking " & reportnumber(0) )
        Set maindoc = mainincidents.GetDocumentByKey(reportnumber(0), True)
        Call agentLog.LogAction ( "Accessing " & reportnumber(0) )

        If maindoc Is Nothing Then
            Call agentLog.LogAction ( "Main does not contain " & reportnumber(0) & " creating new document." )
            ' if not, create new document
            Set maindoc = maindb.Createdocument()
            maindoc.Form = "Incident"

            ForAll fieldname In fieldsToCopy
                Call agentLog.LogAction ( "Field name: " & fieldname ) 
                Set fieldItem = projectdoc.Getfirstitem(fieldname)
                Call maindoc.Copyitem(fieldItem, fieldname)
            End ForAll

            Call maindoc.Save(True, False)
            Call CreateNotice ( maindoc )
        Else
            Call agentLog.LogAction ( "Main contains " & reportnumber(0) & " updating document." )
            ' if it does, update data
            ForAll fieldname In fieldsToCopy
                Call agentLog.LogAction ( "Field name: " & fieldname ) 
                value = projectdoc.GetItemValue(fieldname)
                Call maindoc.ReplaceItemValue(fieldname, value(0))
            End ForAll
        End If

        'Path and filename
        Call maindoc.Replaceitemvalue("Path", thisdb.Filepath)
        Call maindoc.Save(True, False)
        Call agentLog.LogAction ( "Saved " & reportnumber(0) )
    Else
        Call agentLog.LogAction ( "Project form is " & projectdoc.Form(0) )
    End If

    ' stamp document as processed
    Set nextprojectdoc = ndc.GetNextDocument(projectdoc)
    Call session.Updateprocesseddoc(projectdoc)
    Set projectdoc = nextprojectdoc
Wend 

exiting:
    Exit Sub
errorhandler:' report all errors in a messagebox
    reason = "Error #" & CStr (Err) & " (" & Error & ") when creating incident in Main database, on line " & CStr (Erl)
    Call agentLog.LogAction ( reason )
    MessageBox reason, 16, "Error" 
    Resume exiting
End Sub

然后，您需要将代码添加到索引数据库中索引表单的onLoad事件中。我把我放在一个由ToolsRunMacro调用的代理中，但你可以直接把它放进去。这是我的打开项目副本代理。

Sub Initialize
' this button opens the incident report in the project database
Dim ws As New NotesUIWorkspace
Dim session As New NotesSession
Dim reportdb As NotesDatabase
Dim view As NotesView
Dim uidoc As NotesUIDocument
Dim thisdoc, reportdoc As NotesDocument
Dim filepath, reportnumber As Variant
Dim baseurl, opener, unid As String

Call StartAgentLogging ( session )
Set thisdb = session.Currentdatabase

Set uidoc = ws.CurrentDocument
Set thisdoc = uidoc.Document
filepath = thisdoc.GetItemValue ( "Path" )
reportnumber = thisdoc.GetItemValue ( "ReportNumber" )

Set reportdb = session.GetDatabase (thisdb.Server, filepath (0), False )
If reportdb Is Nothing Then
    MessageBox ( "Could not find Project Security Incident Report database" & Chr$(10) & thisdb.Server & "\" & filepath(0) )
    Call agentLog.LogAction ( "Could not find Project Security Incident Report database" & Chr$(10) & thisdb.Server & "\" & filepath(0) )
    Exit Sub
End If
If Not reportdb.Isopen Then
    Call reportdb.Open(thisdb.Server, filepath (0)) 
End If
Set view = reportdb.GetView ( "Incidents" )
Set reportdoc = view.GetDocumentByKey ( reportnumber(0) )
If reportdoc Is Nothing Then
    MessageBox ( "Could not find Report #" & reportnumber(0) )
    Call agentLog.LogAction ( "Could not find Report #" & reportnumber(0) )
    Exit Sub
End If

Call uidoc.Close
unid = reportdoc.UniversalID
baseurl = reportdb.NotesURL
opener = Left$ ( baseurl, InStr ( baseurl, "?" ) -1 ) & "/Incidents/" & unid & "?OpenDocument"
Call ws.URLOpen ( opener )
Call agentLog.LogAction ( "Opened Report #" & reportnumber(0) )
End Sub

现在，您可以将索引数据库限制为仅包含最近一年的文档，或者查看其中包含所有文档时的工作方式。很大程度上取决于您需要在视图中提供多少数据。

在我的情况下，索引数据库包含来自许多数据库的文档的索引文档，并充当“完整数据”数据库的中央访问点。它还在测试中，所以我不确定它对我有多好，但我认为我会为你提供它。

如何向用户提供非常大的应用程序的迷你版本

2 个答案: