Question

如果注释掉use strict;，我会有几行代码可以使用。但是，我不想因为一个小部分而对整个脚本禁用它。

我需要重新编码，或以某种方式暂时禁用use strict;，然后重新启用它。第一个选项更现实，但我不知道如何更改代码以在严格模式下工作。

my ($ctc_rec_ref) = get_expected_contacts($ctc,$fy);

my @expected_ctc_rec = @$ctc_rec_ref;

print $expected_ctc_rec[0][0]."\n";
print $expected_ctc_rec[0][1]."\n";
print $expected_ctc_rec[0][2]."\n";

sub get_expected_contacts
{
    my (@ctc_rec,$i) = ((),0);
    $STMT = "SELECT DISTINCT field1, field2, field3 FROM table WHERE field4 = ? AND field5 = ? AND field6 = 'E'";
    $sth = $db1->prepare($STMT); $sth->execute(@_); 
    while(@results = $sth->fetchrow_array())
    {
        push @{ $ctc_rec[$i] }, $results[0];
        push @{ $ctc_rec[$i] }, $results[1];
        push @{ $ctc_rec[$i] }, $results[2];

        $i++;
    }   
    return (\@ctc_rec);
}

<小时/> 启用use strict;后：

不能使用字符串（“0”）作为ARRAY引用而“严格的参考”在使用时 ./return5.pl第49行。

（第49行：push @{ $ctc_rec[$i] }, $results[0];）

禁用use strict;时：

1468778 
04/01/2011 
30557

如何重写此代码以使其像禁用严格模式一样工作？如果无法做到这一点，可以暂时禁用use strict;，然后在脚本中为这段短代码重新启用吗？

Answer 1

问题在于

my (@ctc_rec,$i) = ((),0);

不符合您的想法。它与

相同

my @ctc_rec = (0);
my $i;

strict正在做它的意图并抓住你的错误。试着写：

my @ctc_rec;
my $i = 0;

代替。那应该摆脱错误。

在这种情况下，还有另一种方法可以摆脱错误，同时大大简化代码：使用selectall_arrayref。

sub get_expected_contacts
{
   return $db1->selectall_arrayref(
     "SELECT DISTINCT field1, field2, field3 FROM table WHERE field4 = ? AND field5 = ? AND field6 = 'E'",
     undef, @_
   );
}

如果你真的故意做了strict禁止的事情（但知道你在做什么），你可以在本地禁用strict：

use strict;

# this code is strict
{ 
  no strict;
  # some code that is not strict here
}
# strict is back in effect now

但是在你完全理解strict抱怨的内容以及为什么在这种情况下可以这样做之前，你永远不应该这样做。最好只禁用您必须使用的strict部分。例如，您可以说no strict 'refs';允许符号引用而不禁用其他内容strict。（注意：相同的技术适用于您应该使用的warnings编译指示。）

Answer 2

问题在于@ctc_rec和$ i的声明。试试这个，你的代码应该停止提供严格的错误：

替换：

my (@ctc_rec,$i) = ((),0);

使用：

my @ctc_rec;
my $i = 0;

如何在使用'strict'时避免产生此错误？

2 个答案: