Question

我的问题的本质是如何用MVC3和Ninject以合理的方式组合这些对象（见下文）（尽管我不确定DI应该在解决方案中发挥作用）。我无法透露我的项目的真实细节，但这里是一个近似，说明了问题/问题。 VB或C＃中的答案都很受欢迎！

我有几种不同的产品，其性能差异很大，但所有这些产品都需要在目录中表示。每个产品类在我的数据库中都有一个对应的表。商品具有一些特定于商品的属性，因此拥有自己的表。我已经为目录条目定义了一个接口，其目的是调用DescriptionText属性将根据底层的具体类型给出非常不同的结果。

Public Class Clothing
    Property Identity as Int64
    Property AvailableSizes As List(Of String)
    Property AvailableColor As List(Of String)
End Class

Public Class Fasteners
    Property Identity as Int64
    Property AvailableSizes As List(Of String)
    Property AvailableFinishes As List(Of String)
    Property IsMetric As Boolean
End Class

Public Interface ICatalogEntry
    Property ProductId as Int64
    Property PublishedOn As DateTime
    Property DescriptionText As String
End Interface

鉴于DescriptionText是表示层关注的问题，我不想在我的产品类中实现ICatalogEntry接口。相反，我想将其委托给某种格式化程序。

Public Interface ICatalogEntryFormatter
    Property DescriptionText As String
End Interface

Public Class ClothingCatalogEntryFormatter
    Implements ICatalogEntryFormatter

    Property DescriptionText As String
End Class

Public Class FastenerCatalogEntryFormatter
    Implements ICatalogEntryFormatter

    Property DescriptionText As String
End Class

在某处的控制器中会有如下代码：

Dim entries As List(Of ICatalogEntry)
                   = catalogService.CurrentCatalog(DateTime.Now)

在某个视图中，会出现如下代码：

<ul>
@For Each entry As ICatalogEntry In Model.Catalog
    @<li>@entry.DescriptionText</li>
Next
</ul>

所以问题是构造函数是什么样的？如何设置它以便在适当的位置实例化适当的对象。看起来像仿制药或DI可能有助于此，但我似乎有一个心理障碍。我想出的唯一想法是将一个ProductType属性添加到ICatalogEntry，然后实现这样的工厂：

Public Class CatalogEntryFactory
    Public Function Create(catEntry as ICatalogEntry) As ICatalogEntry
        Select Case catEntry.ProductType
        Case "Clothing"
            Dim clothingProduct = clothingService.Get(catEntry.ProductId)
            Dim clothingEntry = New ClothingCatalogEntry(clothingProduct)
            Return result
        Case "Fastener"
            Dim fastenerProduct = fastenerService.Get(catEntry.ProductId)
            Dim fastenerEntry = New FastenerCatalogEntry(fastenerProduct)
            fastenerEntry.Formatter = New FastenerCatalogEntryFormatter
            Return fastenerEntry
    ...     
    End Function
End Class

Public ClothingCatalogEntry
    Public Sub New (product As ClothingProduct)
        Me.Formatter =  New ClothingCatalogEntryFormatter(product)
    End Sub

    Property DescriptionText As String
        Get
            Return Me.Formatter.DescriptionText
        End Get
    End Property
End Class

...FastenerCatalogEntry is omitted but you get the idea...

Public Class CatalogService
    Public Function CurrentCatalog(currentDate as DateTime)
        Dim theCatalog As List(Of ICatalogEntry)
                                  = Me.repository.GetCatalog(currentDate)

        Dim theResult As New List(Of ICatalogEntry)

        For Each entry As ICataLogEntry In theCatalog
            theResult.Add(factory.Create(entry))
        Next

        Return theResult
    End Function
End Class

恕我直言，除了必须为每个新产品类别更改工厂外，我并没有真正得到这些代码的任何气味。然而，我的直觉说这是旧的做事方式，而现在DI和/或仿制药可以更好地做到这一点。关于如何处理这个问题的建议非常感谢（关于更好标题的建议......）

Answer 1

我喜欢在视图的模型上使用默认构造函数，并通过Automapper填充它们。

我会有一个这样的视图模型：

public interface IHasDescription
{
    public string DescriptionText { get; set; }
}

public class ViewModelType : IHasDescription
{
    [DisplayName("This will be rendered in the view")]
    public string SomeText { get; set; }

    public string DescriptionText { get; set; }
}

我有一个来自DAL的模型：

public class DALModelType
{
    public string SomeText { get; set; }
}

所以你的控制器中有这样的东西：

var dalModel = someRepository.GetAll();
var viewModel = Mapper.Map<DALModelType, ViewModelType>(dalModel);

您在某个文件中拥有Automapper设置代码。这样，您只能在一个地方而不是多个方法/控制器中使用转换代码。你有custom resolver使用依赖注入（而不是（）=＆gt; new CustomResolver（）），这将包含你获取显示文本的逻辑。

Mapper.CreateMap<IHasDescription, ViewModelType>()
    .ForMember(dest => dest.DescriptionText, 
               opt => opt.ResolveUsing<CustomResolver>().ConstructedBy(() => new CustomResolver()));

不确定这是否适用于您的工作流程，但应能够为您提供所需的内容。

Answer 2

因此，进行一些小改动后，我使用Ninject Factory扩展来实现这一点。最大的变化是我的实体有足够的信息来显示任何类型（衣服或紧固件在我的设计示例中），如果该项目实际上是衣服，则紧固件特定属性将为空，反之亦然。

Public Interface IDescribable
    ReadOnly Property DescriptionText As String
End Interface

Public Enum ProductType
    CLOTHING
    FASTENER
End Enum

Public Interface ICatalogEntry
    Inherits IDescribable
    ReadOnly Property ProductId As Int64
    ReadOnly Property PublishedOn As DateTime
    ReadOnly Property ProductType As ProductType
End Interface

Public Class CatalogEntryEntity
    Public Property ProductId As Long
    Public Property ProductType As ProductType
    Public Property PublishedOn As Date
    Public Property DescriptionText As String
    Public Property Color As String
    Public Property Finish As String
    Public Property IsMetric As Boolean
End Class

然后，我可以按如下方式定义目录服务：

Public Class CatalogService
    Private ReadOnly _factory As ICatalogEntryFactory
    Private ReadOnly _repository As CatalogRepository

    Public Sub New(entryFactory As ICatalogEntryFactory, repository As CatalogRepository)
        Me._factory = entryFactory
        Me._repository = repository
    End Sub

    Public Function CurrentCatalog(currentDate As DateTime) As List(Of ICatalogEntry)
        Dim items = Me._repository.GetCatalog()
        Return (From item In items Select _factory.Create(item.ProductType.ToString(), item)).ToList()
    End Function
End Class

Public Interface ICatalogEntryFactory
    Function Create(bindingName As String, entity As CatalogEntryEntity) As ICatalogEntry
End Interface

Ninject将提供工厂（这太棒了！）假设我设置了这样的绑定：

theKernel.Bind(Of ICatalogEntry)().To(Of ClothingCatalogEntry)().Named("CLOTHING")
theKernel.Bind(Of ICatalogEntry)().To(Of FastenerCatalogEntry)().Named("FASTENER")
theKernel.Bind(Of ICatalogEntryFactory)().ToFactory(Function() New UseFirstParameterAsNameInstanceProvider())

为简洁起见，我省略了FastenerCatalogEntry; ClothingCatalogEntry是这样的：

Public Class ClothingCatalogEntry   
    Public Sub New(ByVal entity As CatalogEntryEntity)
...

this post帮我最大限度地解决了这个问题。我完全按照那里所示使用了UseFirstParameterAsNameInstanceProvider。

在ASP.NET MVC3项目中编写多态对象

2 个答案: