Question

如何通过构造函数调用为Haxe类生成main()（访问）方法？

例如

static function main() new App()

function new() {
    //....
}

我想用宏创建它，就像这样：

import haxe.macro.Context;
import haxe.macro.Expr;

class Build {
    macro public static function buildFields():Array<Field> {
        var fields:Array<Field> = Context.getBuildFields();
        var cls = Context.getLocalClass().get();
        var pack = cls.pack.concat([cls.name]);
        var name = pack.join(".");

        fields.push({
            name: "main",
            access: [Access.APublic, Access.AStatic],
            kind: FieldType.FFun({
                expr: macro {
                    Type.createInstance(Type.resolveClass($v{name}), []);
                },
                args: [],
                ret: null
            }),
            pos: Context.currentPos()
        });

        return fields;
    }
}

@:build(Build.buildFields())
class App {
    function new() {
        //....
    }
}

这样可以很好地生成main()方法，但是我不确定如何生成new App()而不是求助于Type.createInstance()。

Answer 1

要生成类似new App()的构造函数调用，您可以按照haxe.macro.TypePath的说明对here进行验证。

var typePath:haxe.macro.TypePath = {
    pack: cls.pack,
    name: cls.name
}

expr: macro new $typePath(),

顺便说一句，我建议不要使用class reification，它可以手动使用常规的Haxe语法声明字段：

fields = fields.concat((macro class {
    public static function main() {
        new $typePath();
    }
}).fields);

使用构建宏生成构造函数调用

1 个答案: