Question

我正在使用Flash Professional CS5.5，我需要制作一个应用程序，其中有一个球（符号）使用加速度计移动，我想要的是，当球坐标A达到此坐标B时，它进入框架2（gotoAndPlay（2））。我必须先找到球坐标，对吗？我该怎么做？

这是我现在的代码

c_ball.addEventListener(MouseEvent.MOUSE_DOWN, fl_ClickToDrag);
function fl_ClickToDrag(event:MouseEvent):void{
c_ball.startDrag();}
stage.addEventListener(MouseEvent.MOUSE_UP, fl_ReleaseToDrop);
function fl_ReleaseToDrop(event:MouseEvent):void{
c_ball.stopDrag();}

如果在重新找到坐标之后会起作用吗？

function f_level (e) if (c_ball.x==100 && c_ball.y==100) {
gotoAndStop(2);}

Answer 1

如果您正在寻找Accelerometer数据，那么

MOUSE_UP和MOUSE_DOWN不是您所需要的。您需要Accelerometer类和相关事件。

尝试这样的事情：

import flash.sensors.Accelerometer;
import flash.events.AccelerometerEvent;

var accel:Accelerometer = new Accelerometer();


accel.addEventListener(AccelerometerEvent.UPDATE, handleAccelUpdate);

更新处理程序：

function handleAccelUpdate(e:AccelerometerEvent):void{
   //inside this function you now have access to acceleration x/y/z data
   trace("x: " + e.accelerationX);
   trace("y: " + e.accelerationY);
   trace("z: " + e.accelerationZ);
   //using this you can move your MC in the correct direction
   c_ball.x -= (e.accelerationX * 10); //using 10 as a speed multiplier, play around with this number for different rates of speed 
   c_ball.y += (e.accelerationY * 10); //same idea here but note the += instead of -=

   //you can now check the x/y of your c_ball mc
   if(c_ball.x == 100 && c_ball.y == 100){
         trace("you win!"); //fires when c_ball is at 100, 100
   }
}

现在，这将让你在屏幕上“滚动”你的MC，这样你可能会想要添加某种边界检查。

查看这篇精彩的文章了解更多信息：

http://www.republicofcode.com/tutorials/flash/as3accelerometer/

Answer 2

一种简单易行的方法是使用碰撞检测，而不是仅针对目标区域测试一个位置（用户难以满足的位置）：

package
{
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;

public class Hittester extends Sprite
{

    var ball:Sprite = new Sprite();
    var testarea:Sprite = new Sprite();

    public function Hittester()
    {
        super();
        ball.graphics.beginFill(0xff0000);
        ball.graphics.drawCircle(0,0,10);

        testarea.graphics.beginFill(0x00ff00);
        testarea.graphics.drawRect(0,0,50,50);
        testarea.x = 100;
        testarea.y = 100;

        // if testarea should be invisble
        /*testarea.alpha = 0;
        testarea.mouseEnabled = false;
        */

        ball.addEventListener(MouseEvent.MOUSE_DOWN, startDragging);

        addChild(testarea);
        addChild(ball);
    }
    private function startDragging( E:Event  = null):void{
        ball.startDrag();
        stage.addEventListener(MouseEvent.MOUSE_UP, stopDragging);
    }
    private function stopDragging( E:Event  = null):void{
        stage.removeEventListener(MouseEvent.MOUSE_UP, stopDragging);       
        ball.stopDrag();

        test();
    }
    private function test():void{
        if( ! ball.hitTestObject(testarea) ){
            ball.x = 10;
            ball.y = 10;
        }
        else{
            // here goes next frame command ;)
        }
    }   
}
}

AS3 - 如果符号的坐标到达此处？

2 个答案: