Question

在下面的MWE中，我有一系列属性，我对它进行排序，然后输出XML和属性。当我输出整个XML时，它看起来排序：

<data attr="attrA">testA</data><data attr="attrZ">testZ</data> 
<data attr="attrZ">testZ</data><data attr="attrA">testA</data>

但是，如果我打印下一个属性，我不会得到排序的输出（升序==降序）：

attrZ attrA
attrZ attrA

这怎么可能？我怎样才能获得：

attrA attrZ 
attrZ attrA

...

<xsl:stylesheet version="2.0"
     xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
     xmlns:xs="http://www.w3.org/2001/XMLSchema">    
     <xsl:variable name="dataUnsorted" as="element()*">
            <data attr="attrZ">testZ</data>
            <data attr="attrA">testA</data>
     </xsl:variable>

     <xsl:variable name="dataAscending" as="element()*">
      <xsl:perform-sort select="$dataUnsorted">
        <xsl:sort select="@attr" order="ascending"/> 
      </xsl:perform-sort>
    </xsl:variable>

     <xsl:variable name="dataDescending" as="element()*">
      <xsl:perform-sort select="$dataUnsorted">
        <xsl:sort select="@attr" order="descending"/> 
      </xsl:perform-sort>
    </xsl:variable>  

     <xsl:template match="/">
          <xsl:message>
          <xsl:copy-of select="$dataAscending"/>
      </xsl:message> 
      <xsl:message>
           <xsl:copy-of select="$dataDescending"/>
      </xsl:message> 
      <xsl:message>
          <xsl:value-of select="$dataAscending/@attr"/>
      </xsl:message> 
      <xsl:message>
           <xsl:value-of select="$dataDescending/@attr"/>
      </xsl:message> 
      </xsl:template>    
</xsl:stylesheet>

Answer 1

/@attr中的步骤$dataAscending/@attr选择属性节点并按文档顺序对它们进行排序，即选择步骤选择节点的方式（https://www.w3.org/TR/xpath-31/#id-path-operator）。

如果您想保留订单，您有三种选择：

使用for in return表达式：for $e in $dataAscending return $e/@attr
对属性序列进行排序和存储，而不是元素序列
仅限XPath / XSLT 3+：使用!：$dataAscending!@attr

XSL执行排序不处理属性？

1 个答案: