Question

我正在使用Word的Office365版本。我已经创建了一个VBA用户表单，其中包含带有辅助文本作为初始值的文本框。我正在使用以下代码清除用户输入文本字段中的值，并在帮助者文本空白时重新填充它们：

Private Sub txtCount_Enter() 
'When the user enters the field, the value is wiped out
  With txtCount
    If .Text = "Count No" Then
      .ForeColor = &H80000008
      .Text = ""
    End If
  End With
End Sub

Private Sub txtCount_AfterUpdate() 
'If the user exits the field without entering a value, re-populate the default text
  With txtCount
    If .Text = "" Then
        .ForeColor = &HC0C0C0
        .Text = "Count No"
    End If
  End With
End Sub

我的表单中有12个左右的字段。我知道我可以以某种方式访问表单中的文本框集合，但是可以对它们调用操作吗？有人可以给我一个例子吗？

Answer 1

将每个文本框的默认值放在.text属性和.tag属性中，以使此代码起作用。

当调用ControlToggle（Boolean）时，它将浏览所有控件（但仅目标TextBoxes）。如果传递了True，则如果文本框的值为默认值（位于.tag属性中），它将在控件中隐藏文本。如果传递False，它将找到任何空白字段，并使用默认字段重新填充。

Private Sub ControlToggle(ByVal Hide As Boolean)

    Dim oControl As Control
    For Each oControl In Me.Controls
        If TypeName(oControl) = "TextBox" Then
            If Hide Then
                If oControl.Text = oControl.Tag Then
                    oControl.Text = ""
                    oControl.ForeColor = &H80000008
                End If
            Else
                If oControl.Text = "" Then
                    oControl.Text = oControl.Tag
                    oControl.ForeColor = &HC0C0C0
                End If
            End If

        End If
    Next

End Sub

Answer 2

我的另一个答案集中在遍历所有控件上。要切换默认文本，请在文本框进入和退出控件时（不循环）按文本框进行切换。我建议根据先前的答案使用一个功能。

您仍然需要同时在.Tag和.Text属性中填充默认文本

Private Sub ToggleControl(ByRef TB As Control, ByVal Hide As Boolean)
    If Hide Then
        If TB.Text = TB.Tag Then
            TB.Text = ""
            TB.ForeColor = &H80000008
        End If
    Else
        If TB.Text = "" Then
            TB.Text = TB.Tag
            TB.ForeColor = &HC0C0C0
        End If
    End If
End Sub

Private Sub TextBox1_AfterUpdate()
    Call ToggleControl(TextBox1, False)
End Sub

Private Sub TextBox1_Enter()
    Call ToggleControl(TextBox1, True)
End Sub

Word VBA：定位多个文本输入字段，并在_Enter（）和_AfterUpdate（）上更改Value

2 个答案: