Question

我想暂停播放一个YouTube视频，当我没有在后台播放时，我用快捷键播放。但我无法理解如何定位chrome及其中一个标签。

按快捷键将“空格键”键发送到chrome youtube标签。

这看起来很简单，但我对此感到很陌生。

Answer 1

原始工作脚本：

SetTitleMatchMode, 2

ControlGet, OutputVar, Hwnd,,Chrome_RenderWidgetHostHWND1, Google Chrome

ControlFocus,,ahk_id %outputvar%

Loop {
    IfWinExist, YouTube
        break

    ControlSend, , ^{PgUp} , Google Chrome
    sleep 300
}
ControlSend, , {Space} , Google Chrome

ctrl + PgUp用于圈选标签，直到找到youtube标签，然后将space发送给Chrome。您必须将睡眠定时器调整到您的系统。

没有youtube标签或根本没有Chrome会导致无限循环。包括安全检查！

Answer 2

这将在不使用Chrome浏览器时播放/暂停youtube视频，并按alt + shift + p，对于在youtube上收听音乐很有用。它将找到youtube标签，播放/暂停，然后在后台全部返回到您的工作标签

SetTitleMatchMode 2
controlID := 0
tabCount := 0
#IfWinNotActive, ahk_exe chrome.exe
; Play/pause
+!p::
    ControlGet, controlID, Hwnd,,Chrome_RenderWidgetHostHWND1, Google Chrome
    ControlFocus,,ahk_id %controlID%
    IfWinExist, YouTube
    {
        ControlSend, Chrome_RenderWidgetHostHWND1, k , Google Chrome
        return
    }
    tabCount := 0
    Loop {
        IfWinExist, YouTube
            break
        ControlSend, , ^{PgUp} , Google Chrome
        sleep 150
    tabCount := tabCount + 1
    if tabCount > 10
      return
    }
    ControlSend, , k , Google Chrome
    Loop, %tabCount% {
        ControlSend, , ^{PgDn} , Google Chrome
        sleep 150
    }
    return
#IfWinNotActive

Answer 3

#Persistent
#NoEnv
#SingleInstance, Force
DetectHiddenWindows, On
SetWorkingDir %A_ScriptDir%
SetTitleMatchMode, 2

controlN := 0

return

#IfWinNotActive, ahk_exe chrome.exe
z & space::
    chromeSend("{Space}")
return


z & right::
    chromeSend("{Right}")
return

z & left::
    chromeSend("{Left}")
return

chromeSend(keys)
{
    ControlGet, controlN, Hwnd,,Chrome_RenderWidgetHostHWND1, Google Chrome
    ControlFocus,,ahk_id %controlN%
    Sleep, 50
    ControlSend, Chrome_RenderWidgetHostHWND1, %keys% , Google Chrome
}



#IfWinActive, ahk_exe chrome.exe
z & space::
    chromeSend("k")
return


z & right::
    chromeSend("{Right}")
return

z & left::
    chromeSend("{Left}")
return

使用此代码，您可以使用z +空格/箭头控制youtube。

AHK暂停\在未聚焦的Chrome选项卡中播放youtube

3 个答案: