Question

我已经获得了RTL格式的gcc控制流图转储，并使用graphviz对其进行了可视化。但是，仍然不清楚哪些跳转/呼叫是直接的，哪些是间接的。有什么建议可以将它们彼此区分开来吗？

Answer 1

直接调用通常包含 symbol_ref 作为RTL的一部分，因为编译器确切地知道调用目标。对于间接调用，存在使用一个或多个寄存器但不存在符号的存储器引用。因此，内存RTL子表达式类似于我们在mov指令中看到的标准内存读写格式。

例如，Linux内核3.19中函数 do_early_param 内的第一个调用指令是直接调用：

callq  ffffffffc1657839 <strcmp>

各个RTL

(call_insn/i:TI 19 18 134 4 (set (reg:SI 0 ax)                          
    (call (mem:QI (symbol_ref:DI ("strcmp") [flags 0x41] <function_decl 0x2b2f6f0e1a00 strcmp>) [0 __builtin_strcmp S1 A8])
        (const_int 0 [0]))) init/main.c:436 631 {*call_value}               
 (expr_list:REG_DEAD (reg:DI 5 di)                                          
    (expr_list:REG_DEAD (reg:DI 4 si)                                       
        (expr_list:REG_EH_REGION (const_int 0 [0])                          
            (nil))))                                                        
(expr_list:REG_FRAME_RELATED_EXPR (use (reg:DI 5 di))                       
    (expr_list:REG_FRAME_RELATED_EXPR (use (reg:DI 4 si))                   
        (nil))))

稍后，我们有一个间接的电话：

 callq  *0x8(%rbx)

转换为

  (call_insn:TI 38 37 140 7 (set (reg:SI 0 ax)                            
        (call (mem:QI (mem/f:DI (plus:DI (reg/v/f:DI 3 bx [orig:60 p ] [60])    
                        (const_int 8 [0x8])) [0 MEM[base: p_1, offset: 8B]+0 S8 A64]) [0 *D.45869_10 S1 A8]) 
            (const_int 0 [0]))) init/main.c:439 631 {*call_value}               
     (expr_list:REG_DEAD (reg:DI 5 di)                                          
        (nil))                                                                  
    (expr_list:REG_FRAME_RELATED_EXPR (use (reg:DI 5 di))                       
        (nil)))

（没有symbol_ref）。对于JMP指令，请记住，间接JMP实际上可能是尾调用，在RTL中显示为CALL_P指令。例如，在函数 mtrr_bp_init 中我们有

 jmpq   *%rax

在RTL中

 (call_insn/j:TI 144 143 145 25 (call (mem:QI (reg/f:DI 0 ax [orig:151 mtrr_if.32_31->set_all ] [151]) [0 *D.30602_32 S1 A8])
        (const_int 0 [0])) arch/x86/kernel/cpu/mtrr/main.c:744 623 {*sibcall}   
     (expr_list:REG_DEAD (reg/f:DI 0 ax [orig:151 mtrr_if.32_31->set_all ] [151])
        (nil))                                                                  
    (nil))

除此之外，通常间接jmp将显示为PARALLEL RTL表达式。例如，在函数 update_mp_table 中，我们看到

jmpq   *-0x3eff7188(,%rax,8)

在RTL中是：

    (jump_insn:TI 173 170 174 22 (parallel [                              
            (set (pc)                                                           
                (mem/u/c:DI (plus:DI (mult:DI (reg:DI 0 ax [orig:182 *mpt_138 ] [182])
                            (const_int 8 [0x8]))                                
                        (label_ref:DI 175)) [0 S8 A8]))                         
            (use (label_ref 175))                                               
        ]) arch/x86/kernel/mpparse.c:741 613 {*tablejump_1}                     
     (expr_list:REG_DEAD (reg:DI 0 ax [orig:182 *mpt_138 ] [182])               
        (insn_list:REG_LABEL_OPERAND 175 (nil)))                                
 -> 175)

区分GCC的RTL转储中的调用/跳转类型

1 个答案: