Question

我理解we cannot access Map properties the same way we access them in other classes，因为能够在groovy中使用点符号获取地图键。

现在，对于实现java.util.Map的类，有没有办法仍然可以从使用propertyMissing的expando元类中受益？

以下是我正在尝试的内容：

LinkedHashMap.metaClass.methodMissing = { method, args ->
    println "Invoking ${method}"
    "Invoking ${method}"
}

LinkedHashMap.metaClass.propertyMissing = { method, args ->
    println "Accessing ${method}"
    "Accessing ${method}"
}

def foo = [:]

assert "Invoking bar" == foo.bar() // this works fine
assert "Accessing bar" == foo.bar  // this doesn't work, for obvious reasons, but I'd like to be able to do that...

我一直在尝试通过自定义DelegatingMetaClasses但没有成功......

Answer 1

不确定它是否适合您的用例，但您可以在地图上使用Guava和withDefault方法...

@Grab( 'com.google.guava:guava:16.0.1' )
import static com.google.common.base.CaseFormat.*

def map
map = [:].withDefault { key -> 
    LOWER_UNDERSCORE.to(LOWER_CAMEL, key).with { alternate ->
        map.containsKey(alternate) ? map[alternate] : null
    }
}

map.possibleSolution = 'maybe'

assert map.possible_solution == 'maybe'

这样做的一个副作用是在断言之后，映射包含两个键：值对：

assert map == [possibleSolution:'maybe', possible_solution:'maybe']

Answer 2

如果我理解得很清楚，你可以提供自定义地图：

class CustomMap extends LinkedHashMap {

    def getAt(name) {
        println "getAt($name)"
        def r = super.getAt(name)
        r ? r : this.propertyMissing(name)
    }

    def get(name) {
        println "get($name)"
        super.get(name)
        def r = super.get(name)
        r ? r : this.propertyMissing(name)

    }
    def methodMissing(method, args) {
        println "methodMissing($method, $args)"
        "Invoking ${method}"
    }

    def propertyMissing(method) {
        println "propertyMissing($method)"
        "Accessing ${method}"
    }
}

def foo = [bar:1] as CustomMap

assert foo.bar == 1
assert foo['bar'] ==  1
assert foo.lol == 'Accessing lol'
assert foo['lol'] ==  'Accessing lol'
assert foo.bar() == 'Invoking bar'

Answer 3

我重读groovy Maps javadocs，我发现有两种版本的get方法。一个需要一个参数，另一个需要2个。

采用2的版本几乎完成了我在这里描述的内容：如果它找不到你的密钥，它会返回一个默认值。

我得到了预期的效果，但没有点符号，因此我只是将其作为替代解决方案发布，以防有人遇到此帖：

Map.metaClass.customGet = { key ->
    def alternate = key.replaceAll(/_\w/){ it[1].toUpperCase() }
    return delegate.get(key, delegate.get(alternate, 'Sorry...'))
}

def m = [myKey : 'Found your key']

assert 'Found your key' == m.customGet('myKey')

assert 'Found your key' == m.customGet('my_key')

assert 'Sorry...' == m.customGet('another_key')

println m

-Result -

m = [myKey：找到你的钥匙，my_key：找到你的钥匙，另一个钥匙：抱歉......，另一个钥匙：对不起......]

正如蒂姆的解决方案一样，每当我们要求初始地图中不存在的新值时，这会导致m在第二个断言+ 2个键之后包含两个键，并且默认值（抱歉...）...通过删除默认值的键来解决。例如：

Map.metaClass.customGet = { key ->
    def alternate = key.replaceAll(/_\w/){ it[1].toUpperCase() }
    def ret = delegate.get(key, delegate.get(alternate, 'Sorry...'))
    if (ret == 'Sorry...') {
        delegate.remove(key)
        delegate.remove(alternate)
    }
    ret
}

随意评论/纠正这可能导致的任何错误......只是在这里大声思考......

如何在groovy中实现java.util.Map的类上使用propertyMissing

3 个答案: