Question

我使用Android版本23进行开发。但现在我想调试只安装了版本19的设备。

为此，我将gradle文件更改为

apply plugin: 'com.android.application'

android {
    compileSdkVersion 19
    buildToolsVersion "19.1.0"

    defaultConfig {
        applicationId "com.mydomain.myapp"
        minSdkVersion 16
        targetSdkVersion 19
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
}

dependencies {
    compile fileTree(include: ['*.jar'], dir: 'libs')
    testCompile 'junit:junit:4.12'
    compile fileTree(include: ['dtp_library'], dir: 'libs')
    compile project(':libs:dtp_library')

    compile 'com.android.support:appcompat-v7:19.+'
    compile 'com.android.support:design:19.+'
    compile 'com.android.support:support-v4:19.+'        
}

但这一行

compile 'com.android.support:design:19.+'

抛出编译器错误

无法解决＆com; android.support：design：19。+＆＃39;

如何让它发挥作用？

Answer 1

这是我的build.gradle示例，它在API 19设备上运行得非常好。

您需要注意的一点是，您不需要减少编译SDK。这就像安装了Java 8，但编译Java 6代码。它仍然有效。

另外，我认为appcompat-v7库取决于support-v4库，因此您不需要包含它。

apply plugin: 'com.android.application'

repositories {
    jcenter()
}

android {
    compileSdkVersion 23
    buildToolsVersion "23.0.3"

    defaultConfig {
        applicationId "com.androidstack.app"
        minSdkVersion 14
        targetSdkVersion 19
        versionCode 1
        versionName "1.0"
    }
}

ext {
    supportLibVersion = '23.2.1'  // variable that can be referenced to keep support libs consistent
}

dependencies {
    compile fileTree(dir: 'libs', include: ['*.jar'])

    compile "com.android.support:appcompat-v7:${supportLibVersion}"
    compile "com.android.support:design:${supportLibVersion}"
}

Answer 2

删除compile 'com.android.support:design:19.+'，然后尝试

使用Android Studio调试旧的Android版本

2 个答案: