Question

我在我的查询控制台中尝试了下面提到的Xquery，但是我需要从集合中搜索数据吗？

let $value1 := "antony"
let $value2 := "cse"
for $uri1 in cts:uris((),(), (  
    cts:element-query(xs:QName("P"),
      cts:and-query((
          cts:element-attribute-value-query(xs:QName("P"),xs:QName("name"),$value1),
          cts:element-attribute-value-query(xs:QName("P"),xs:QName("value"),$value2)
      ))
    )
))
let $xml := doc($uri1)
return $xml//PS/P [@name eq "volume"]/@value

请建议我如何在上面提到的XQuery中添加该集合？

Answer 1

首先我想说，既然你最终需要文档而不是URI，那么使用cts：search会更直接。您可以添加＆＃34;未过滤的＆＃34;如果您想避免过滤成本，请选择：

let $value1  := "antony"
let $value2 := "cse"
return
cts:search( doc(), 
  cts:element-query(xs:QName("P"),
    cts:and-query((
      cts:element-attribute-value-query(xs:QName("P"),xs:QName("name"),$value1),
      cts:element-attribute-value-query(xs:QName("P"),xs:QName("value"),$value2)
    ))
  ), "unfiltered"
)//PS/P[@name eq "volume"]/@value

或者，因为你只关心/ PS / P元素：

cts:search( doc()//PS/P, 
  cts:element-query(xs:QName("P"),
    cts:and-query((
      cts:element-attribute-value-query(xs:QName("P"),xs:QName("name"),"antony"),
      cts:element-attribute-value-query(xs:QName("P"),xs:QName("value"),"cse")
    ))
  ), "unfiltered"
)[@name eq "volume"]/@value

要在集合中搜索，请将doc（）替换为集合（＆＃34; yourcollection＆＃34;）：

cts:search( collection("yourcollection")//PS/P, 
  cts:element-query(xs:QName("P"),
    cts:and-query((
      cts:element-attribute-value-query(xs:QName("P"),xs:QName("name"),"antony"),
      cts:element-attribute-value-query(xs:QName("P"),xs:QName("value"),"cse")
    ))
  ), "unfiltered"
)[@name eq "volume"]/@value

marklogic 8 - 如何搜索集合

1 个答案: