Question

我正在编写一个存储过程，我需要在过程中动态构造一个SQL语句来引用传入的表名。

我需要让这个SQL语句返回一个结果，然后我可以在整个过程的其余部分使用它。

我尝试过使用临时表和所有内容，但我不断收到一条消息，我需要声明变量等。

例如：

DECLARE @FiscalYear INT    
DECLARE @DataSource NVARCHAR(25)
DECLARE @SQL NVARCHAR(250)
SELECT @DataSource = 'CustomerCosts20120328'
DECLARE @tempFiscalYear TABLE ( FiscalYear INT ) 
SELECT @SQL = 'INSERT INTO @tempFiscalYear SELECT DISTINCT FiscalYear FROM ' + @DataSource
EXEC(@SQL)
SELECT @FiscalYear = FiscalYear FROM @tempFiscalYear

或者...

DECLARE @FiscalYear INT  
DECLARE @DataSource NVARCHAR(25)
DECLARE @SQL NVARCHAR(250)
SELECT @DataSource = 'CustomerCosts20120328'
SELECT @SQL = 'SELECT DISTINCT @FiscalYear = FiscalYear FROM ' + @DataSource
EXEC(@SQL)

无论如何不使用实际的桌子就可以做到这一点吗？

感谢。

Answer 1

您尝试过类似的事情吗？

DECLARE @FiscalYear INT, @DataSource NVARCHAR(25), @SQL NVARCHAR(250);
SET @DataSource = N'CustomerCosts20120328';
SET @SQL = N'SELECT DISTINCT @FiscalYear = FiscalYear FROM ' + @DataSource;
EXEC sp_executesql @SQL, N'@FiscalYear INT OUTPUT', @FiscalYear OUTPUT;

PRINT @FiscalYear;

您需要确保在nvarchar字符串前加上N，例如： SELECT @SQL = N'SELECT ...。

另外，您知道如果查询返回多行，则分配给@FiscalYear的值完全是任意的，对吧？虽然您可能希望该表中包含单个值，但使用MAX()或TOP 1 ... ORDER BY来确保只分配一个可预测的值是不会有害的。

Answer 2

首先，您需要知道使用动态SQL会冒SQL注入攻击的风险，在使用它之前，您应首先查看this link。执行此操作后，您可以将第一个查询更改为：

DECLARE @FiscalYear INT    
DECLARE @DataSource NVARCHAR(25)
DECLARE @SQL NVARCHAR(250)
SELECT @DataSource = 'CustomerCosts20120328'
DECLARE @tempFiscalYear TABLE ( FiscalYear INT ) 
SELECT @SQL = 'SELECT DISTINCT FiscalYear FROM ' + @DataSource

INSERT INTO @tempFiscalYear
EXEC(@SQL)

SELECT @FiscalYear = FiscalYear FROM @tempFiscalYear

您还应该考虑@AaronBertrand对@FiscalYear参数赋值的评论。

从存储过程中的动态SQL获取结果

2 个答案: