Question

标准ML中的Functors与模块系统相关，可以基于其他结构生成结构。下面给出了为各种类型的列表生成列表组合器的仿函数示例，但此示例存在问题：

各种类型的列表都有优势 - 例如，惰性列表可以无限长，并且concantenation列表具有O（1）concat运算符。但是当所有这些列表类型都符合相同的签名时，仿函数只能使用它们的一般属性。

因此，我的问题是：什么是一个很好的例子，当函子有用时，各种生成的结构不会失去它们的特殊能力？

signature MYLIST =
sig
  type 'a t
  val null : 'a t -> bool
  val empty : 'a t
  val cons : 'a * 'a t -> 'a t
  val hd : 'a t -> 'a
  val tl : 'a t -> 'a t
end

structure RegularList : MYLIST =
struct
  type 'a t = 'a list
  val null = List.null
  val empty = []
  val cons = op::
  val hd = List.hd
  val tl = List.tl
end

structure LazyList : MYLIST =
struct
  datatype 'a t = Nil | Cons of 'a * (unit -> 'a t)
   val empty = Nil
   fun null Nil = true
    | null _ = false
   fun cons (x, xs) = Cons (x, fn () => xs)
   fun hd Nil = raise Empty
    | hd (Cons (x, _)) = x
   fun tl Nil = raise Empty
    | tl (Cons (_, f)) = f ()
end

structure ConcatList : MYLIST =
struct
  datatype 'a t = Nil | Singleton of 'a | Concat of 'a t * 'a t
  val empty = Nil
  fun null Nil = true
    | null (Singleton _) = false
    | null (Concat (xs, ys)) = null xs andalso null ys
  fun cons (x, xs) = Concat (Singleton x, xs)
  fun hd Nil = raise Empty
    | hd (Singleton x) = x
    | hd (Concat (xs, ys)) = hd xs
  fun tl Nil = raise Empty
    | tl (Singleton x) = Nil
    | tl (Concat (xs, ys)) = (* exercise *)
end

signature MYLISTCOMB =
sig
  type 'a t
  val length : 'a liste -> int
  val map : ('a -> 'b) -> 'a liste -> 'b liste
  val foldl : ('a * 'b -> 'b) -> 'b -> 'a liste -> 'b
  val append : 'a liste * 'a liste -> 'a liste
  val concat : 'a liste liste -> 'a liste
  val sort : ('a * 'a -> order) -> 'a t -> 'a t
end

functor ListComb (X : MYLIST) : MYLISTCOMB =
struct
  type 'a t = 'a X.t
  open X

  fun length xs =
      if null xs then 0
      else 1 + length (tl xs)

  fun map f xs =
      if null xs then empty
      else cons(f (hd xs), map f (tl xs))

  fun foldl f e xs =
      if null xs then e
      else foldl f (f (hd xs, e)) (tl xs)

  fun append (xs, ys) =
      if null xs then ys
      else cons (hd xs, append (tl xs, ys))

  fun concat xs =
      if null xs then empty
      else append (hd xs, concat (tl xs))

  fun sort cmp xs = (* exercise *)
end

structure RegularListComb = ListComb (RegularList)
structure LazyListComb = ListComb (LazyList)
structure ConcatListComb = ListComb (ConcatList)

Answer 1

不确定我完全理解你的问题。显然，仿函数对于定义模块化抽象很有用，（1）是多态的，（2）需要对其类型参数进行一整套操作，（3）提供类型作为结果的一部分（特别是 abstract < / em> types），以及（4）提供一整套操作。

请注意，您的示例不使用（3），这可能是仿函数最有趣的方面。想象一下，例如，实现一个抽象矩阵类型，你希望通过它所基于的矢量类型进行参数化。

ML仿函数的一个特定特征 - 以及核心语言多态函数 - 是参数。 Parametricity是一种语义属性，表示（多态代码）的评估对于它实例化的具体类型是遗忘的。这是一个重要的属性，因为它意味着各种语义上的善。特别是，它提供了非常强大的抽象和推理原则（参见例如Wadler的"Theorem's for free!"，或者我在reply to another question中给出的简要解释）。它也是类型擦除编译的基础（即，在运行时不需要任何类型）。

Parametricity意味着单个仿函数不能为不同的类型提供不同的实现 - 这似乎就是你所要求的。但是，当然，您可以自由编写多个函数，这些函数对其参数进行不同的语义/复杂性假设。

希望能回答你的问题。

Answer 2

以下是SML仿函数的一些有用示例。它们是在以下前提下制作的：如果你可以做一组事情，那么你就可以做另一套事情了。

集合的仿函数：如果可以比较元素，则可以使用平衡数据结构（例如二叉搜索树或其他种类的树）创建集合。

signature SET =
sig
    type elem
    type set
    val empty : set
    val singleton : elem -> set
    val union : set -> set -> set
    val intersect : set -> set -> set
end

signature ORD =
sig
    type t
    val compare : t * t -> order
end

functor BalancedSetFunctor(structure Cmp : ORD) :> SET =
struct
    type elem = Cmp.t
    type set = ...

    val empty = ...
    fun singleton x = ...
    fun union s1 s2 = ...
    fun intersect s1 s2 = ...
end

迭代的仿函数：对于任何类型的事物集合（例如列表），如果可以迭代它们，则可以自动折叠它们。您还可以为不同的方式创建不同的结构，以折叠相同的数据类型（例如，树的预订，有序和后序遍历）。

signature ITERABLE =
sig
    type elem
    type collection
    val next : collection -> (elem * collection) option
end

signature FOLD =
sig
    type elem
    type collection
    val fold : (elem * 'b -> 'b) -> 'b -> collection -> 'b
end

functor FoldFunctor(Iter : ITERABLE) :> FOLD =
struct
    type elem = Iter.elem
    type collection = Iter.collection

    fun fold f e xs =
        case Iter.next xs of
            NONE => e
          | SOME (x, xs') => fold f (f (x, e)) xs'
end

Answer 3

Functors是“提升者” - 他们提升（这个动词是标准FP术语）：对于给定的一组类型和值，它们允许您在一组新的类型和值之上创建他们。所有符合所需模块接口的模块都可以从仿函数中“受益”，但是如果你的能力意味着特定于实现的优势，它们就不会失去它们的特殊能力。

例如，你的例子很好地证明了我的观点：连接列表有一个非常快的concat运算符，正如你所写的那样，当用仿函数解除时，这种“能力”并没有消失。它仍然存在，甚至可能被仿函数代码使用。因此，在这个示例中，仿函数代码实际上受益于列表实现，没有知道它。这是一个非常强大的概念。

另一方面，由于模块在由仿函数提升时必须适合接口，因此在过程中会丢失多余的值和类型，这可能很烦人。不过，根据ML方言，这种限制可能会有所放松。

标准ML仿函数示例

3 个答案: