Question

我有这个XML：

<Year>
  <Movies>
    <Add>
        <Key>movie1</Key>
        <Value>black</Value>
    </Add>
    <Add>
        <Key>movie2</Key>
        <Value>white</Value>
    </Add>
  </Movies>
</Year>

需要将其转换为此XML，并使用特殊的asterix作为起始字符：

<Year>
    <MovieList>*movie1-black,movie2-white<MovieList>
</Year>

我尝试了几种xslt变换，我到处都是。这是我最新的黑客攻击。现在在XML工具中摆弄这个......

<xsl:template match="b:Year">
 <xsl:copy>
   <xsl:for-each select="*">
      <xsl:element name="MovieList">
        <xsl:for-each select="./b:Movies/b:Add">
          <xsl:if test="position() = 1">*</xsl:if>
          <xsl:value-of select="./b:Key"/>-<xsl:value-of select="./b:Value"/>
          <xsl:if test="position() != last()">,</xsl:if>
        </xsl:for-each>
      </xsl:element>
   </xsl:for-each>
  <xsl:apply-templates select="node()"/>
 </xsl:copy>
</xsl:template>

任何xslt专家对此有一些指导意见？谢谢！

Answer 1

以下是使用XSLT 1.0可以执行的操作：

 <xsl:stylesheet version="1.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>

     <xsl:template match="Year/Movies">
        <Year>
          <xsl:variable name="movielist">
            <xsl:for-each select="Add">
              <xsl:value-of select="concat(Key, '-', Value, ',')"/>
            </xsl:for-each>
          </xsl:variable>
          <MovieList>
              <xsl:value-of select="concat('*',substring($movielist, 0, string-length($movielist)))"/>
          </MovieList>
        </Year>
    </xsl:template>
</xsl:stylesheet>

根据您的输入，它会产生：

<Year>
   <MovieList>*movie1-black,movie2-white</MovieList>
</Year>

您可以利用XSLT 2.0更加聪明，利用separator的{{1}}属性，如类似示例中所述：Dimitre的concatenation two fields in xsl

Answer 2

<强>予。这种简单有效的XSLT 1.0转换（没有变量，也没有结果的后处理）：

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
    <Year>
     <xsl:apply-templates/>
    </Year>
 </xsl:template>

 <xsl:template match="Movies">
  <MovieList>
   <xsl:apply-templates/>
  </MovieList>
 </xsl:template>

 <xsl:template match="Add">
  <xsl:value-of select="substring('*,', 2 - (position()=1),1)"/>
  <xsl:value-of select="concat(Key, '-', Value)"/>
 </xsl:template>
</xsl:stylesheet>

应用于提供的XML文档时：

<Year>
    <Movies>
        <Add>
            <Key>movie1</Key>
            <Value>black</Value>
        </Add>
        <Add>
            <Key>movie2</Key>
            <Value>white</Value>
        </Add>
    </Movies>
</Year>

会产生想要的正确结果：

<Year>
   <MovieList>*movie1-black,movie2-white</MovieList>
</Year>

<强> II。 XSLT 2.0解决方案：

<xsl:stylesheet version="2.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="/*">
    <Year>
     <xsl:apply-templates/>
    </Year>
 </xsl:template>

 <xsl:template match="Movies">
  <MovieList>
   <xsl:sequence select="'*'[current()/Add]"/>
   <xsl:value-of select="Add/concat(Key, '-', Value)"
        separator=","/>
  </MovieList>
 </xsl:template>
</xsl:stylesheet>

作为键值的元素的XSLT转换

2 个答案: