Question

这是我的第一个批处理程序，我一直在网上搜索，但仍在努力编写解决方案。

我有以下CSV文件：

"RH",2013/06/15 02:14:58 -0400,"X","LQ3SUEEWPWKL6",005,
"FH",01
"SH",2013/06/14 00:00:00 -0400,2013/06/14 23:59:59 -0400,"LQ3SUEEWPWKL6",""
"CH","TransactionID","InvoiceID", 
......

我正在尝试编写一个简单的程序来执行以下操作：

如果column1 =“RH”，则提取column2值（2013/06/15 02:14:58 -0400）
如果column1 =“SH”，则提取column4值（LQ3SUEEWPWKL6）

和管道输出到文件。

这是我的代码到目前为止，但if条件对我不起作用

@echo off
:: Set input file in variable
::Set _InputFile=%1

:: Store input line into different variables
FOR /F "tokens=1-18* delims=," %%A IN (%_InputFile%) DO (
Set _var1=%%A
Set _var2=%%B
Set _var3=%%C
Set _var4=%%D
Set _var5=%%E
Set _var6=%%F
Set _var7=%%G
Set _var8=%%H
Set _var9=%%I
Set _var10=%%J
Set _var11=%%K
Set _var12=%%L
Set _var13=%%M
Set _var14=%%N
Set _var15=%%O
Set _var16=%%P
Set _var17=%%Q
Set _var18=%%R


IF "%_var1%"=="RH" echo %var2%

)

我的CSV文件在Excel和记事本中看起来很好但是当我执行脚本以显示第一个变量时，看起来在第一条记录的“RH”之前有一些垃圾字符 - 我无法绕过它，因为我需要如果var1 =“RH”，则提取其他列数据：

∩╗┐"RH"
FH
01
SH
CH
TransactionID,PaymentTrackingID,
SF
SF
SC
RF
CAD,CR,0
RF
USD,CR,0
RC
FF

Answer 1

(
FOR /F "tokens=1-18* delims=," %%A IN (%_InputFile%) DO (
  if "%%~A"=="RH" echo %%~B
  if "%%~A"=="SH" echo %%~D
 )
)>youroutputfilename

应该工作 - 不需要将所有值分配给不同的变量 - 但是如果你打算使用它们，那么

FOR /F "tokens=1-18* delims=," %%A IN (%_InputFile%) DO (
...
Set _var17=%%Q
Set _var18=%%R
CALL :PROCESS
)
...
GOTO :EOF

:PROCESS
IF %_var1%=="RH" echo %_var2%
IF %_var1%=="SH" echo %_var4%
GOTO :EOF

请注意，使用此方法时，由于您要将%%x分配给_varx，因此如果引用%%x，则引号将包含在已分配的值中。要删除封闭的引号（如果存在），请使用SET _varx=%%~x。

对于OP问题的附录20130703-1956Z

@ECHO OFF
SETLOCAL
SET _Inputfile=u:\noname1.txt
(
FOR /F "tokens=1-18* delims=," %%A IN (%_InputFile%) DO (
  SET "RH="
  SET "SH="
  ECHO(%%A|FINDSTR /l /c:"\"RH\"" >NUL
  IF NOT ERRORLEVEL 1 SET RH=Y
  ECHO(%%A|FINDSTR /l /c:"\"SH\"" >NUL
  IF NOT ERRORLEVEL 1 SET SH=Y
  if DEFINED RH echo %%~B
  if DEFINED SH echo %%~D
 )
)>u:\youroutputfilename
TYPE u:\youroutputfilename
del u:\youroutputfilename
echo========First way

(
FOR /F "tokens=1-18* delims=," %%A IN (%_InputFile%) DO (
  SET _var1=%%A
  SET "RH="
  SET "SH="
  CALL :process
  if DEFINED RH echo %%~B
  if DEFINED SH echo %%~D
 )
)>u:\youroutputfilename

TYPE u:\youroutputfilename
del u:\youroutputfilename
echo========Second way

SETLOCAL ENABLEDELAYEDEXPANSION 
(
FOR /F "tokens=1-18* delims=," %%A IN (%_InputFile%) DO (
  SET _var1=%%A
  IF "!_var1:~-4!"==""RH"" echo %%~B
  IF "!_var1:~-4!"==""SH"" echo %%~D
 )
)>u:\youroutputfilename

TYPE u:\youroutputfilename
del u:\youroutputfilename
echo========Third way
ENDLOCAL

GOTO :EOF

:process
IF "%_var1:~-4%"==""RH"" SET RH=Y
IF "%_var1:~-4%"==""SH"" SET SH=Y
GOTO :EOF

Answer 2

您有解析问题。首先使用)结束for循环，之后，您可以使用新变量：

@echo off :: Set input file in variable ::Set _InputFile=%1 :: Store input line into different variables FOR /F "tokens=1-18* delims=," %%A IN (%_InputFile%) DO ( Set "_var1=%%A" Set "_var2=%%B" Set "_var3=%%C" Set "_var4=%%D" Set "_var5=%%E" Set "_var6=%%F" Set "_var7=%%G" Set "_var8=%%H" Set "_var9=%%I" Set "_var10=%%J" Set "_var11=%%K" Set "_var12=%%L" Set "_var13=%%M" Set "_var14=%%N" Set "_var15=%%O" Set "_var16=%%P" Set "_var17=%%Q" Set "_var18=%%R" ) IF "%_var1%"=="RH" echo %var2%

Answer 3

您需要启用delayed expansion：

@echo off

setlocal EnableDelayedExpansion

set "_InputFile=..."

for /f "tokens=1-18* delims=," %%A in (%_InputFile%) do (
  Set _var1=%%A
  Set _var2=%%B
  ...

  if "!_var1!"=="RH" echo !_var2!
)

Answer 4

因为没有回答“为什么我的行以∩╗┐”RH“”开头，我会做一些坟墓。

因此，∩╗┐来自BOM（字节顺序标记），表示文件是UTF，以及必要时写入字节的方式。答案：你可以用

if x%_var1:RH=%x NEQ x%_var1%x (echo %_var2%)

这将检查RH是否在％_var1％中（如果在var中替换RH后，它保持不变，RH不在var中）这意味着，Bom是否在这里并不重要。但是，如果你想要完全匹配，你会遇到问题。

处理它的另一种方法是不在文件中包含bom，这意味着在没有BOM的情况下保存为ASCII或UTF-8;或者使用工具从UTF-8文件中删除bom。

从csv文件读取并根据第一列值提取某些数据列

4 个答案: