Question

每个节点包含字段LIGHT_COLOUR中的颜色列表，由字母R（红色），W（白色）等标识。在字段中，LIGHT_COLOUR只能是一个颜色/字母或多个由＆＃39; - ＆＃39;分隔的字体。

这是我的测试用XML：

<LIGHT_INFORMATION_LIST>
    <LIGHT_INFORMATION>
        <LIGHT_CHARACTERISTICS>Al</LIGHT_CHARACTERISTICS>
        <LIGHT_COLOUR>W-G</LIGHT_COLOUR>
    </LIGHT_INFORMATION>
    <LIGHT_INFORMATION>
        <LIGHT_CHARACTERISTICS>Al</LIGHT_CHARACTERISTICS>
        <LIGHT_COLOUR>W-R</LIGHT_COLOUR>
    </LIGHT_INFORMATION>
    <LIGHT_INFORMATION>
        <LIGHT_CHARACTERISTICS>F</LIGHT_CHARACTERISTICS>
        <LIGHT_COLOUR>R</LIGHT_COLOUR>
    </LIGHT_INFORMATION>
    <LIGHT_INFORMATION>
        <LIGHT_CHARACTERISTICS>F</LIGHT_CHARACTERISTICS>
        <LIGHT_COLOUR>G</LIGHT_COLOUR>
    </LIGHT_INFORMATION>
    <LIGHT_INFORMATION>
        <LIGHT_CHARACTERISTICS>F</LIGHT_CHARACTERISTICS>
        <LIGHT_COLOUR>W</LIGHT_COLOUR>
    </LIGHT_INFORMATION>
</LIGHT_INFORMATION_LIST>

这是我的XSLT：

<xsl:for-each select="LIGHT_INFORMATION_LIST">
    <xsl:for-each select="LIGHT_INFORMATION">
        <xsl:for-each select="LIGHT_COLOUR">
            <xsl:value-of select="."/>
        </xsl:for-each> 
    </xsl:for-each> 
</xsl:for-each>

现在我的输出是：W-G W-R R G W
这是LIGHT_COLOUR字段中的所有元素。

我会输出所有元素一次（LIGHT_COLOUR distinct）。

在输出中我会：W G R

Answer 1

执行此操作的一种方法是首先创建一个包含连接成一个字符串的所有单独LIGHT_COLOUR元素的变量

  <xsl:variable name="allColours">
     <xsl:for-each select="LIGHT_INFORMATION_LIST/LIGHT_INFORMATION">
        <xsl:value-of select="concat(LIGHT_COLOUR, '-')" />
     </xsl:for-each>
  </xsl:variable>

因此，在您的示例中，它将设置为“W-G-T-W-R-E-E-R-E-E - ”。

然后，您可以使用递归模板将字符串拆分为字符，但同时保留不同值的运行列表。因此，在每次迭代时，它获取连字符之前的下一个字符，并检查它是否已经在不同值列表中。如果没有，它会将其添加到此列表中，递归模板将继续处理，直到没有任何内容。

试试这个XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="xml" indent="yes"/>

   <xsl:template match="/">
      <xsl:variable name="allColours">
         <xsl:for-each select="LIGHT_INFORMATION_LIST/LIGHT_INFORMATION">
            <xsl:value-of select="concat(LIGHT_COLOUR, '-')" />
         </xsl:for-each>
      </xsl:variable>

      <xsl:call-template name="tokenizeDistinct">
         <xsl:with-param name="string" select="$allColours" />
      </xsl:call-template>
   </xsl:template>

   <xsl:template name="tokenizeDistinct">
      <xsl:param name="string" />
      <xsl:param name="splitChar" select="'-'" />
      <xsl:param name="distinctList" select="' '" />

      <xsl:variable name="nextChar" select="substring-before(concat($string, $splitChar), $splitChar)" />
      <xsl:variable name="newDistinctList">
         <xsl:value-of select="$distinctList" />
         <xsl:if test="$nextChar != '' and not(contains($distinctList, concat(' ', $nextChar, ' ')))">
            <xsl:value-of select="concat($nextChar, ' ')" />
         </xsl:if>
      </xsl:variable>
      <xsl:choose>
         <xsl:when test="contains($string, $splitChar)">
            <xsl:call-template name="tokenizeDistinct">
               <xsl:with-param name="string" select="substring-after($string, $splitChar)" />
               <xsl:with-param name="splitChar" select="$splitChar" />
               <xsl:with-param name="distinctList" select="$newDistinctList" />
            </xsl:call-template>
         </xsl:when>
         <xsl:otherwise>
            <xsl:value-of select="$newDistinctList" />
         </xsl:otherwise>
      </xsl:choose>
   </xsl:template>
</xsl:stylesheet>

应用于XML时，输出以下内容

W G R

Answer 2

如果 - 我怀疑 - 有一个已知的可能颜色列表，在这个列表中每种颜色都用一个字母表示，那么这可能很简单。例如，以下样式表：

XSLT 1.0

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:param name="color-list">RGBCMYKW</xsl:param> 

<xsl:template match="/">
    <xsl:variable name="present-colors">
        <xsl:for-each select="LIGHT_INFORMATION_LIST/LIGHT_INFORMATION">
            <xsl:value-of select="translate(LIGHT_COLOUR, '-', '')"/>
        </xsl:for-each> 
    </xsl:variable> 
    <result>
        <xsl:value-of select="translate($color-list, translate($color-list, $present-colors, ''), '')"/>
    </result>
</xsl:template>

</xsl:stylesheet>

应用于您的示例输入时，将返回：

<?xml version="1.0" encoding="UTF-8"?>
<result>RGW</result>

返回节点中一次采用的所有XML元素

2 个答案: