Question

是否可以使用TFDFBNBackup和TFDFBNRestore从本地文件创建和还原到远程服务器的备份？

我知道可以使用gbak这样的本地服务管理器命令行工具来完成此操作，但是我不想在新的Firemonkey应用程序（Windows，OSX，Linux）中使用这些工具。我想将功能完全编译到我的应用程序中，并且只能以Firebird连接访问服务器，而没有文件共享。

Answer 1

由于Arioch的建议，我可以解决它，并且效果很好。我使用gbak服务来压缩备份文件。也应该与nbackup风格一起使用。

请在下面找到一些示例代码，没有任何错误处理作为概念证明。由于Backup仅在绝对可靠的情况下才有意义，因此在出于生产目的实施此概念时，必须进行复杂的错误检测和处理。

此外，还必须修改服务器上的firebird.conf，以允许外部文件访问数据库所在的文件夹。我在Windows中创建了一些数据库的备份，并对传输到本地计算机的文件进行了二进制比较。

在示例中，我提供了标签和进度条。备份组件应设置为冗长以显示进度，尽管这会减慢服务器上的备份速度，但我希望能够向用户提供反馈。

procedure TForm1.Button1Click(Sender: TObject);
var
  count: int64;
  fs: TFileStream;
  x: integer;

  procedure dropBackupTable;
  begin
    with FDQuery do
    begin
      sql.text := 'execute block as ' + 'begin ' +
        'if (exists(select 1 from rdb$relations where rdb$relation_name=''BACKUP'')) then ' +
        'execute statement ''drop table backup'';' + 'end';
      execute;
    end;
  end;

begin

  lbl.text := 'Online backup on server...';
  dropBackupTable;
  pb.Value := 2;
  pb.Max := 2000;
  with FDIbBackup do
  begin
    host := '192.168.2.14';
    database := 'r:\databases\office.fdb';
    port := 1216;
    UserName := 'SYSDBA';
    Password := '???????';
    BackupFiles.Clear;
    BackupFiles.add('r:\databases\back.fbk');
    Backup;
  end;

  lbl.text := 'Copying backup file...';

  with FDQuery do
  begin
    sql.text := 'create table backup external ''r:\databases\back.fbk'' (x integer)';
    execute;
    sql.text := 'select count(*) from backup';
    open;
    count := fields[0].AsInteger;
    close;
    pb.Max := count div 1024;
    pb.Value := 0;
    sql.text := 'select * from backup';
    open;
    fs := TFileStream.create('d:\temp\local.fbk', fmCreate, (fmShareDenyRead or fmShareDenyNone));
    count := 0;
    while not eof do
    begin
      inc(count);
      x := fields[0].AsInteger;
      fs.write(x, sizeOf(x));
      if count > 1023 then
      begin
        pb.Value := pb.Value + 1;
        application.processmessages;
        count := 0;
      end;
      next;
    end;
    close;
    fs.free;
    pb.Value := 0;
  end;

  dropBackupTable;

  lbl.text := 'Ready.';
end;

procedure TForm1.FBBackProgress(ASender: TFDPhysDriverService; const AMessage: string);
begin
  if pb.Value = pb.Max then
    pb.Value := 2
  else
    pb.Value := pb.Value + 1;
  application.processmessages;
end;

Delphi Firedac将Firebird数据库备份到本地文件

1 个答案: