Question

假设我有2个阵列

my @one = ("one","two","three","four","five");
my @two = ("three","five");

如何判断第二个数组中的所有元素是否都在第一个？

Answer 1

my %one = map { $_ => 1 } @one;
if (grep($one{$_}, @two) == @two) {
   ...
}

Answer 2

另一种解决方法。

my %hash;
undef @hash{@two};  # add @two to keys %hash 
delete @hash{@one}; # remove @one from keys %hash 
print !%hash;       # is there anything left?

我从这个perlmonks node

中偷走了这个想法

Answer 3

use strict;

my @one = ("one","two","three","four","five");
my @two = ("three","five");

my %seen_in_one = map {$_ => 1} @one;

if (my @missing = grep {!$seen_in_one{$_}} @two) {
    print "The following elements are missing: @missing";
} else {
    print "All were found";
}

Answer 4

另一种方法，不确定它比ikegami更好。还是TIMTOWTDI

#!/usr/bin/env perl

use strict;
use warnings;

use List::Util qw/first/;
use List::MoreUtils qw/all/;

my @one = ("one","two","three","four","five");
my @two = ("three","five");

if ( all { my $find = $_; first { $find eq $_ } @one } @two ) {
  print "All \@two found in \@one\n";
}

Answer 5

从5.10开始，智能匹配运营商就会这样做。

my $verdict = !grep { not $_ ~~ @one } @two;

或List::MoreUtils::all：

my $verdict = all { $_ ~~ @one } @two;

检查数组中的所有字符串是否都在第二个数组中

5 个答案: