Question

我有一个我正在制作的RPG游戏画面：

:OBJ1
CLS
echo.
echo.   
echo The tiger rolls down the steep hill...
echo What do you do?
echo.
echo.
CHOICE /c abc /n /m ">"
IF %errorlevel%==1 (GOTO ATTACK)
IF %errorlevel%==2 (GOTO WALK)
IF %errorlevel%==3 (GOTO COLLECT)

正如您所知，一旦您选择了一个选项，它就会进入另一个屏幕。在该屏幕之后，您选择另一个选项。而另一个。我有很多类似的代码，每个都有不同的情况。我想知道如果有一种方法可以全局检测何时按下字母“q”，而不是为每种情况暂停添加选项“q”。

因此无论屏幕如何，如果按“q”，它会立即进入暂停菜单。

非常感谢：）

Answer 1

这是一个小小的演示：

@ECHO Off
SETLOCAL
SET Posx=15
SET Posy=15
SET Posz=0
CALL :choose awc "ATTACK:Attack" "WALK:Walk" "COLLECT:Collect"
ECHO Jump to %jumpto% as choice made was %choicemade%
CALL :choose eds "EAT:Eat Ration" "DRINK:Drink Potion" "SLEEP:Sleep"
ECHO Jump to %jumpto% as choice made was %choicemade%
CALL :choose news "NORTH:Go North" "EAST:Go East" "SOUTH:Go South" "WEST:Go West"
ECHO Jump to %jumpto% as choice made was %choicemade%
ECHO ---------------------------------------------------
CALL :choose news "GO 0 1:Go North" "GO 1 0:Go East" "GO -1 0:Go West" "GO 0 -1:Go South"
ECHO CALL :%jumpto% as choice made was %choicemade%
CALL :%jumpto%
CALL :choose news "GO 0 1:Go North" "GO 1 0:Go East" "GO -1 0:Go West" "GO 0 -1:Go South"
ECHO CALL :%jumpto% as choice made was %choicemade%
CALL :%jumpto%
CALL :choose newsd "GO 0 1:Go North" "GO 1 0:Go East" "GO -1 0:Go West" "GO 0 -1:Go South" "GO 0 0 1:Down Stairs"
ECHO CALL :%jumpto% as choice made was %choicemade%
CALL :%jumpto%

GOTO :EOF

:: Move in a direction
:GO
ECHO Current position: %posx% %posy% AT level %posz%
SET /a posx+=%1
SET /a posy+=%2
SET /a posz+=%3+0
ECHO Current position: %posx% %posy% AT level %posz%
:: set ERRORLEVEL to 0
CD .
CALL :enc_%posx%_%posy%_%posz% 2>nul

GOTO :eof

:: Encounter at 16,14,1
:enc_16_14_1
ECHO it's dark
GOTO :eof

:choose
SETLOCAL enabledelayedexpansion
SET "params=%*"
SET "choices=q%1qx"

:chooseloop
SET /a choicemade=0
FOR %%Z IN (%params% " :Pause" "ENDGAME:Exit Game") DO (
 FOR /f "tokens=1*delims=:" %%X IN ("%%~Z") DO (
  IF !choicemade! neq 0 (
   CALL ECHO %%choices:~!choicemade!,1%% %%Y
   SET "jumpto!choicemade!=%%X"
  )
  SET /a choicemade +=1
 )
)
choice /c %choices:~1% /n /m ">"
SET "jumpto=!jumpto%errorlevel%!"
SET "choicemade=!choices:~%errorlevel%,1!"
IF NOT "%choicemade%"=="q"  GOTO exitchoose
:: pause code

PAUSE

GOTO chooseloop

:exitchoose
endlocal&SET "jumpto=%jumpto%"&SET "choicemade=%choicemade%"
GOTO :eof

我不明白为什么你需要一个pause功能。批处理将暂停，直到您在任何情况下操作密钥。

:choose子例程需要n个参数。第一个是有效键列表（q和x由例程添加），其余为"destination-data: prompt-text"，按照指定有效键的顺序。

变量choices设置为指定的选项，最后加q和x（因为这些始终有效）加上开头的额外q。我将这个额外的字符放入，因为批处理子字符串计数来自“字符0”，而errorlevel建立的choice计数来自1。

:chooseloop回应来自choices的1个字符的子字符串，具体取决于choicemade，它只是一个计数器。我们不想在params中显示第一个参数，因此从choicemade=1开始，显示从choicemade字符开始的单字符字符串，以及菜单文本，然后将jumpto1 .. jumpton设置为目标数据。

做出选择，设置errorlevel。

使用errorlevel根据需要将jumpto设置为jumpto1 .. jumpton中的目标数据，并将choicemade设置为实际的选择字母

现在，如果选择字母不是q，我们需要返回调用者，但如果 q我们执行暂停，并返回:chooseloop重复菜单生成和choice条目。

如果选择字符不是q，我们只需终止本地环境，并为主例程设置jumpto和choicemade。

如果您运行演示，您会发现jumpto包含目标数据。你可以直接使用它，或者你可能有点偷偷摸摸。

请注意，在第4次演示之后，CALL :%jumpto%将被执行。 :GO例程接受两个参数（可选3）在地图上移动x，y [，z]。

:GO例程只是将第一个参数添加到posx，将第二个参数添加到posy。第三个参数可能存在也可能不存在，因此添加0以满足set /a的语法。我已经在x，y，z位置之前和之后报告了。

现在移动了，我们使用errorlevel将0设置为cd .，然后尝试调用:enc_%posx%_%posy%_%posz%即内部子例程enc_thecubeyouarelocatedin。这可能存在也可能不存在。如果它存在，它将被执行。如果不是，则cmd只会发出一条错误消息，该消息可由2>nul删除，并将errorlevel设置为1。请注意，goto nonexistenetlabel将退出程序并生成令人讨厌的消息。

通过这种方式，可以处理特定位置的特价，但最终它将全部返回到执行call :GO...的原始位置

如果您正在寻找加载/保存游戏的方法，请尝试此处：https://stackoverflow.com/a/50639536/2128947

如何通过按“q”随时使批处理文件给出菜单，而不必在整个过程中反复写入？

1 个答案: