Question

我正在尝试使用LLVM为裸机ARM Cortex M4开发生成代码。 IR的创建进展顺利，LLVM正在（正如我的观点）生成正确的ARM Thumb ASM。

我购买了Arm开发套件进行一些测试：Atmel SAM4L-EK http://www.atmel.com/tools/SAM4L-EK.aspx

我创建了一个应用程序，打开开发板上的黄色led。（我只是想从板上得到一些东西）我在Atmel Studio上运行了一个附带的应用程序，LED工作正常。但我的申请似乎什么也没做......

根据手册，LED连接到PC10 在ATSAM4LC4C MCU的数据表中，它说GPIO端口的地址是0x400E1000，一个端口占用地址空间0x0200个字节，因此端口C在0x400E1000 + 0x0400上。

所以这是我的程序输出（LLVM输出）：

.syntax unified
.eabi_attribute 6, 10
.eabi_attribute 9, 2
.eabi_attribute 20, 1
.eabi_attribute 21, 1
.eabi_attribute 23, 3
.eabi_attribute 24, 1
.eabi_attribute 25, 1
.eabi_attribute 44, 1
.file   ""
.text
.globl  main
.align  2
.type   main,%function
.code   16
.thumb_func
main:
movw    r0, #5120
movw    r2, #5184
movw    r3, #5200
mov.w   r1, #1024
movt    r0, #16398
movt    r2, #16398
movt    r3, #16398
.LBB0_1:
str r1, [r0]
str r1, [r2]
str r1, [r3]
b   .LBB0_1
.Ltmp0:
.size   main, .Ltmp0-main

此代码将GPIOEnableRegister中的第10位设置为1

然后OutputDriverEnableRegister中的第10位为1

然后OutputValueRegister中的第10位为1

此时LED应该亮起......

这是我使用的启动代码：

.section INTERRUPT_VECTOR, "x"
.global _Reset
_Reset:
B Reset_Handler /* Reset */
B . /* Undefined */
B . /* SWI */
B . /* Prefetch Abort */
B . /* Data Abort */
B . /* reserved */
B . /* IRQ */
B . /* FIQ */

Reset_Handler:
#mov    r0, stack_top
MOV sp,r0
BL main
B .

两个汇编程序文件都编译为目标文件，如下所示：

as -mcpu=cortex-m4 -g startup.s -o startup.o

使用GNU ARM汇编程序

这是我使用的链接器脚本：

ENTRY(_Reset)
OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
OUTPUT_ARCH(arm)
SEARCH_DIR(.)

/* Memory Spaces Definitions */
MEMORY
{
     rom (rx)  : ORIGIN = 0x00000000, LENGTH = 0x00040000 /* flash, 256K */
     ram (rwx) : ORIGIN = 0x20000000, LENGTH = 0x00008000 /* sram, 32K */
}

SECTIONS
{
 . = 0x0;
 .text : {
 startup.o (INTERRUPT_VECTOR)
 *(.text)
}
.data : { *(.data) }
.bss : { *(.bss COMMON) }
. = ALIGN(8);0
. = . + 0x1000; /* 4kB of stack memory */
stack_top = .;
}

然后将目标文件链接到ELF二进制文件，如下所示：

ld -T linkerscript.ld armtest.o startup.o -o armtest.elf

使用GNU Arm Linker

然后我使用Atmel Studio将ELF二进制文件上传到电路板

Bot没有任何反应（也没有重置）

任何见解都会非常感激！

Answer 1

cortex-m系列不会像非皮质m系列手臂一样开机。 cortex-m有一个（非手臂）传统的中断向量表方法，而不是像全尺寸手臂那样的指令表。

/* vectors.s */
.thumb

.word   0x20020000  /* stack top address */
.word   _start      /* 1 Reset */
.word   hang        /* 2 NMI */
.word   hang        /* 3 HardFault */
.word   hang        /* 4 MemManage */
.word   hang        /* 5 BusFault */
.word   hang        /* 6 UsageFault */
.word   hang        /* 7 RESERVED */
.word   hang        /* 8 RESERVED */
.word   hang        /* 9 RESERVED*/
.word   hang        /* 10 RESERVED */
.word   hang        /* 11 SVCall */
.word   hang        /* 12 Debug Monitor */
.word   hang        /* 13 RESERVED */
.word   hang        /* 14 PendSV */
.word   hang        /* 15 SysTick */
.word   hang        /* 16 External Interrupt(0) */
.word   hang        /* 17 External Interrupt(1) */
.word   hang        /* 18 External Interrupt(2) */
.word   hang        /* 19 ...   */

.thumb_func
.global _start
_start:
    /*ldr r0,stacktop */
    /*mov sp,r0*/
    bl notmain
    b hang

.thumb_func
hang:   b .

您需要将堆栈顶部地址设置为特定于处理器的第一个项目。使用llvm你可能需要在这里调整一些指令，上面是针对gnu的。

让裸机ARM应用程序启动的问题

1 个答案: