Question

@solved C＃使用相同的代码是

的两倍

我正在使用perl解析phred33 fastq文件，并且需要相当长的时间（大约15分钟）。 fastq文件约为3演出。有没有合理的方法可以加快速度？

$file=shift;
open(FILE,$file);
open(FILEFA,">".$file.".fa");
open(FILEQA,">".$file.".qual");
while($line=<FILE>)
{
    chomp($line);
    if($line=~m/^@/)
    {


    $header=$line;
    $header =~ s/@/>/g;
    $seq=<FILE>;
    chomp($seq);
    $nothing=<FILE>;
    $nothing="";
    $fastq=<FILE>;

    print FILEFA $header."\n";
    print FILEFA $seq."\n";
    $seq="";
    print FILEQA $header."\n";

        @elm=split("",$fastq);
        $i=0;
        while(defined($elm[$i]))
        {
            $Q = ord($elm[$i]) - 33;
            if($Q!="-23")
            {
            print FILEQA $Q." ";
            }
            $i=$i+1;
        }
        print FILEQA "\n";
    }
}
print $file.".fa\n";
print $file.".qual\n";

Answer 1

这里没有使用CPU。这是IO限制，因此大部分时间都是通读3GB。可以进行微观优化（以及其他清理）。

首先，始终使用use strict; use warnings;。

主要代码是

my @elm = split(//, $fastq);
my $i=0;
while(defined($elm[$i])) {
    my $Q = ord($elm[$i]) - 33;
    if($Q!="-23") {
        print FILEQA $Q." ";
    }
    $i=$i+1;
}

if($Q!="-23")的目的是检查角色是否是换行符，如果你chomp($fastq);，则不必这样做。（-23周围的引号是什么？！）

chomp($fastq);
my @elm = split(//, $fastq);
my $i=0;
while(defined($elm[$i])) {
    my $Q = ord($elm[$i]) - 33;
    print FILEQA $Q." ";
    $i=$i+1;
}
print FILEQA "\n";

使用while循环只会使事情复杂化。当您具有已知的迭代次数时，请使用for循环。

chomp($fastq);
for (split(//, $fastq)) {
    print FILEQA (ord($_)-33)." ";
}
print FILEQA "\n";

将内心转化为内容可能会有所帮助。

chomp($fastq);
print FILEQA join(' ', map ord($_)-33, split //, $fastq), "\n";

第二个想法，不够内在：）

$fastq =~ s/(.)/(ord($1)-33) . " "/eg;
print FILEQA $fastq;

但是我们预先计算了翻译的内容？然后我们不必重复调用子（/e代码）。

my %map = map { chr($_) => ($_-33)." " } 0x00..0xFF;

$fastq =~ s/(.)/$map{$1}/g;
print FILEQA $fastq;

经过多次清理后，我们得到：

use strict;
use warnings;

my %map = map { chr($_) => ($_-33)." " } 0x00..0xFF;

my $file = shift;

my $fa_file   = "$file.fa";
my $qual_file = "$file.qual";

open(my $FILE,   '<', $file     ) or die $!;
open(my $FILEFA, '>', $fa_file  ) or die $!;
open(my $FILEQA, '>', $qual_file) or die $!;

while (my $header = <$FILE>) {
    next if $header !~ /^@/;

    my $seq = <$FILE>;
    <$FILE>;
    my $fastq = <$FILE>;

    $header =~ s/@/>/g;
    $fastq =~ s/(.)/$map{$1}/g;

    print $FILEFA $header;
    print $FILEFA $seq;

    print $FILEQA $header;
    print $FILEQA $fastq;
}

print "$fa_file\n";
print "$qual_file\n";

提高解析fastq的速度

1 个答案: