Question

所以我有一个目录，其中创建了日志文件，我想读取最新的日志文件。该目录将包含日志文件，错误文件和一些其他文件，每次都会创建。我的日志文件名称将以test-install-＆lt;＆gt; .log

开头

如何使用批处理脚本找到哪个是最新的日志文件。

由于

Answer 1

@echo off
    setlocal enableextensions disabledelayedexpansion

    set "lastLog="
    for /f "delims=" %%a in ('dir /b /o-d "x:\logsFolder\test-install-*.log" 2^>nul') do (
        if not defined lastLog set "lastLog=%%a"
    )

    echo %lastLog%

或者，对于一长串文件，避免迭代

@echo off
    setlocal enableextensions disabledelayedexpansion

    set "lastLog="
    for /f "delims=" %%a in ('dir /b /o-d "x:\logsFolder\test-install-*.log" 2^>nul') do (
        set "lastLog=%%a" 
        goto :done
    )
:done
    echo %lastLog%

或者，如果你有一个非常大的文件列表

@echo off
    setlocal enableextensions disabledelayedexpansion

    set "lastLog="
    for /f "delims=" %%a in ('
        dir /b /o-d "x:\logsFolder\test-install-*.log" 2^>nul
        ^| cmd /q /v /c"set /p .=&if defined . (echo(!.!)"
    ') do set "lastLog=%%a" 
    echo %lastLog%

在名称以＆lt;＆gt;开头的目录中查找最新文件使用批处理脚本

1 个答案: