Question

我在触发器中创建了一个游标，但它无法正常工作。请帮我解决一下

Create trigger Posts_Raw_To_Queue_Trigger  ON SendNotificationPostsRaw FOR INSERT
AS
BEGIN

DECLARE @PostID uniqueidentifier  
DECLARE @UserID uniqueidentifier
DECLARE @ProfID int
DECLARE @Email nvarchar(100)
DECLARE @CreationTime  datetime
DECLARE @SpecialityID int

SELECT @ProfID= ProfessionalID,@Email= Email from Professionals where UserID=@UserID
SELECT @PostID = I.PostID,@UserID = I.UserID ,@CreationTime =I.CreationTime  FROM INSERTED I

DECLARE post_relation_cursor CURSOR FOR select CategoryId  from PostCategoryRelations  where PostId=@PostID;

OPEN post_relation_cursor;
FETCH NEXT FROM post_relation_cursor INTO @SpecialityID 
WHILE @@FETCH_STATUS = 0  
BEGIN  
       INSERT INTO SendNotificationPostsQueue (UserID,PostID,SpecialityID,TemplateID,CreationTime,SendTime,JSONParameters) Values(@UserID,@PostID,1,1,'04/11/2013','04/11/2013','')

       FETCH NEXT FROM post_relation_cursor INTO @SpecialityID;
END;
CLOSE post_relation_cursor;
DEALLOCATE post_relation_cursor;

END

如果我删除光标并将虚拟值插入SendNotificationPostsQueue，它就可以工作。所以我的光标有问题...请告诉我为什么光标不起作用？

Answer 1

似乎根本不需要使用光标，最好不要在几乎所有情况下都使用光标。只需用标准插件替换扳机的主体（开始和结束之间的部分）：

INSERT INTO SendNotificationPostsQueue (UserID,PostID,SpecialityID,TemplateID,CreationTime,SendTime,JSONParameters)
SELECT
    i.UserID,
    i.PostID,
    1,
    1,
    '04/11/2013', -- Might want i.CreationTime or current_timestamp
    '04/11/2013',
    ''
FROM INSERTED i
    -- possibly want "LEFT JOIN Professionals p on i.UserID = p.UserID" here to grab other info

请注意我没有使用只能插入一行的插入的values子句。我将一个select语句作为插入的一部分，因此插入与select返回的行数。这意味着我们不需要使用游标，也不需要一堆变量来为游标供电。

正如@automatic所提到的，您当前代码的一个问题是您假设INSERTED只保留一行。如果它有多个，那么当您尝试将列分配给变量时，您将抛出错误。

出于优雅，可维护性和性能的原因，我强烈建议您放弃此光标并运行一个简单的插入（因为这就是光标所做的一切）。

Answer 2

可能存在问题 -

CREATE TRIGGER dbo.Posts_Raw_To_Queue_Trigger 

    ON SendNotificationPostsRaw
    -- for view
    INSTEAD OF INSERT
    -- OR
    -- for table
    AFTER INSERT

AS BEGIN

    DECLARE 
          @PostID UNIQUEIDENTIFIER
        , @UserID UNIQUEIDENTIFIER
        , @ProfID INT
        , @Email NVARCHAR(100)
        , @CreationTime DATETIME
        , @SpecialityID INT

    SELECT  @ProfID = ProfessionalID
        ,   @Email = Email
    FROM Professionals
    WHERE UserID = @UserID

    -- this posible return invalid result (random record from inserted sequence)
    SELECT  @PostID = I.PostID
        ,   @UserID = I.UserID
        ,   @CreationTime = I.CreationTime
    FROM INSERTED I

    DECLARE post_relation_cursor CURSOR LOCAL READ_ONLY FAST_FORWARD FOR
        SELECT CategoryID
        FROM dbo.PostCategoryRelations
        WHERE PostId = @PostID;

    OPEN post_relation_cursor;

    FETCH NEXT FROM post_relation_cursor INTO @SpecialityID

    WHILE @@FETCH_STATUS=0 BEGIN

        INSERT INTO SendNotificationPostsQueue (
                UserID
            ,   PostID
            ,   SpecialityID
            ,   TemplateID
            ,   CreationTime
            ,   SendTime
            ,   JSONParameters
        )
        SELECT
                 @UserID
             ,   @PostID
             ,   @SpecialityID --- !!!
             ,   1
             ,   '04/11/2013'
             ,   '04/11/2013'
             ,   ''


        FETCH NEXT FROM post_relation_cursor INTO @SpecialityID;

    END;

    CLOSE post_relation_cursor;
    DEALLOCATE post_relation_cursor;

END

<强>更新

如果我理解正确，那么业务逻辑必须是这样的：

CREATE TRIGGER dbo.Posts_Raw_To_Queue_Trigger 

    ON dbo.SendNotificationPostsRaw
    [INSTEAD OF]/[AFTER] INSERT

AS BEGIN

    SET NOCOUNT ON;

    DECLARE 
          @PostID UNIQUEIDENTIFIER
        , @UserID UNIQUEIDENTIFIER
        , @ProfID INT
        , @Email NVARCHAR(100)
        , @CreationTime DATETIME
        , @SpecialityID INT

    DECLARE cur CURSOR LOCAL READ_ONLY FAST_FORWARD FOR
        SELECT
              i.PostID
            , i.UserID
            , ProfID = p.ProfessionalID
            , p.Email
            , i.CreationTime
            , pcr.CategoryID
        FROM INSERTED i
        JOIN dbo.Professionals p ON i.UserID = p.UserID
        JOIN dbo.PostCategoryRelations pcr ON i.PostID = pcr.PostID

    OPEN cur

    FETCH NEXT FROM cur INTO 
          @PostID 
        , @UserID 
        , @ProfID 
        , @Email
        , @CreationTime 
        , @SpecialityID 

    WHILE @@FETCH_STATUS = 0 BEGIN

        INSERT INTO dbo.SendNotificationPostsQueue 
        (
              UserID
            , PostID
            , SpecialityID
            , TemplateID
            , CreationTime
            , SendTime
            , JSONParameters
        )
        SELECT
              @UserID
            , @PostID
            , @SpecialityID
            , 1
            , @CreationTime
            , @CreationTime
            , ''

        FETCH NEXT FROM cur INTO 
              @PostID 
            , @UserID 
            , @ProfID 
            , @Email
            , @CreationTime 
            , @SpecialityID 

    END

    CLOSE cur
    DEALLOCATE cur

END

SQL Server触发器的游标不起作用

2 个答案: