如何在gnuplot上绘制树/图/网络数据？

Question

我有一个由边和颜色组成的数据集，我希望以类似网络的方式绘制它们，使用线条和圆圈（如下图），并可能使用群集着色。

数据的组织方式如下：

point1a_x point1a_y color
point1b_x point1b_y color

point2a_x point2a_y color
point2b_x point2b_y color
(...)

point2n_x point2n_y color
point2n_x point2n_y color

我将如何在gnuplot上进行此操作？

Answer 1

好的，所以我自己弄清楚了，我会在这里留下详细信息，以帮助任何有相同问题的人。

节点上带有标签的单色图：

这将生成一个与问题中的图形非常相似的图形，其中的线条将圆圈与标签结合在一起。

plot 'edges.dat' u 1:2 with lines lc rgb "black" lw 2 notitle,\
'edges.dat' u 1:2:(0.6) with circles fill solid lc rgb "black" notitle,\
'edges.dat' using 1:2:($0) with labels tc rgb "white" offset (0,0) font 'Arial Bold' notitle

几乎没有任何变化，它可以与问题图片上的那个相匹配。

plot 'edges.dat' u 1:2 with lines lc rgb "black" lw 2 notitle,\
'edges.dat' u 1:2:(0.8) with circles linecolor rgb "white" lw 2 fill solid border lc lt 0 notitle, \
'edges.dat' using 1:2:($0) with labels offset (0,0) font 'Arial Bold' notitle

---

群集色图：

unset colorbox

set palette model RGB defined ( 0 0 0 0 , 1 1 0 0 , 2 1 0.9 0, 3 0 1 0, 4 0 1 1 , 5 0 0 1 , 6 1 0 1 )

plot 'edges.dat' u 1:2:3 with lines lc palette notitle,\
'edges.dat' u 1:2:(0.15):3 with circles fill solid palette notitle

---

所有图上使用的数据都遵循以下结构：

21.53 9.55 0
24.26 7.92 0

5.63 3.23 1
2.65 1.77 1

5.63 3.23 0
4.27 7.04 0

(...)

Answer 2

accepted答案对我来说并不合适。以下是我必须改变的方法：

输入文件的格式

# A vertex has 3 fields: x coordinate, y coordnate and the label
# An edge consists of two points in consecutive lines
# There must be one or more blank lines between each edge.

21.53 9.55 A
24.26 7.92 B

5.63 3.23 C
2.65 1.77 D

5.63 3.23 C
4.27 7.04 E

#...

与其他答案相比，最大的区别是标签属于顶点，而不是边缘。

另请注意，我将标签更改为字母而不是数字。标签可以是任何字符串，这使得它们在示例中不是顺序索引更清楚。

绘图命令

plot \
  'edges.dat' using 1:2       with lines lc rgb "black" lw 2 notitle,\
  'edges.dat' using 1:2:(0.6) with circles fill solid lc rgb "black" notitle,\
  'edges.dat' using 1:2:3     with labels tc rgb "white" offset (0,0) font 'Arial Bold' notitle

这里的重大变化是，在绘制标签时，我们绘制第3个字段而不是$0字段，这是一个序列号。