Question

我很困惑如何惯用地更改通过clojure.contrib的zip-filter.xml访问的xml树。应该尝试这样做，还是有更好的方法？

假设我有一些虚拟xml文件“itemdb.xml”，如下所示：

<itemlist> 
  <item id="1">
    <name>John</name>
    <desc>Works near here.</desc>
  </item>
  <item id="2">
    <name>Sally</name>
    <desc>Owner of pet store.</desc>
  </item>
</itemlist>

我有一些代码：

(require '[clojure.zip :as zip]
  '[clojure.contrib.duck-streams :as ds]
  '[clojure.contrib.lazy-xml :as lxml]
  '[clojure.contrib.zip-filter.xml :as zf]) 

(def db (ref (zip/xml-zip (lxml/parse-trim (java.io.File. "itemdb.xml")))))

;; Test that we can traverse and parse.
(doall (map #(print (format "%10s: %s\n"
       (apply str (zf/xml-> % :name zf/text))
       (apply str (zf/xml-> % :desc zf/text))))
     (zf/xml-> @db :item)))

;; I assume something like this is needed to make the xml tags
(defn create-item [name desc]
  {:tag :item
   :attrs {:id "3"}
   :contents
   (list {:tag :name :attrs {} :contents (list name)}
         {:tag :desc :attrs {} :contents (list desc)})})

(def fred-item (create-item "Fred" "Green-haired astrophysicist."))

;; This disturbs the structure somehow
(defn append-item [xmldb item]
  (zip/insert-right (-> xmldb zip/down zip/rightmost) item))

;; I want to do something more like this
(defn append-item2 [xmldb item]
  (zip/insert-right (zip/rightmost (zf/xml-> xmldb :item)) item))

(dosync (alter db append-item2 fred-item))

;; Save this simple xml file with some added stuff.
(ds/spit "appended-itemdb.xml"
    (with-out-str (lxml/emit (zip/root @db) :pad true)))

我不清楚在这种情况下如何正确使用clojure.zip函数，以及它如何与zip-filter交互。

如果你在这个小例子中发现任何特别奇怪的东西，请指出。

Answer 1

首先，您应该在Fred的定义中使用:content（而不是:contents）。

随着这种变化，以下似乎有效：

(-> (zf/xml-> @db :item) ; a convenient way to get to the :item zipper locs
    first                ; but we actually need just one
    zip/rightmost        ; let's move to the rightmost sibling of the first :item
                         ; (which is the last :item in this case)
    (zip/insert-right fred-item) ; insert Fred to the right
    zip/root)            ; get the modified XML map,
                         ; which is the root of the modified zipper

您的append-item2非常相似，只需要进行两次更正：

zf/xml->返回一系列拉链位置; zip/rightmost只接受一个，所以你必须首先捕获一个（因此上面的first）;
完成修改拉链后，需要使用zip/root返回基础树的（修改后的版本）。

作为关于风格的最后一点，print + format = printf。： - ）

Answer 2

在创建项目中，您输入错误：内容为：内容，您应该更喜欢向量到文字列表。

（我打算做一个更全面的回答，但Michal已经写好了。）

zip-filter的替代方案是Enlive：

(require '[net.cgrand.enlive-html :as e]) ;' <- fix SO colorizer

(def db (ref (-> "itemdb.xml" java.io.File. e/xml-resource))

(defn create-item [name desc]
  {:tag :item
   :attrs {:id "3"}
   :content [{:tag :name :attrs {} :content [name]}
             {:tag :desc :attrs {} :content [desc]}]})

(def fred-item (create-item "Fred" "Green-haired astrophysicist."))

(dosync (alter db (e/transformation [:itemlist] (e/append fred-item))))

在Clojure中插入到XML文件的Zipper树中

2 个答案: