Question

我需要使用Coldfusion \ Java在Windows服务器上创建一个包含多个文件的TAR文件。我已经找到了许多解包它们的例子，但很少创建它们。我发现这个使用gzip向文件中添加一些文本的例子，但是我需要添加文件。我也不是100％确定gzip与构建tarball是一回事。这个项目被转让给我，只需很短的转向，我就会旋转我的车轮，所以非常感谢任何正确方向的帮助：

Win Server 2012， ColdFusion 10， Java版本1.7.0_15

    <cfset lineBreak = chr(13) & chr(10) />
<!--- open the sitemap file --->
<cfset tarFilePath = "#application.imageingFolder#DTSimages\Pending\tiff.gz" />
#tarFilePath#
<!--- create streams --->
<cfset outputStream = CreateObject("java", "java.io.FileOutputStream").Init(
            CreateObject("java","java.io.File").Init(tarFilePath)) />
<cfset gzipStream = CreateObject("java", "java.util.zip.GZIPOutputStream").Init(outputStream) />
<cfsavecontent variable="siteMapHeader"><?xml version="1.0" encoding="UTF-8"?>
<urlset xmlns="http://www.sitemaps.org/schemas/sitemap/0.9"
    xmlns:image="http://www.sitemaps.org/schemas/sitemap-image/1.1"
    xmlns:video="http://www.sitemaps.org/schemas/sitemap-video/1.1">
</cfsavecontent>
<cfset siteMapFooter = "</urlset>" />
<cfset gzipStream.write(ToString(siteMapHeader).GetBytes()) />

<cfset gzipStream.close() />
<cfset outputStream.close() />

Answer 1

虽然often used together，但tar和gzip是不同的东西。来自ZIP vs. GZIP：

... tar命令用于创建存档（不是压缩）和另一个程序（gzip或压缩）用于压缩存档。

一个简单的选择是安装7-Zip（支持tar和gzip）并使用适当的参数从cfexecute调用它。要创建TAR文件（未压缩）：

<!--- 
   "a" - add files to archive 
   "t" - Type of archive 
   output .tar file 
   space separated list of files to add 
--->
<cfexecute name="c:\Program Files\7-Zip\7z.exe"
    arguments=" a -ttar c:\path\myarchive.tar c:\path\file1.xlsx c:\temp\otherfile.txt"
    variable="output"
    errorVariable="error"
    timeout="60"    />

<cfoutput>
    output = #output#<br>
    error = #error#<br>
</cfoutput>

对于java选项，this thread提到使用Apache Commons库来创建TAR文件。它也恰好与CF捆绑在一起，所以它应该开箱即用：

http://www.oracle.com/technetwork/articles/java/compress-1565076.html

<cfscript>
    // Initialize TAR file to generate
    outputPath = "c:/temp/outputFile3.tar";
    os = createObject("java", "java.io.FileOutputStream").init(outputPath);
    tar = createObject("java", "org.apache.commons.compress.archivers.tar.TarArchiveOutputStream").init(os);

    // Add an entry from a string
    someTextContent = '<?xml version="1.0" encoding="UTF-8"?>....';
    binaryContent = charsetDecode(someTextContent, "utf-8");
    entry = createObject("java", "org.apache.commons.compress.archivers.tar.TarArchiveEntry").init("siteHeader.xml");
    entry.setSize(arrayLen(binaryContent));
    tar.putArchiveEntry(entry);
    tar.write(binaryContent);
    tar.closeArchiveEntry();

    // Create an entry from a file
    inputFile = createObject("java", "java.io.File").init("c:/path/someImage.jpg");
    entry = tar.createArchiveEntry(inputFile, "myImage.jpg");
    tar.putArchiveEntry(entry);
    tar.write(FileReadBinary(inputFile));
    tar.closeArchiveEntry();

    // Close TAR file
    tar.flush();
    tar.close();
</cfscript>

有关详细信息，请参阅文档：Apache Commons - The TAR package

NB：如果您要归档大型文件，请查看缓冲。有关基本概念，请参阅Code Sample 3: Zip.java。忽略它是Zip文件的事实。基本概念是相同的，只有类别不同。

在Windows服务器上使用Coldfusion \ Java创建TAR文件（tarball）

1 个答案: