Question

我想创建一个批处理文件来读取循环中文件的每一行，并用另一个字符串替换字符串。以下是我的代码段：

for /F "tokens=*" %%i in (myfile) do (
  set str=%%i
  set str=%str: %oldstring% = %newstring%%
echo %str% >> newfile
)

这会产生一个新文件，其中'Echo is off'与myfile中的行数一样多。看起来像str变量在分配给%% i时根本没有任何值。有人能帮助我吗？

Answer 1

试试这个小脚本：

@echo off
set val=50
echo %val%
for /l %%i in (1,1,1) do (
    set val=%%i
    echo %val%
)
echo %val%
pause>nul

输出结果为：

50
50
1

不是你的预期，对吗？

那是因为在for循环中，变量在循环结束之前不会更新。要解决此问题，您可以使用setlocal enabledelayedexpansion，并使用感叹号（%）替换百分号（!）：

@echo off
setlocal enabledelayedexpansion
set val=50
echo %val%
for /l %%i in (1,1,1,) do (
    set val=%%i
    echo !val!
)
echo %val%
pause>nul

输出：

50
1
1

str变量没有值（在for循环期间）的原因是因为它尚未预先设置。

因此，通过这些快速修改，您的脚本将起作用......

setlocal enabledelayedexpansion
for /f "tokens=*" %%i in (myfile) do (
    set str=%%i
    set str=!str: %oldstring% = %newstring%!
    echo !str! >> newfile
)

顺便说一下，这个代码段假设{for}不会在forloop中设置oldstring和newstring，否则事情会变得混乱。

玩得开心。

Answer 2

花了一些时间，我得到了正确的方法：

@echo off
setlocal enabledelayedexpansion

set oldstring=AF-07295
set /a count=1000

for %%f in (*.*) do (
  set /a count=!count!+1
  for /f "tokens=*" %%i in (%%f) do (
    set str=%%i

    call set str=%%str:!oldstring!=!count!%%
    echo !str! >> %%~nf.ordnew

  )
)

endlocal

Answer 3

setlocal ENABLEDELAYEDEXPANSION
set filein="c:\program files\test1.txt"
set fileout="c:\program files\test2.txt"
set old=@VERSION@
set new=2.0.3
for /f "tokens=* delims=¶" %%i in ( '"type %filein%"') do (
    set str=%%i
    set str=!str:%old%=%new%!
    echo !str! >> %fileout% 
)

工作完美并且不会删除行文件开头的空格

用于读取文件并用新文件替换字符串的批处理文件

3 个答案: