Question

在我的XSLT中，我正在预处理大型XML文件，并且必须操纵某些值（因为源系统没有按预期提供它们）。

属性“name”和“nm”都应该包含相同的文本。但是，在原始XML中它们是空的。

我需要使用另一个属性“description”和硬编码查找列表生成它们（例如description =“Some value”表示nm和name都应该是“NameABC”）。因为我的查找列表很长，所以我真的不想在两个模板中实现它，一个用于属性“nm”，一个用于“name”。相反，我想在一个地方实现我的查找列表，并且总是一次更改两个属性。

有没有办法做到这一点？

这是我原来的XML（当然是简化示例）：

<?xml version="1.0" encoding="UTF-8"?>
<Sample>
    <Header>
        <Type>A</Type>
    </Header>
    <DataSet name="">
        <Info description="Some value" nm="" other="123"/>
    </DataSet>
    <DataSet name="">
        <Info description="Another value" nm="" other="456"/>
    </DataSet>
</Sample>

期望的输出：

<?xml version="1.0" encoding="UTF-8"?>
<Sample>
    <Header>
        <Type>A</Type>
    </Header>
    <DataSet name="NameABC">
        <Info description="Some value" other="123" nm="NameABC"/>
    </DataSet>
    <DataSet name="NameXYZ">
        <Info description="Another value" other="456" nm="NameXYZ"/>
    </DataSet>
</Sample>

我当前的XSLT（仅更改属性“nm”）：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:fo="http://www.w3.org/1999/XSL/Format">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

    <xsl:template match="Sample">
        <xsl:copy>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="DataSet">
        <xsl:copy>
            <xsl:for-each select="@*">
                <xsl:attribute namespace="" name="{name()}"><xsl:value-of select="."/></xsl:attribute>
            </xsl:for-each>
            <xsl:apply-templates/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="Info">
        <xsl:element name="Info">
            <xsl:for-each select="@*">
                <xsl:attribute namespace="" name="{name()}"><xsl:value-of select="."/></xsl:attribute>
            </xsl:for-each>
            <xsl:apply-templates select="@nm"/>
            <xsl:copy-of select="node()"/>
        </xsl:element>
    </xsl:template>

    <xsl:template match="Info/@nm">
        <xsl:choose>
            <xsl:when test="/Sample/Header/Type='A' and .=''">
                <xsl:attribute name="nm">
                    <xsl:choose>
                        <xsl:when test="../@description = 'Some value'">NameABC</xsl:when>
                        <xsl:when test="../@description = 'Another value'">NameXYZ</xsl:when>
                    </xsl:choose>
                </xsl:attribute>
            </xsl:when>
            <xsl:otherwise>
                <xsl:copy-of select="."/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>

    <xsl:template match="*">
        <xsl:copy-of select="."/>
    </xsl:template>

</xsl:stylesheet>

Answer 1

怎么样：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="DataSet">
    <xsl:variable name="nm">
        <xsl:choose>
            <xsl:when test="Info/@description = 'Some value'">NameABC</xsl:when>
            <xsl:when test="Info/@description = 'Another value'">NameXYZ</xsl:when>
        </xsl:choose>
    </xsl:variable>
    <xsl:copy>
        <xsl:apply-templates select="@*"/>
        <xsl:attribute name="name"><xsl:value-of select="$nm"/></xsl:attribute>
        <xsl:apply-templates select="node()" >
            <xsl:with-param name="nm" select="$nm"/>
        </xsl:apply-templates>
    </xsl:copy>
</xsl:template>

<xsl:template match="Info">
    <xsl:param name="nm"/>
    <xsl:copy>
        <xsl:apply-templates select="@*"/>
        <xsl:attribute name="nm"><xsl:value-of select="$nm"/></xsl:attribute>
        <xsl:apply-templates select="node()"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

替代：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="DataSet/@name">
    <xsl:attribute name="name">
        <xsl:call-template name="getName">
            <xsl:with-param name="desc" select="../Info/@description"/>
        </xsl:call-template>
    </xsl:attribute>
</xsl:template>

<xsl:template match="Info/@nm">
        <xsl:attribute name="nm">
            <xsl:call-template name="getName">
                <xsl:with-param name="desc" select="../@description"/>
            </xsl:call-template>
        </xsl:attribute>
</xsl:template>

<xsl:template name="getName">
    <xsl:param name="desc"/>
    <xsl:choose>
        <xsl:when test="$desc = 'Some value'">NameABC</xsl:when>
        <xsl:when test="$desc = 'Another value'">NameXYZ</xsl:when>
    </xsl:choose>
</xsl:template>

</xsl:stylesheet>

Answer 2

在这种情况下，我更喜欢使用外部XML文件来实现查找表。

<lut>
  <entry desc="Some value" name="NameABC" number="123"/>
  <entry desc="Another value" name="NameXYZ" number="456"/>
  <!-- and another dozen entries -->
</lut>

放置在lut.xml中，可以为DataSet和Info应用以下样式表模板（其中从{l}读取other以提供另一个示例）：

<xsl:template match="DataSet">
  <xsl:variable name="desc" select="./Info/@description"/>
  <xsl:copy>
    <xsl:apply-templates select="@*"/>
    <xsl:attribute name="name">
      <xsl_value-of select="document('lut.xml')/lut/entry[@desc=$desc]/@name"/>
    </xsl:attribute>
    <xsl:apply-templates/>
  </xsl:copy>
</xsl:template>

<xsl:template match="Info">
  <xsl:variable name="desc" select="./@description"/>
  <xsl:copy>
    <xsl:apply-templates select="@*"/>
    <xsl:attribute name="nm">
       <xsl:value-of select="document('lut.xml')/lut/entry[@desc=$desc]/@name"/>
    </xsl:attribute>
    <xsl:attribute name="other">
       <xsl:value-of select="document('lut.xml')/lut/entry[@desc=$desc]/@number"/>
    </xsl:attribute>
    <xsl:apply-templates/>
  </xsl:copy>
</xsl:template>

通过使用其他属性或将Header分组为“type”-blocks，也很容易实现entries值的依赖性。

一次更改不同的属性

2 个答案:

替代：