Question

Perl6中是否存在“钳位”或等效方法或子程序？

例如

my $range= (1.0 .. 9.9)
my $val=15.3;

my $clamped=$range.clamp($val);
# $clamped would be 9.9

$val= -1.3;
$clamped=$range.clamp($val);
# $clamped would be 1.0

欢呼

Answer 1

您可能想探索的另一种技巧是使用Proxy，它使您可以在从容器中获取或存储值时定义“挂钩”。

sub limited-num(Range $range) is rw {
    my ($min, $max) = $range.minmax;
    my Numeric $store = $min;
    Proxy.new(
        FETCH => method () { $store },
        STORE => method ($new) {
            $store = max($min, min($max, $new));
        }
    )
}

# Note the use of binding operator `:=`
my $ln := limited-num(1.0 .. 9.9);
say $ln;     # OUTPUT: 1

$ln += 4.2;  
say $ln;     # OUTPUT: 5.2

$ln += 100;  
say $ln;     # OUTPUT: 9.9

$ln -= 50;   
say $ln;     # OUTPUT: 1

$ln = 0;     
say $ln;     # OUTPUT: 1

此特定的limited-num将使用其最小值进行初始化，但您也可以在声明时进行设置

my $ln1 := limited-num(1.0 .. 9.9) = 5.5;
say $ln1;    # OUTPUT 5.5;

my $ln2 := limited-num(1.0 .. 9.9) = 1000;
say $ln2;    # OUTPUT 9.9

Answer 2

我不这么认为。因此，也许：

multi clamp ($range, $value) {
  given $range {
    return .max when (($value cmp .max) === More);
    return .min when (($value cmp .min) === Less);
  }
  return $value
} 
my $range = (1.0 .. 9.9);
say $range.&clamp: 15.3; # 9.9
say $range.&clamp: -1.3; # 1

my $range = 'b'..'y';
say $range.&clamp: 'a'; # b
say $range.&clamp: 'z'; # y

MOP允许直接浏览P6系统中可用的对象。 .^methods是一种特别方便的元方法，它适用于大多数内置对象：

say Range.^methods; # (new excludes-min excludes-max infinite is-int ...

默认情况下，这仅包括Range类中定义的方法，而不包括其继承的方法。（要获得它们，您可以使用say Range.^methods: :all。这将为您带来更大的列表。）

当我尝试使用它时，我发现它还包含许多无助地命名为Method+{is-nodal}.new的方法。因此，也许可以改用它：

say Range.^methods.grep: * !~~ / 'is-nodal' /;

该网：

(new excludes-min excludes-max infinite is-int elems iterator
flat reverse first bounds int-bounds fmt ASSIGN-POS roll pick
Capture push append unshift prepend shift pop sum rand in-range
hyper lazy-if lazy item race of is-lazy WHICH Str ACCEPTS perl
Numeric min max BUILDALL)

这就是我用来引导我上述解决方案的原因；我有点了解这些方法，但是使用.^methods来提醒我。

探索可用资源的另一种方法是doc，例如the official doc's Range page。这让我着迷：

ACCEPTS min excludes-min max excludes-max bounds
infinite is-int int-bounds minmax elems list flat
pick roll sum reverse Capture rand

出于好奇，将这两个列表（排序和装袋）进行比较：

say

<ACCEPTS ASSIGN-POS BUILDALL Capture Numeric Str WHICH append
 bounds elems excludes-max excludes-min first flat fmt hyper 
 in-range infinite int-bounds is-int is-lazy item iterator
 lazy lazy-if max min new of perl pick pop prepend push
 race rand reverse roll shift sum unshift>.Bag

 ∩

<ACCEPTS Capture bounds elems excludes-max excludes-min flat
 infinite int-bounds is-int list max min minmax pick
 rand reverse roll sum>.Bag

显示：

Bag(ACCEPTS, Capture, bounds, elems, excludes-max, excludes-min,
flat, infinite, int-bounds, is-int, max, min, pick,
rand, reverse, roll, sum)

因此由于某些原因，list，minmax和sum被记录为Range方法，但没有被我的.^methods调用列出。大概将它们称为Method+{is-nodal}.new。嗯。

say Range.^lookup('minmax'); # Method+{is-nodal}.new
say Range.^lookup('minmax').name; # minmax

是的。嗯所以我可以写：

say Range.^methods>>.name.sort;

(ACCEPTS ASSIGN-POS AT-POS BUILDALL Bag BagHash Capture EXISTS-POS
 Mix MixHash Numeric Set SetHash Str WHICH append bounds elems
 excludes-max excludes-min first flat fmt hyper in-range infinite
 int-bounds is-int is-lazy item iterator lazy lazy-if list max min
 minmax new of perl pick pop prepend push race rand reverse roll
 shift sum unshift)

无论如何，希望对您有所帮助。

Answer 3

奇怪的是没有人建议使用augment。诚然，它会造成全局变化，但这可能不是问题。

augment class Range {
   method clamp ($value) { ... }
}

您将需要在use MONKEY-TYPING之前的同一范围内使用编译指示augment才能使用它。但是通过这种方式，例如，您可以简单地说$range.clamp(5)。它可以为您省掉raiph的答案一个字符，但以破坏预编译的代价（并非微不足道）为代价。

Perl6中是否存在“钳位”方法/范围/数值等子

3 个答案: