Question

我正在努力将存储过程从SQL服务器转换为Oracle。此存储过程提供直接结果集。我的意思是，如果您在例如Management Studio中调用存储过程，则直接获取结果集。

通过转换为Oracle，我可以解决Oracle中不会显示结果集的问题

我在互联网上搜索并看到存储过程应该产生一个REF CURSOR，但我仍然会解决问题，编写一小段代码来获得结果集进程。

伪代码：

调用存储过程并获取游标使用该光标执行某些操作，以便显示我的结果集

有人有想法吗？

Answer 1

在SQL Plus中：

SQL> create procedure myproc (prc out sys_refcursor)
  2  is
  3  begin
  4     open prc for select * from emp;
  5  end;
  6  /

Procedure created.

SQL> var rc refcursor
SQL> execute myproc(:rc)

PL/SQL procedure successfully completed.

SQL> print rc

     EMPNO ENAME      JOB              MGR HIREDATE           SAL       COMM     DEPTNO
---------- ---------- --------- ---------- ----------- ---------- ---------- ----------
      7839 KING       PRESIDENT            17-NOV-1981       4999                    10
      7698 BLAKE      MANAGER         7839 01-MAY-1981       2849                    30
      7782 CLARKE     MANAGER         7839 09-JUN-1981       2449                    10
      7566 JONES      MANAGER         7839 02-APR-1981       2974                    20
      7788 SCOTT      ANALYST         7566 09-DEC-1982       2999                    20
      7902 FORD       ANALYST         7566 03-DEC-1981       2999                    20
      7369 SMITHY     CLERK           7902 17-DEC-1980       9988         11         20
      7499 ALLEN      SALESMAN        7698 20-FEB-1981       1599       3009         30
      7521 WARDS      SALESMAN        7698 22-FEB-1981       1249        551         30
      7654 MARTIN     SALESMAN        7698 28-SEP-1981       1249       1400         30
      7844 TURNER     SALESMAN        7698 08-SEP-1981       1499          0         30
      7876 ADAMS      CLERK           7788 12-JAN-1983       1099                    20
      7900 JAMES      CLERK           7698 03-DEC-1981        949                    30
      7934 MILLER     CLERK           7782 23-JAN-1982       1299                    10
      6668 Umberto    CLERK           7566 11-JUN-2009      19999          0         10
      9567 ALLBRIGHT  ANALYST         7788 02-JUN-2009      76999         24         10

Answer 2

Oracle不是sql server。在SQL Developer

中尝试以下操作

variable rc refcursor;
exec testproc(:rc2);
print rc2

Answer 3

我的解决方案是创建一个流水线功能。优点是查询可以是一行：

select * from table(yourfunction(param1, param2));
您可以将结果加入其他表格，也可以根据需要对其进行过滤或排序。
结果显示为常规查询结果，因此您可以轻松操作它们。

要定义功能，您需要执行以下操作：

  -- Declare the record columns
  TYPE your_record IS RECORD(
     my_col1 VARCHAR2(50), 
     my_col2 varchar2(4000)
  );
  TYPE your_results IS TABLE OF your_record;

  -- Declare the function
  function yourfunction(a_Param1 varchar2, a_Param2 varchar2)
  return your_results pipelined is
    rt          your_results;
  begin
    -- Your query to load the table type
    select s.col1,s.col2
    bulk collect into rt
    from your_table s
    where lower(s.col1) like lower('%'||a_Param1||'%');

    -- Stuff the results into the pipeline..
    if rt.count > 0 then 
      for i in rt.FIRST .. rt.LAST loop 
        pipe row (rt(i)); 
      end loop; 
    end if;

    -- Add more results as you please....
    return;
  end find;

如上所述，您只需查看结果即可：

select * from table(yourfunction(param1, param2)) t order by t.my_col1;

Answer 4

在SQL Plus中：

SQL> var r refcursor
SQL> set autoprint on
SQL> exec :r := function_returning_refcursor();

用对过程/函数的调用替换最后一行，并显示refcursor的内容

Answer 5

嗨，我知道这是前一段时间被问到的，但我刚刚想出来了，这可能对其他人有所帮助。不确定这是否正是您正在寻找的，但这就是我调用存储过程并使用SQL Developer查看输出的方法。
在SQL Developer中查看proc时，右键单击并选择“Run”或选择Ctrl + F11以显示“运行PL / SQL”窗口。这将创建一个模板，其中包含您需要修改的输入和输出参数。我的proc返回一个sys_refcursor。对我来说棘手的部分是声明一个行类型，它完全等同于proc返回的select stmt / sys_refcursor：

DECLARE
  P_CAE_SEC_ID_N NUMBER;
  P_FM_SEC_CODE_C VARCHAR2(200);
  P_PAGE_INDEX NUMBER;
  P_PAGE_SIZE NUMBER;
  v_Return sys_refcursor;
  type t_row is record (CAE_SEC_ID NUMBER,FM_SEC_CODE VARCHAR2(7),rownum number, v_total_count number);
  v_rec t_row;

BEGIN
  P_CAE_SEC_ID_N := NULL;
  P_FM_SEC_CODE_C := NULL;
  P_PAGE_INDEX := 0;
  P_PAGE_SIZE := 25;

  CAE_FOF_SECURITY_PKG.GET_LIST_FOF_SECURITY(
    P_CAE_SEC_ID_N => P_CAE_SEC_ID_N,
    P_FM_SEC_CODE_C => P_FM_SEC_CODE_C,
    P_PAGE_INDEX => P_PAGE_INDEX,
    P_PAGE_SIZE => P_PAGE_SIZE,
    P_FOF_SEC_REFCUR => v_Return
  );
  -- Modify the code to output the variable
  -- DBMS_OUTPUT.PUT_LINE('P_FOF_SEC_REFCUR = ');
  loop
    fetch v_Return into v_rec;
    exit when v_Return%notfound;
    DBMS_OUTPUT.PUT_LINE('sec_id = ' || v_rec.CAE_SEC_ID || 'sec code = ' ||v_rec.FM_SEC_CODE);
  end loop;

END;

Answer 6

CREATE OR REPLACE PROCEDURE SP_Invoices(p_nameClient IN CHAR)
AS
BEGIN       
    FOR c_invoice IN 
    (
       SELECT CodeInvoice, NameClient FROM Invoice
       WHERE NameClient = p_nameClient
    )
    LOOP
        dbms_output.put_line('Code Invoice: ' || c_invoice.CodeInvoice);
        dbms_output.put_line('Name Client : ' ||  c_invoice.NameClient );
    END LOOP;
END;

在SQL Developer中执行：

BEGIN
    SP_Invoices('Perico de los palotes');
END;
-- Or:
EXEC SP_Invoices('Perico de los palotes');

输出：

> Code Invoice: 1 
> Name Client : Perico de los palotes
> Code Invoice: 2 
> Name Client : Perico de los palotes

Answer 7

从Oracle 12c开始的FYI，您可以执行以下操作：

CREATE OR REPLACE PROCEDURE testproc(n number)
AS
  cur SYS_REFCURSOR;
BEGIN
    OPEN cur FOR SELECT object_id,object_name from all_objects where rownum < n;
    DBMS_SQL.RETURN_RESULT(cur);
END;
/

EXEC testproc(3);

OBJECT_ID OBJECT_NAME                                                                                                                     
---------- ------------
100 ORA$BASE                                                                                                                        
116 DUAL

它应该更接近其他数据库并简化迁移。但这对我来说并不完美，例如，SQL开发人员无法将其很好地显示为普通的SELECT。

我更喜欢管道功能的输出，但是它们需要更多的样板代码进行编码。

更多信息： https://oracle-base.com/articles/12c/implicit-statement-results-12cr1

从oracle存储过程获取结果集

7 个答案: