Question

<xsl:variable name="map">
   <map>
        <item key="Name" value="John"/>
        <item key="Address" value="Un_Known"/>
        <item key="Phone" value="(878)876678"/>
        <item key="Last Name" value="Verner"/>
    </map>
</xsl:variable>

<xsl:for-each select "$map/map/item">
   <xsl:if test="./@key = $input">
      <!-- cool user is asking for something know .. do something fancy -->
   </xsl:if>
<xsl:for-each>

我想在我的XSLT中声明一个类似于结构的地图，然后想要访问它。显然，我不想使用额外的名称空间，所以使用exsl：node-set不是我现在正在寻找的解决方案。

我正在使用XSLT 1.0 Saxon。

有没有更好的方法来做我想做的事情？

由于 Karephul

以下所有答案都是正确有效的。我们最终决定使用“exsl：node-set”

感谢您的建议..

Answer 1

如果您不想使用node-set()扩展功能，可以将<map>数据放在单独的XML文件中，例如map.xml。然后使用document('map.xml')从样式表访问该文件。然后，您可以使用XPath表达式访问地图的内容，如上所示。

Answer 2

您可以直接在XSLT中包含额外的XML信息，例如<map>。该XML数据需要绑定到命名空间（XSLT命名空间除外），但它可以是任何命名空间。

您可以使用带有空字符串的document()函数访问XSLT中的数据，该字符串将加载XSLT文档。

顺便说一句，您可以通过在<xsl:if>选择的XPath上使用谓词过滤器来消除对xsl:for-each的需求。

例如：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    version="1.0"
    xmlns:my="http://stackoverflow.com/questions/12146687/creating-a-map-in-xlst">

    <xsl:param name="input" />

    <my:map >
        <item key="Name" value="John"/>
        <item key="Address" value="Un_Known"/>
        <item key="Phone" value="(878)876678"/>
        <item key="Last Name" value="Verner"/>
    </my:map>

    <xsl:template match="/">
        <xsl:for-each select="document('')/*/my:map/item[@key=$input]">
                <!-- cool user is asking for something know .. do something fancy -->
        </xsl:for-each>
    </xsl:template>

</xsl:stylesheet>

Answer 3

如果您正在使用Saxon，那么很难理解为什么您仍在使用XSLT 1.0。在XSLT 2.0中，这种事情（以及许多其他事情）要容易得多 - 这是你向前迈进的时候。

Answer 4

你有三个非常好的答案。

这是另一个，演示如何使用密钥访问查找表（在实际情况下，它将驻留在单独的XML文档中）：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my" exclude-result-prefixes="my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pInput" select="'Phone'"/>
   <my:map>
        <item key="Name" value="John"/>
        <item key="Address" value="Un_Known"/>
        <item key="Phone" value="(878)876678"/>
        <item key="Last Name" value="Verner"/>
    </my:map>

 <xsl:key name="kLookup" match="item/@value" use="../@key"/>

 <xsl:template match="/">
     <xsl:for-each select="document('')">
       <xsl:value-of select="key('kLookup', $pInput)"/>
     </xsl:for-each>
 </xsl:template>
</xsl:stylesheet>

将此转换应用于任何XML文档（未使用）时，会生成所需的正确结果：

(878)876678

在XSLT 2.0中，xsl:for-each不需要，因为 key() 函数接受第三个参数，该参数指定要编入索引的文档：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="my:my" exclude-result-prefixes="my">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pInput" select="'Phone'"/>
   <my:map>
        <item key="Name" value="John"/>
        <item key="Address" value="Un_Known"/>
        <item key="Phone" value="(878)876678"/>
        <item key="Last Name" value="Verner"/>
    </my:map>

 <xsl:key name="kLookup" match="item/@value" use="../@key"/>

 <xsl:template match="/">
       <xsl:value-of select="key('kLookup', $pInput, document(''))"/>
 </xsl:template>
</xsl:stylesheet>

在XSLT中创建一个Map

感谢您的建议..

4 个答案: