Question

在Groovy中连接字符串的最佳（惯用）方式是什么？

选项1：

calculateAccountNumber(bank, branch, checkDigit, account) {
    bank + branch + checkDigit + account
}

选项2：

calculateAccountNumber(bank, branch, checkDigit, account) {
    "$bank$branch$checkDigit$account"
}

我在旧的Groovy网站上找到了一个关于这个主题的有趣观点：你可以做的事情，但最好不要做。

与在Java中一样，您可以使用“+”符号连接字符串。但是Java 只需要一个“+”表达式中的两个项之一字符串，无论它是在第一个位置还是在最后一个位置。 Java的将在“+”的非String对象中使用toString（）方法表达。但是在Groovy中，你应该安全第一项你的“+”表达式以正确的方式实现了plus（）方法，因为Groovy会搜索并使用它。在Groovy GDK中，只有数字和String / StringBuffer / Character类具有plus（）方法实现连接字符串。为避免意外，请始终使用 GString的。

Answer 1

我总是选择第二种方法（使用GString模板），但是当你有多个参数时，我倾向于将它们包装在${X}中，因为我发现它使它更具可读性

在这些方法上运行一些基准（使用Nagai Masato的优秀GBench module）也表明模板比其他方法更快：

@Grab( 'com.googlecode.gbench:gbench:0.3.0-groovy-2.0' )
import gbench.*

def (foo,bar,baz) = [ 'foo', 'bar', 'baz' ]
new BenchmarkBuilder().run( measureCpuTime:false ) {
  // Just add the strings
  'String adder' {
    foo + bar + baz
  }
  // Templating
  'GString template' {
    "$foo$bar$baz"
  }
  // I find this more readable
  'Readable GString template' {
    "${foo}${bar}${baz}"
  }
  // StringBuilder
  'StringBuilder' {
    new StringBuilder().append( foo )
                       .append( bar )
                       .append( baz )
                       .toString()
  }
  'StringBuffer' {
    new StringBuffer().append( foo )
                      .append( bar )
                      .append( baz )
                      .toString()
  }
}.prettyPrint()

在我的机器上给出了以下输出：

Environment
===========
* Groovy: 2.0.0
* JVM: Java HotSpot(TM) 64-Bit Server VM (20.6-b01-415, Apple Inc.)
    * JRE: 1.6.0_31
    * Total Memory: 81.0625 MB
    * Maximum Memory: 123.9375 MB
* OS: Mac OS X (10.6.8, x86_64) 

Options
=======
* Warm Up: Auto 
* CPU Time Measurement: Off

String adder               539
GString template           245
Readable GString template  244
StringBuilder              318
StringBuffer               370

因此，有了它的可读性和速度，我建议使用模板; - ）

注意：如果您在GString方法的末尾添加toString()以使输出类型与其他指标相同，并使其成为更公平的测试，StringBuilder和StringBuffer击败GString方法获得速度。但是，因为大多数事情都可以使用GString来代替String（你只需要谨慎使用Map键和SQL语句），大多数情况下都可以不进行最终转换

添加这些测试（正如评论中提到的那样）

  'GString template toString' {
    "$foo$bar$baz".toString()
  }
  'Readable GString template toString' {
    "${foo}${bar}${baz}".toString()
  }

现在我们得到结果：

String adder                        514
GString template                    267
Readable GString template           269
GString template toString           478
Readable GString template toString  480
StringBuilder                       321
StringBuffer                        369

正如你所看到的（正如我所说），它比StringBuilder或StringBuffer慢，但仍然比添加字符串快一点......

但仍然更具可读性。

在下面的ruralcoder注释后编辑

更新到最新的gbench，用于连接的较大字符串和初始化为良好大小的StringBuilder的测试：

@Grab( 'org.gperfutils:gbench:0.4.2-groovy-2.1' )

def (foo,bar,baz) = [ 'foo' * 50, 'bar' * 50, 'baz' * 50 ]
benchmark {
  // Just add the strings
  'String adder' {
    foo + bar + baz
  }
  // Templating
  'GString template' {
    "$foo$bar$baz"
  }
  // I find this more readable
  'Readable GString template' {
    "${foo}${bar}${baz}"
  }
  'GString template toString' {
    "$foo$bar$baz".toString()
  }
  'Readable GString template toString' {
    "${foo}${bar}${baz}".toString()
  }
  // StringBuilder
  'StringBuilder' {
    new StringBuilder().append( foo )
                       .append( bar )
                       .append( baz )
                       .toString()
  }
  'StringBuffer' {
    new StringBuffer().append( foo )
                      .append( bar )
                      .append( baz )
                      .toString()
  }
  'StringBuffer with Allocation' {
    new StringBuffer( 512 ).append( foo )
                      .append( bar )
                      .append( baz )
                      .toString()
  }
}.prettyPrint()

给出

Environment
===========
* Groovy: 2.1.6
* JVM: Java HotSpot(TM) 64-Bit Server VM (23.21-b01, Oracle Corporation)
    * JRE: 1.7.0_21
    * Total Memory: 467.375 MB
    * Maximum Memory: 1077.375 MB
* OS: Mac OS X (10.8.4, x86_64)

Options
=======
* Warm Up: Auto (- 60 sec)
* CPU Time Measurement: On

                                    user  system  cpu  real

String adder                         630       0  630   647
GString template                      29       0   29    31
Readable GString template             32       0   32    33
GString template toString            429       0  429   443
Readable GString template toString   428       1  429   441
StringBuilder                        383       1  384   396
StringBuffer                         395       1  396   409
StringBuffer with Allocation         277       0  277   286

Answer 2

def my_string = "some string"
println "here: " + my_string

不太确定为什么上面的答案需要进入基准测试，字符串缓冲区，测试等。

Answer 3

在当前硬件上重现tim_yates答案，并添加leftShift（）和concat（）方法以检查发现：

  'String leftShift' {
    foo << bar << baz
  }
  'String concat' {
    foo.concat(bar)
       .concat(baz)
       .toString()
  }

结果表明concat（）是纯String的更快解决方案，但是如果您可以在其他地方处理GString，则GString模板仍在前面，而值得一提的是应该转到leftShift（）（按位运算符）和StringBuffer（）并进行初始分配：

Environment
===========
* Groovy: 2.4.8
* JVM: OpenJDK 64-Bit Server VM (25.191-b12, Oracle Corporation)
    * JRE: 1.8.0_191
    * Total Memory: 238 MB
    * Maximum Memory: 3504 MB
* OS: Linux (4.19.13-300.fc29.x86_64, amd64)

Options
=======
* Warm Up: Auto (- 60 sec)
* CPU Time Measurement: On

                                    user  system  cpu  real

String adder                         453       7  460   469
String leftShift                     287       2  289   295
String concat                        169       1  170   173
GString template                      24       0   24    24
Readable GString template             32       0   32    32
GString template toString            400       0  400   406
Readable GString template toString   412       0  412   419
StringBuilder                        325       3  328   334
StringBuffer                         390       1  391   398
StringBuffer with Allocation         259       1  260   265

使用Groovy进行字符串连接

3 个答案:

在下面的ruralcoder注释后编辑